Fun with the TI-73 Part II: Rolling Two Dice, Numerical Derivative, Rectangular/Polar Conversions

Fun with the TI-73 Part II: Rolling Two Dice, Numerical Derivative, Rectangular/Polar Conversions

TI-73 Program:  TWODICE - Rolling Two Dice

Introduction:

The program TWODICE will roll two regular dice and give the sum of those dice in three lists:

L_1: die 1

L_2: die 2

L_3: total

If there are seven rolls or less, the program displays the rolls.  In any case, the results are stored in the above lists.

Access L_1 by pressing [ 2nd ] [ STAT ] (LIST), 1

Access L_2 by pressing [ 2nd ] [ STAT ] (LIST), 2

Access L_3 by pressing [ 2nd ] [ STAT ] (LIST), 3

Program:

"EWS 2021"

Disp "ROLL THE DICE"

Input "ROLLS? ",X

dice(X)→L_1

dice(X)→L_2

L_1+L_2→L_3

If X≤7

Then

ClrScreen

For(A,1,X)

Output(A,1,L_1(A))

Output(A,3,L_2(A))

Output(A,6,L_3(A))

End

Pause

End

ClrScreen

Disp "L_1 = DIE 1","L_2 = DIE 2","L_3 = TOTAL"

Pause

Your results will vary.

TI-73 Program:  DERIVY1 - Numerical Derivative of y1(x)

The simple program DERIVY1 calculates the numerical derivatives of the equation stored in Y_1.  

Access Y_1 by pressing [ 2nd ] [ APPS ] (VARS), 2, 1

Program:

"EWS 2021"

Disp "D/DX Y_1"

Prompt X

10^(-8)→H

(2*H)^-1*(Y_1(X+H)-Y_1(X-H))→D

Disp "APPROX D/DX"

Pause D

Example:

Y_1 = (X^2-3)^2 + 1

Derivative at x = 0.95, Result:  -7.9705

Derivative at x = 2, Result:  8

Y_1 = e^(X^3/4)

Derivative at x = 0.46, Result: 0.16261

Derivative at x = 1.55, Result:  4.571295

TI-73 Program: RECPOL - Rectangular/Polar Conversion

This program has two conversions:

1.  >RECT:  Polar (r, θ) to Rectangular (x, y)

2.  >POLAR:  Rectangular (x, y) to Polar (r, θ)

This program works in either Degree or Radian mode.

I take a different approach to calculate angle than the atan2 method.  Approached this as calculating the angle between the vectors [ x, 0 ] and [ x, y].  The angle between vectors v1 and v2 is:

