TI 84 Color Programs
For this blog entry,
I used TI Connect CE to transfer the programs and get screen shots. It is sweet!
TI Connect CE works with the TI-84 Plus family (Monochrome, C Silver
Edition, and the upcoming CE (review coming soon!)). You can edit programs and transfer them. The interface is a lot nicer, and you can
drag and drop programs and data files.
This blog will
feature some of the color functions and commands of the TI 84 Plus C Silver
Edition (and the upcoming TI 84 Plus CE).
 |
| CIRCLE4 in Progress |
CIRCLE4: Circle Draw and Update Program
Notes:
* Press 1, 2, 3, and 4 to change the color of
the circles. The colors cycle through
black, blue, red, and green.
* Since a list is used, we must use the numeric
color identifiers: 12 for black, 10 for blue, 11 for red, and 14 for Green.
(see table below for full reference)
* Database is
stored and recalled to preserve the current database (0).
Numeric Color
Identifiers:
10: blue
11: red
12: black
13: magenta
14: green
15: orange
16: brown
17: navy
18: light blue
19: yellow
20: white
21: light gray
22: medium gray
23: gray
24: dark gray
Program:
StoreGDB 0:0→J
AxesOff:FnOff
ZStandard:ClrDraw
{12,10,11,14}→L₅
{1,1,1,1}→L₆
Goto 0
Lbl 1
0→K
Repeat K=105
getKey→K
If K=92:Then
L₆(1)+1→L₆(1)
If L₆(1)=5:1→L₆(1)
Circle(–5,5,4,L₅(L₆(1)))
End
If K=93:Then
L₆(2)+1→L₆(2)
If L₆(2)=5:1→L₆(2)
Circle(5,5,4,L₅(L₆(2)))
End
If K=94:Then
L₆(3)+1→L₆(3)
If L₆(3)=5:1→L₆(3)
Circle(–5,–5,4,L₅(L₆(3)))
End
If K=82:Then
L₆(4)+1→L₆(4)
If L₆(4)=5:1→L₆(4)
Circle(5,–5,4,L₅(L₆(4)))
End
End
RecallGDB 0
AxesOn
Stop
Lbl 0
Circle(–5,5,4,12)
Circle(5,5,4,12)
Circle(–5,–5,4,12)
Circle(5,–5,4,12)
Goto 1
ARC84C: Arc Length
Find the Arc
Length of function Y1. Once
the arc length is calculated, the function is plotted in black and the arc
length is plotted in red.
Program:
FnOff :Func:FnOn 1
ClrDraw:Radian
Menu("USE Y₁?","YES",1,"NO",2)
Lbl 2
Input "Y₁, USE STRINGS:",Y₁
Lbl 1
GraphColor(1,BLACK)
Input
"LOW:",A
Input
"HIGH:",B
fnInt(√(1+nDeriv(Y₁,X,X)²),X,A,B)→L
Disp "ARC
LENGTH=",L
Pause
For(K,A,B,ΔX)
Pt-On(K,Y₁(K),1,RED)
End
TextColor(BLUE)
Text(150,0,"ARC=")
Text(150,40,L)
Examples
Y1 =
cos(X)*e^X from X = 1 to 2. Arc Length
= 4.7031139029…
Y1 =
-2X^2 + 4X + 1 rom X = -2 to 2. Arc
Length = 20.7833…
AREABTWN: Area Between Curves
This calculates
the area between two curves, Y1 and Y2. This program works best if you can set the
graph screen to where the curves intersect at only two points. The program first searches for two
intersections, one from the left side of the graph screen (Xmin) and one from
the right (Xmax). After the area is
calculated, both curves are graphed and the area between curves are
shaded. Function and Radian modes are
used.
Program:
Func:Radian:FnOff
:ClrDraw
FnOn 1:FnOn 2
Menu("USE Y₁/Y₂?","YES",1,"NO",2)
Lbl 2
Input "Y₁:",Y₁
Input "Y₂:",Y₂
Lbl 1
GraphColor(1,BLACK)
GraphColor(2,BLUE)
solve(Y₁-Y₂,X,Xmin)→A
solve(Y₁-Y₂,X,Xmax)→B
If A>B:Then
A→C:B→A:C→B:End
(A+B)/2→C
If A=B:Then
Disp "NO
SOLUTION":Stop
End
If Y₁(C)≥Y₂(C):Then
fnInt(Y₁-Y₂,X,A,B)→I
Disp
"AREA=",I
Disp "PRESS
ENTER TO GRAPH"
Pause
Shade(Y₂,Y₁,A,B,1,1,GREEN)
Else
fnInt(Y₂-Y₁,X,A,B)→I
Disp
"AREA=",I
Pause
Shade(Y₁,Y₂,A,B,1,1,GREEN)
End
Examples
The Standard
Window is used. Xmin = -10, Xmax = 10,
Ymin = -10, Ymax = 10
Y1 =
-2X^2 + 4X + 1, Y2 = X^2.
Area = 2.734721…
Y1 =
1.2X + .63, Y2 = -X^2 + 5X + 1.
Area = 10.58676675…
I plan to
accomplish the same programs for the Casio Prizm soon. Eddie
This blog is
property of Edward Shore. 2015.