HP 35S: Resistors in Series or Parallel (Portred from HP-33E)

Resistors in Series or Parallel
Source: HP-33E Student Engineering Applications, 1978
Original Calculator: HP-33S
Credit to Hewlett Packard Company
Ported to HP 35S by Eddie Shore, 10/10/2013

Instructions:
1. For each group of parallel or series resistors: press XEQ R.
2. At the Mode Prompt (INPUT M), enter 0 R/S for Parallel Resistors, 1 R/S for Series Resistors
3. Enter resistor values (assumed to be in Ohms) then press R/S.
4. To find the total, press XEQ R016.
5. Optional: Store the result in a variable for future use, as long is it not R.

Parallel Resistors: total resistance = 1/( 1/R1 + 1/R2 + ... )

Series Resistors: total resistance = R1 + R2 + ...


Program:
R001 LBL R
R002 0
R003 STO R
R004 SF 10 // press Left Shift, Flags, SF, decimal point, 0
R005 0=PAR 1=SER // equation
R006 PSE
R007 CF 10 // press Left Shift, Flags, CF, decimal point, 0
R008 INPUT M
R009 R/S
R010 RCL M
R011 x=0?
R012 XEQ R024
R013 R-down
R014 STO+ R
R015 GTO R009

R016 RCL R // total resistance
R017 RCL M
R018 x=0?
R019 XEQ R024
R020 CLx
R021 STO M
R022 R-down
R023 RTN

R024 R-down
R025 1/x
R026 ENTER
R027 RTN

Example 1:

Keystrokes:
1st Set:
XEQ R ENTER
0 R/S
120 R/S
240 R/S
120 R/S
XEQ R016
STO T

2nd Set:
XEQ R ENTER
0 R/S
320 R/S
400 R/S
XEQ R016
STO U
RCL+ T

Total Resistance: 225 7/9 ohms

Example 2:

XEQ R ENTER
0 R/S
30 R/S
60 R/S
XEQ R016 // Result: 20
STO T

XEQ R ENTER
1 R/S
RCL T R/S
80 R/S
XEQ R016 // Result: 100
STO T

XEQ R ENTER
0 R/S
RCL T R/S
40 R/S
XEQ R016

Total Resistance: 28 4/7 ohms