Showing posts with label learning curve. Show all posts
Showing posts with label learning curve. Show all posts

Friday, November 13, 2026

HP 20S and DM 42 Learning Curve

HP 20S and DM 42 Learning Curve



The Learning Curve


The learning curve relates the average time it takes to produce, finished, or manufacture a certain amount of units using two factors: (1) the tie it takes to complete a first product or procedure and (2) a learning curve percentage. Typically the learning curve percentage is determined by the fraction of a time it takes to complete a second product or procedure.


For example: If it takes 3 hours to manufacture and assemble the first desk, and it only takes 2.5 hours to a second desk, the learning curve is 2.5 ÷ 3 or about 0.8333 (83.33%).



The learning curve formula is:



y = a * x^b



where:

b: The learning curve index, where b = log f ÷ log 2. f is the learning curve.

a: The time to finish a first product

x: how many products needed to achieve an average time per products

y: the average time per product





HP 20S: Learning Curve



Input Registers:

R1: a

R2: f



Output Registers:

R3: b



Input/Output Registers:

R4: x

R5: y



Labels:

Initialize a and f: a [ INPUT ] f [ XEQ ] (A) (view b)

Given x, calculate y: x [ XEQ ] (B)

Given y, calculate x: y [ XEQ ] (C)



Code:

LBL A; 01 61, 41, A

STO 2; 02 21, 2

SWAP; 03 51, 31

STO 1; 04 21, 1

SWAP; 05 51, 31

LOG; 06 51, 13

÷ ; 07 45

2 ; 08 2

LOG; 09 51, 13

= ; 10 74

STO 3; 11 21, 3

RTN; 12 61, 26



LBL B; 13 61, 41, b

STO 4; 14 21, 4

y^x; 15 14

RCL 3; 16 22, 3

× ; 17 55

RCL 1; 18 22, 1

= ; 19 74

STO 5; 20 21, 5

RTN; 21 61, 26



LBL C; 22 61, 41, C

STO 5; 23 21, 5

( ; 24 33

RCL 5; 25 22, 5

÷ ; 26 45

RCL 1; 27 22, 1

) ; 28 34

LOG; 29 51, 13

÷ ; 30 45

RCL 3; 31 22, 3

= ; 32 74

10^x; 33 51, 12

STO 4; 34 21, 4

RTN; 35 61, 26



DM42: Learning Curve



Input Registers:

R01: a

R02: f



Output Registers:

R03: b



Input/Output Registers:

R04: x

R05: y



Code:

00 {92-Byte Prgm}

01 LBL “LEARN”

02 LBL 11

03 “A,B>”

04 KEY 1 GTO 01

05 “X>Y”

06 KEY 2 GTO 02

07 “Y>X”

08 KEY 3 GTO 03

09 “EXIT”

10 KEY 6 GTO 06

11 MENU

12 LBL 10

13 STOP

14 GTO 10



15 LBL 01

16 STO 02

17 x<>y

18 STO 01

19 x<>y

20 LOG

21 2

22 LOG

23 ÷

24 STO 03

25 LBL 11



26 LBL 02

27 STO 04

28 RCL 03

29 Y↑X

30 RCL× 01

31 STO 05

32 GTO 11



33 LBL 03

34 STO 05

35 RCL÷ 01

36 LOG

37 RCL 03

38 1/x

39 ×

40 10↑X

41 STO 04

42 GTO 11



43 LBL 06

44 CLMENU

45 EXITALL

46 RTN

(47 END)



Examples

(FIX 4)



Example 1:

a = 15, f = 0.8

Input: x = 20, Result: y ≈ 5.7181

Input: x = 40, Result y ≈ 4.5745

Input: y = 1, Result x ≈ 4500.6281



Example 2:

a = 2.5, f = 0.94

Input: x = 20, Result y ≈ 1.9134

Input x = 100, Result y ≈ 1.6573

Input y = 2, Result x ≈ 12.1791



Source


Kagan, Julia. “Understanding the Learning Curve: Impact on Efficiency and Costs” Investopedia. May 21, 2026.

https://www.investopedia.com/terms/l/learning-curve.asp Retrieved July 10, 2026


Until next time,



Eddie


HHC Conference Videos

Please check out the Youtube page hpcalc.org at https://www.youtube.com/@hpcalc .   

Videos and talks from HP Calculator conferences until HCC 2025 are posted.   Look out for talks from HCC 2026 to posted there soon.  Disclaimer:  I do not run this account.  


All original content copyright, © 2011-2026. Edward Shore. Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited. This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author.


Symmetric Quartic Equation - Python

Symmetric Quartic Equation - Python Note: The code is programmed with a TI-84 Evo. No modules are used, so the scripts should be adopt...