θ = acos( dot(v1, v2) / ( norm(v1) * norm(v2) ) = acos( x / √(x^2 + y^2))

The angle is negative if y<0.   

Like the argument and angle conversions, the point (0,0) is defined to have an angle of 0.

Since there is no theta character (θ) on the TI-73, I use the variable A instead.

Program:

"EWS 2021"

Lbl 0

Menu("MENU",">RECT",1,">POLAR",2,"EXIT",3)

Lbl 1

Input "R? ",R

Input "ANG? ",A

R*cos(A)→X

R*sin(A)→Y

Disp "X= ",X,"Y= ",Y

Pause

Goto 0

Lbl 2

Input "X? ",X

Input "Y? ",Y

√(X^2+Y^2)→R

If X=0 and Y=0

Then

0→A

Else

cos^-1(X/√(X^2+Y^2))→A

If Y<0

-A→A

End

Disp "R=",R,"ANG=",A

Pause

Goto 0

Lbl 3

Examples:

Examples are in Degree mode.

R = 19, ANG = 87.3°

Result:  X = 0.8950225635, Y = 18.97890762

X = -11.5, Y = 2.4

Result:  R = 1.74776575, ANG = 168.2118167

Eddie

All original content copyright, © 2011-2021.  Edward Shore.   Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited.  This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author. 

Fun with the TI-73 Part I: Logarithmic Regression, Percent, Square Root Simplification

 Fun with the TI-73 Part I: Logarithmic Regression, Percent, Square Root Simplification

TI-73 Program:  LNREG - Logarithmic Regression

Introduction:

The program LNREG fits the data to the equation:

y = a * ln x + b

The lists used are:

L_1:  x list  

L_2:  y list

Access L_1 by pressing [ 2nd ] [ STAT ] (LIST), 1.

Access L_2 by pressing [ 2nd ] [ STAT ] (LIST), 2

You can edit lists by pressing [LIST].  

The lower case a and b are from the VARS, Statistics, EQ menu.

Program:

"EWS 2021"

Disp "FIT Y=A LN X +B","USES X=L1,Y=L2:

ln(L_1) → L_1

LinReg(ax+b) L_1,L_2

a → A

b → B

Output(4,1,"A=")

Output(4,5,A)

Output(5,1,"B=")

Output(5,5,B)

Output(6,5,r²)

e^(L_1) → L_1

Pause

Menu("PLOT?","YES",1,"NO",2)

Lbl 1

PlotsOff

FnOff

"A*ln(X)+B"→Y_1

Plot1(xyLine,L_1,L_2,□)

ZoomStat

Lbl 2

Example:

X:  L_1 = {1, 2, 3, 4, 5, 6}

Y:  L_2 = {-1.26, 2.1018, 4.0683, 5.4635, 6.5458, 7.43}

Results:

y = A ln x + B

A = -1.259978557

B = 4.849985251

r^2 ≈ 1

TI-73 Program: PERCENT - Percent Calculations

Introduction:

The program gives the users four options:

1.  Adding tax (plus percent)

2.  Subtracting tax (minus percent)

3.  Percent Change

4.  Percent Total

The percent key divides the amount by 100.  Example:  5% turns to 0.052.

Program:

"EWS 2021"

Menu("PERCENT","TAX+",1,"TAX-",2,"%CHG",3,"%TOT",4)

Lbl 1

Prompt N

Input "X% ",X

N*(1+X%)→Y

Pause Y

Stop

Lbl 2

Prompt N

Input "X% ",X

N*(1-X%)→Y

Pause Y

Stop

Lbl 3

Input "OLD=",O

Input "NEW=",N

(N-O)*100/O→Y

Pause Y

Stop

Lbl 4

Input "PART=",P

Input "WHOLE=",W

100*P/W→Y

Pause Y

Stop

Example:

TAX+:   Add 15% to 19.95

N: 19.95, X%:  15

Result:  22.9425

TAX-:  Subtract 15% from 19.95

N:  19.95, X%:  15

Result:  16.9575

%CHG:  Old (O):  11700, New (N):  15420

Result:  31.79487179

%TOT:  Part (P):  11700, Whole (W):  15420

Result:  75.7548638

TI-73 Program: SQROOT - Simplification Square Root

This program tries to factor √N to A√B.  N, A, and B are integers.

Program:

"EWS 2021"

Disp "√(N)->A√(B)"

Prompt N

iPart(√(N))→X

While X≠0

If fPart(N/X^2)=0

Then

X→A

N/X^2→B

Goto 1

Else

X-1→X

End

End

Lbl 1

Disp "A=",A,"B=",B

Pause

Examples:

N = 88;   √88 = 2√22

N = 1225;  √1225 = 35√1

Notes:

*  There is no ALPHA key for the TI-73 (family).   Text is entered by use of the [ 2nd ] [ MATH ] (TEXT) key sequence.  Letters are selected by using the arrow keys and selecting them with the ENTER key.

*  The underscore character ( _ ) acts like a space.

*  The TEXT has the letters A-Z, _, <, =, >, ≤, ≠, ≥, and the logic functions and, or.  For the question mark character, ?, press [ 2nd ] [ PRGM ] (CATALOG) [ ↑ ] [ ENTER ]. 

* The programming language of the TI-73 is the robust as the TI-83 family (TI-83, TI-83 Plus, TI-84 Plus family, TI-82).  

* The main difference is that results are shown on a separate screen for output.   When a program terminates, the TI-73 returns to the Home screen.  It is necessary to include a Pause at the end to keep the results on the screen.

Stay tuned tomorrow for more programs for the TI-73.  

Eddie

All original content copyright, © 2011-2021.  Edward Shore.   Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited.  This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author. 

TI-84 Plus CE and TI-73 Explorer: Analog Clock

 TI-84 Plus CE and TI-73 Explorer:  Analog Clock

Introduction

The program ANALOG draws a 12-hour analog clock for any given time, given the hour and minute.  The TI-73 program covers the TI-73 Explorer and should be ported to any of the Texas Instruments calculators with monochrome screens with no or little adjustment.

The TI-84 Plus CE adds colors:  hour hand is black, minute hand is brown, the markers are orange.  Adjust colors to your liking.

Notes:

*  The program pauses when the clock is drawn.  Pressing [ENTER] restores turns the Axes back on.

*  The Pt-On command has the syntax Pt-On(x, y, mark, color*).   Mark:  Dot (1 or default), Open Square (2), Plus (3).   Color applies only to the TI-84 Plus CE or TI-84 Plus C Silver Edition.

*  The program sets the calculator to degrees mode.

Math:

Let H be the hour and M be the minute.

Set S = H + M/60,  where S is the decimal hour of the time given.

For a circle of 360°, each hour occupies 30° of the clock (360/12).  Like wise, each minute occupies 6° of the clock  (360/60).

A = 30*S,  B= 6*M

Lines are drawn from the origin (0,0) to a point (x,y).  If we set x and y to an angle θ, then:

x = r * cos θ,  y = r * sin θ, where r is the length of the line.

Angels on a cartesian plane start from the positive x-axis and measured going counter-clockwise.  However, on the analog clock requires angels to measured from the top (due north) and rotate clockwise.  This will require a vertical flip and adjusting the angle by 90°.  The adjusted coordinates are:

 

x = r * cos (θ-90°),  y = -r * sin (θ- 90°), where r is the length of the line.

TI-73 Program: ANALOG

(this includes TI-73 Explorer)

"EWS 2021"

FnOff

PlotsOff

ClrDraw

Degree

Disp "12 HR ANALOG"

Input "HOUR? ",H

Input "MINUTE? ",M

ZStandard

ZSquare

AxesOff

Circle(0,0,8)

For(X,30,360,30)

Pt-On(7*cos(X-90),-7*sin(X-90),2)

End

Line(0,0,5*cos(30H+M-90),-5*sin(30H+M-90))

Line(0,0,7*cos(6M-90),-7*sin(6M-90))

Pause

AxesOn

TI-84 Plus CE Program:  ANALOG

"EWS 2021-01-18"

FnOff 

PlotsOff 

ClrDraw

Degree

Disp "12 HOUR ANALOG CLOCK"

Input "HOUR? ",H

Input "MINUTE? ",M

ZStandard

ZSquare

AxesOff

GridOff

"FACE"

Circle(0,0,8,MEDGRAY)

For(I,30,360,30)

Pt-On(7*cos(I-90),­7*sin(I-90),2,ORANGE)

End

"HOUR"

Line(0,0,5*cos(30H+M/2-90),­5*sin(30H+M/2-90),1,BLACK)

"MINUTE"

Line(0,0,7*cos(6*M-90),­7*sin(6*M-90),1,BROWN)

Pause 

AxesOn 

Next week, more fun with the TI-73 Explorer.  

Eddie

All original content copyright, © 2011-2021.  Edward Shore.   Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited.  This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author. 

Review: Texas Instruments TI-73 Explorer

Review:  Texas Instruments TI-73 Explorer

Basic Information for the TI-73 Explorer

Company: Texas Instruments
Production Years:  1998 - present(?)
New Cost:  originally $95, went down to $70
Battery:  4 AAA with CR1616 backup
Memory:  25,000 bytes, 128K Flash ROM
Type: Graphing

There are three variants of the TI-73

Variant 1:  1998 - 2003.  Gray keyboard, teal and blue keys. 

Variant 2:  2003 - 2009.  Renamed the TI-73 Explorer.  Periwinkle keyboard, red, blue, and white keys.  I have and am reviewing this variant.

Variant 3:  2009 - present.  Same colors as Variant 2, but the calculator is shaped like the 2004 Monochrome TI-84 Plus. 

All three variants have the same command set. 

I purchased mine on eBay (thank you, molecularbonds) for $12.75.  The best bet to buy one is to go online. 

I think new units of the TI-73 Explorer are still being sold despite the fact that I have never seen it being sold in office and electronic stores or one "in the wild".  If production has discontinued, it is a quiet discontinue. 

Background

The TI-73 and the TI-73 Explorer was designed for the middle school market.  The emphasis is on fractions, statistics, and basic algebra.

Dedicated Fraction Keys

There are five dedicated keys to fractions:

[UNIT]:  Assists the user in entering a mixed fraction.  Enter the whole number, press [UNIT], and a fraction bar comes up.  For example, to enter 5 2/3, press 5 [UNIT] 2 [ ↓ ] 3 [ENTER].

[SIMP]:  Simplifies fractions.  This key only works in Mansimp mode.  The key is non-function (a ERR:MODE error occurs in Autosimp mode). 

[ b/c ]:  Fraction bar.  Assists the user in entering a fraction. 

[F ←→ D]:  Fraction/Decimal Conversion.  On the TI-73, the maximum denominator is 1000.  Any number 1/1001 or less will automatically be shown as its decimal equivalent.

[A b/c ←→ d/e]:  Mixed Fraction/Improper Conversion.  If you enter a decimal equivalent, the form you get depends on what mode the calculator is in.

A_b/c mode:  The [A b/c ←→ d/e] converts the number in decimal form into an improper fraction.

b/c mode:  The [A b/c ←→ d/e] converts the number in decimal form into a mixed fraction. 

Statistics

The TI-73 performs one and two variable statistics.  The available regressions are:  Linear Regression (ax+b), Manual Fit (you set the line), Med-Med, Quad Regression (Quadratic Regression, ax^2 + bx + c), and Exp (Exponential Regression, a*b^x). 

Like the TI-84 family (TI-80, TI-82 series, TI-83 series, TI-84 Plus series), the TI-73 has three stat plots.  Unique to the TI-73, you can plot pie charts and horizontal and vertical bar charts with various symbols (such as people, trees, faces, pies, diamonds). 

Further unique to the TI-73 (outside the CAS and Nspire series), lists on the TI-73 can hold strings.  Each string can hold up to six characters.   The lists with strings are used as category lists for pie charts and bar charts.

Speaking of strings, there is only one key with a variable, [ x ], but where did all the alpha characters go?

The Text Facility:  [ 2nd ] [MATH]

Instead of an ALPHA key, the TI-73 has a text entry facility, which can be accessed by pressing [ 2nd ] [MATH].  The screen will allow you to write text strings.  The quote character is included.  You can use the keyboard to type numbers. 

The text facility also has the comparison operators (=, ≠, >, ≥, <, ≤, with Boolean operators and, or). 

When you are done, select DONE and press [ENTER].  Whatever is typed in copied to where your cursor was.

By the way, we can still use the variables A-Z to store values.   This does make storing and recalling variables cumbersome. 

The Constant Key [CONST]

The [CONST] key gives users four constant variables.  Pressing [ 2nd ] [CONST] sets the constants.  Unfortunately, we can not use the store key to store constants directly.

Where Did All the Scientific Functions Go?

Despite a keyboard that is simplified, the TI-73 has a range of mathematical functions.  For example, the logarithmic functions are in the MATH-LOG menu.  The trigonometric functions are in a separate menu.  The hyperbolic functions have to be constructed. 

[MATH]
MATH:  lcm, gcd, cube, cube root, general root, solver
NUM: abs, round, iPart, fPart,min, min, remainder
PRB:  rand, randInt, nPr, nCr, ! (factorial of integers), coin (toss a coin a number of times, results in a 0 or 1), dice (tosses any number of dice for a specific set of rolls)
LOG:  log, 10^, ln, e^

[ 2nd ] [DRAW] (TRIG):
TRIG: sin, sin⁻¹, cos, cos⁻¹, tan, tan⁻¹
ANGLE: °, ', ", ^r (radian angle symbol), >DMS (conversion to degrees, minutes, seconds)

We may not have any calculus functions (integrals, derivatives, summation), but we have a good range of scientific functions.

Graphing

The only graphing mode available on the TI-73 is Functions (y(x)).  Four graph slots are available. 

Programming

The TI-73 has 25,000 bytes.  All of the TI-BASIC commands are available, which includes If, For, While, Repeat, Input, Prompt, Output, IS>, and DS<. 

The use of the TEXT facility is need to create strings, prompts, and labels.  It will take getting used to since I'm used to an ALPHA key to work with.

Conversions

The [ 2nd ] [UNIT] (CONVERT) has many conversions of length, area, volume, time, temperature, mas, and speed.  Always a good thing to have. 

Verdict

I think the TI-73 could have been a great entry-level graphing calculator, like it a successor to the TI-81 or TI-80.  I think the ALPHA key would help greatly.

I was not sure about the marketing strategy that the TI-73 didn't sell well.  A lower price point would have helped too.

The TI-73 may be worth looking at getting, and if you do, I would try online sources like eBay to try to get it less than retail price. 

With the 73, I now have all of the models of Texas Instruments graphing calculators (73, 80, 81, 82, 83, 84, 85, 86, 89, 92, Voyage 200, Nspire). 


Source:
TI-73 and TI-73 Explorer.  Datamath.  Retrieved August 25, 2019

http://www.datamath.org/Graphing/TI-73.htm

http://www.datamath.org/Graphing/TI-73_Explorer.htm

http://www.datamath.org/Graphing/TI-73_Explorer_P1108.htm

Eddie

All original content copyright, © 2011-2019.  Edward Shore.   Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited.  This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author