## Thursday, January 4, 2018

### HP Prime: Black Hole Characteristics – Hawking Radiation (updated 1/23/2018)

HP Prime:  Black Hole Characteristics – Hawking Radiation

Equations Used

Given the mass (either in kg or solar masses), the following equations can estimate these black hole characteristics:

R = M * G/c^2

Life time left as the black hole slowly radiates (in s):
t = M^3 * 5120 * π * G^2 / (hbar * c^4)

The HP Prime uses the conversion for seconds to years:
1 year ≈ 31556925.9747 s

Average temperature of the black hole (K):
temp = (hbar * c^3)/(M * 8 * k * π * G)

If you need to convert to °C subtract 273.15 from this result.

Surface area of the black hole (m^2):
sa = (M^2 * 16 * π * G^2)/c^4

Surface gravity of the black hole (m/s^2), as you can imagine, this will be a huge number:
gr = c^4 / (M * 4 * G)

Constants Used

Values are taken from the HP Prime

Universal Gravitation Constant
G = 6.67384 * 10^-11 m^3/(kg * s^2)

Speed of Light
c = 299792458 m/s

Plank Constant Divided by 2*π
hbar = 1.054571726 * 10^-34 J*s

Boltzmann Constant
k = 1.3806488 * 10^-23 J/K

HP Prime Program BLACKHOLE

EXPORT BLACKHOLE()
BEGIN
// EWS 2018-01-04

// Input of mass
LOCAL ch,M;
INPUT({M,{ch,{"kg","Solar Mass"}}},
"Mass",{"Mass: ","Unit: "});

IF ch==2 THEN
M:=1.988435ᴇ30*M;

END;

LOCAL k,G,c,hbar;
// from 4 Constants
// Shift, Units, Constant
k:=1.3806488ᴇ−23; // Chemistry
G:=6.67384ᴇ−11; // Physics
c:=299792458; // Physics
hbar:=1.054571726ᴇ−34; // Quantum

LOCAL R:=(2*G*M)/c^2;

// Life (years)
LOCAL t:=M^3*5120*π*G^2/
(hbar*c^4*31556925.9747);

// Temperature (K)
LOCAL temp:=(hbar*c^3)/
(M*8*k*π*G);

// Surface Area (m^2)
LOCAL sa:=M^2*16*π*G^2/c^4;

// Gravity
LOCAL gr:=c^4/(4*G*M);

// Results
PRINT();
PRINT(R+" m");
PRINT("Life:");
PRINT(t+" years");
PRINT("Temperature:");
PRINT(temp+" K");
PRINT("Surface Area:");
PRINT(sa+" m^2");
PRINT("Surface Gravity:");
PRINT(gr+" m/s^2");

// List
RETURN {R,t,temp,sa,gr};
END;

Note:  (1/23/2018)

The line in red used to read IF ch:=2 THEN, this is an error on my part.  The above code is now correct. (Alternatively, IF ch=2 THEN also works) Much appreciation to hfw and Salvomic on HP Museum of Calculators for pointing this error to me!

Examples

Cygnus X-1:  14.8 solar masses

Life:  6.79261706057 * 10^70 years
Temperature:  4.16932978074 * 10^-9 K  (near absolute zero, very cold!)
Surface Area:  24004068275.4 m^2
Surface Gravity: 1.02819127807 * 10^12 m/s^2

Sagittarius A*, the center of our Milky Way Galaxy:  4.31 million solar masses

Life: 1.67758214773 * 10^87 years
Temperature: 1.43169560917 * 10^-14 K
Surface Area: 2.03571024785 * 10^21 m^2
Surface Gravity: 3530680.02679 m/s^2

Source:

Jim Wisniewski.  “Hawking Radition Calcualtor”  Xaonon.  January 3, 2017.  http://xaonon.dyndns.org/hawking/  Retrieved December 26, 2017

Eddie

This blog is property of Edward Shore, 2018.

### TI-74: Five Stencil Derivative, Vertical Height on a Hill, Solving Cubic Equations

TI-74:  Five Stencil Derivative, Vertical Height on a Hill, Solving Cubic Equations TI-74 Program: Five Stencil Derivative This program...