Casio fx-CG 50: Impedance Calculations

Casio fx-CG 50:  Impedance Calculations

Introduction

The program FX61IMP contains a suite of impedance calculations.  Why the unusual name?

In the late 1980s, Casio had a fx-61F calculator.  The fx-61F is a specialized programming scientific calculator, which is the only calculator, to my knowledge, to feature an Impedance mode.  The impedance mode has specialized keys to calculate impedance of resistors, capacitors, and inductors (coils).  The calculator also featured 29 specialized electrical formulas, a 30 step programming capability, base conversions, 1 variable statistics, and complex numbers.

The main menu of FX61IMP:

1.  Impedance of a Coil (Inductor)
2.  Impedance of a Capacitor
3.  Impedance of two parallel resistors (Parallel)
4.  Impedance of a Series Resistor
5.  Analysis of total Impedance
6.  Store results in X and Y
7.  View Memory Registers
8.  Clear Variables
9.  Exit

Variables used:
Z = impedance of the current calculation
S = grand total impedance
X = user register
Y = user register

Note:  In electronics, the symbol j is used in complex numbers.  The fx-61F uses j.  However, the fx-CG50 uses i in complex numbers.  The program uses i and the user is notified of this when the program starts. 

1.  Impedance of a Coil (Inductor)
Provide the self-inductance (in H, Henrys) and frequency (in 1/s), the impedance is calculated as:
Z = 2 * π * f * L * i

The result is added to S.

2.  Impedance of a Capacitor
Provide the capacitance (in F, Farads) and frequency (in 1/s), the impedance is calculated as:
Z = 1/(2 * π * f * C * i)

The result is added to S.

3.  Impedance of two parallel resistors (Parallel)
This calculates the impedance of parallel resistors:
Z = 1/(1/a + 1/b) = (a * b) / (a + b)

The result is added to S.

4.  Impedance of a Series Resistor
The impedance of the resistor is:  R (in Ω, Ohms)

Z = R

The result is added to S.

5.  Analysis of total Impedance
Takes the total impedance (S) and returns its total, magnitude, and phase angle (in degrees).  You will have an opportunity to clear S (reset S to zero).

6.  Store results in X and Y
You can store Z or S in the variables X and Y.

7.  View Memory Registers
View the contents Z, S, X, and Y.

8.  Clear Variables
Resets Z, S, X, and Y to 0.

9.  Exit
Exits the program.

The program is listed in text form, which can be copied to the fx-CG 50.

Program Text Listing:
'ProgramMode:RUN
"2019-09-09 EWS"
Deg
a+bi
ClrText
Red Locate 1,3,"NOTICE"
Blue Locate 1,5,"J is represented"
Blue Locate 1,6,"by _Imaginary_. (_Sqrt__(-)_1)"
" "Disps0->S
0->Z
0->X
0->Y
Lbl 0
ClrText
Menu "IMPEDANCE","COIL",1,"CAPACITOR",2,"PARALLEL",3,"SERIES RESISTOR",4,"ANALYSIS",5,"STORE IN X OR Y",6,"VIEW MEMORY",7,"CLEAR VARS",8,"EXIT",E
Lbl 1
"FREQ: "?->F
"INDUCTANCE: "?->L
2piLFImaginary->ZDispsS+Z->S
Goto 0
Lbl 2
"FREQ: "?->F
"CAPACITY: "?->C
(2piFCImaginary)^<-1>->ZDispsS+Z->S
Goto 0
Lbl 3
"PARALLEL IMPEDANCE"
"A_#E6D7_B"
"A: "?->A
"B: "?->B
(AB)/(A+B)->ZDispsS+Z->S
Goto 0
Lbl 4
"RESISTANCE: "?->R
R->ZDispsS+Z->S
Goto 0
Lbl 5
"TOTAL IMPEDANCE:"
SDisps"MAGNITUDE: "
Abs SDisps"PHASE ANGLE: "
Arg SDispsMenu "CLEAR TOTAL?","YES",Y,"NO",0
Lbl Y
0->S
"CLEARED!"DispsGoto 0
Lbl 6
Menu "WHAT TO STORE?","Z_->_X",M,"Z_->_Y",N,"S_->_X",O,"S_->_Y",P
Lbl M
Z->X
"DONE!"DispsGoto 0
Lbl N
Z->Y
"DONE!"DispsGoto 0
Lbl O
S->X
"DONE!"DispsMenu "CLEAR TOTAL?","YES",Y,"NO",0
Lbl Y
0->S
"CLEARED!"DispsGoto 0
Lbl P
S->Y
"DONE!"DispsMenu "CLEAR TOTAL?","YES",Y,"NO",0
Lbl Y
0->S
"CLEARED!"DispsGoto 0
Lbl 7
ClrText
"Z: "
ZDisps"S: "
SDisps"X: "
XDisps"Y: "
YDispsGoto 0
Lbl 8
0->Z
0->S
0->X
0->Y
"DONE!"DispsGoto 0
Lbl E
ClrText
Red Locate 5,4,"FX61 IMPEDANCE"

Note:  Disps:  ◢, ⊿
Imaginary:  i  [SHIFT] [ 0 ]

Program Calculator Listing:
"2019-09-09 EWS"
Deg
a+bi
ClrText
Red Locate 1,3,"NOTICE"
Blue Locate 1,5,"J is represented"
Blue Locate 1,6,"by i. (√-1)"
" "⊿
0->S
0->Z
0->X
0->Y
Lbl 0
ClrText
Menu "IMPEDANCE","COIL",1,"CAPACITOR",2,"PARALLEL",3,"SERIES RESISTOR",4,"ANALYSIS",5,"STORE IN X OR Y",6,"VIEW MEMORY",7,"CLEAR VARS",8,"EXIT",E
Lbl 1
"FREQ: "?->F
"INDUCTANCE: "?->L
2πLFi->Z⊿
S+Z->S
Goto 0
Lbl 2
"FREQ: "?->F
"CAPACITY: "?->C
(2πFCi)⁻¹->Z⊿
S+Z->S
Goto 0
Lbl 3
"PARALLEL IMPEDANCE"
"A||B"
"A: "?->A
"B: "?->B
(AB)÷(A+B)->Z⊿
S+Z->S
Goto 0
Lbl 4
"RESISTANCE: "?->R
R->Z⊿
S+Z->S
Goto 0
Lbl 5
"TOTAL IMPEDANCE:"
S⊿
"MAGNITUDE: "
Abs S⊿
"PHASE ANGLE: "
Arg S⊿
Menu "CLEAR TOTAL?","YES",Y,"NO",0
Lbl Y
0->S
"CLEARED!"⊿
Goto 0
Lbl 6
Menu "WHAT TO STORE?","Z->X",M,"Z->Y",N,"S->X",O,"S->Y",P
Lbl M
Z->X
"DONE!"⊿
Goto 0
Lbl N
Z->Y
"DONE!"⊿
Goto 0
Lbl O
S->X
"DONE!"⊿
Menu "CLEAR TOTAL?","YES",Y,"NO",0
Lbl Y
0->S
"CLEARED!"⊿
Goto 0
Lbl P
S->Y
"DONE!"⊿
Menu "CLEAR TOTAL?","YES",Y,"NO",0
Lbl Y
0->S
"CLEARED!"⊿
Goto 0
Lbl 7
ClrText
"Z: "
Z⊿
"S: "
S⊿
"X: "
X⊿
"Y: "
Y⊿
Goto 0
Lbl 8
0->Z
0->S
0->X
0->Y
"DONE!"⊿
Goto 0
Lbl E
ClrText
Red Locate 5,4,"FX61 IMPEDANCE"

The || is found in (CHAR), (MATH).

Examples:

Example 1:
Two coils in a series with inductance of 0.1 H and 0.2 H, respectively.  The frequency is 50 Hz. 

Sequence:
Option 1:  Enter 50 for frequency, 0.1 for inductance.
Option 1:  Enter 50 for frequency, 0.2 for inductance.
Option 5:  For analysis.

Total Impedance:  94.24777961i
Magnitude:  94.24777961
Phase Angle:  90°
(Clear the total)

Example 2:
A capacitor of 30 μF, a resistor of 10 Ω, and coil of 0.3 H are in a series.  Find the total impedance of the circuit if the frequency is 65 Hz.

Sequence:
Option 2:  Enter 65 for frequency, 30E-6 for capacity
Option 4:  Enter 10 for resistance
Option 1:  Enter 65 for frequency, 0.3 for inductance
Option 5:  For analysis

Total Impedance:  10 + 40.90419396i
Magnitude: 42.10882429
Phase Angle:  76.26214952°
(Clear the total)

Example 3:
Three resistors in parallel with 100 Ω, 200 Ω, and 400 Ω, respectively.  Find the total impedance.

Sequence:
Option 3:  Enter 100 for A and 200 for B.
Option 6:  Store S in X.  Clear the total.
Option 3:  Enter X for A and 400 for B.
Option 5:  For analysis

Total Impedance: 57.14285714
Magnitude: 57.14285714
Phase Angle: 0°

Eddie

All original content copyright, © 2011-2019.  Edward Shore.   Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited.  This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author.

HP Prime and TI-84+: RLC Parallel Circuit and Impedance

RLC Parallel Circuits and Impedance

 

Parallel RLC Circuit

The program RLCPAREL calculates:

* The total impedance of the circuit, and its magnitude in ohms

* Phase angle in a circuit in degrees.

* Current of the series in amps.

Input:

Battery/Source:  enter voltage and frequency

Add as many resistors (R) (in Ohms Ω), capacitors (C) (in farad), and inductors (L) (in henrys) as needed.

Notes:

HP Prime program only:  On the input screen, enter the real (a) and imaginary (if needed) (bi) parts separately.  Complex numbers can be directly entered on the TI-84+ program.

Example:

Parallel circuit powered by a 14 V, 5000 Hz battery.  The circuit has:

a resistor of 100 Ω, a capacitor of 3.2*10^-6 farads, and an inductor of 0.082 henrys.

Results:

Total Resistance:

0.987305540105 – 9.88715235955*i

Magnitude:

9.93632497508

Phase Angle:

84.2974952432

Current:

1.40897163037

HP Prime:  RLCPAREL

// Impedance of a Parallel

// EWS 2015-02-22

// Turn allow complex from real input on

// Declare subroutines

chsubr();

casubr();

// Main Routine

EXPORT RLCPAREL()

BEGIN

// initial steps

Z0:=0;

// radian mode

HAngle:=0;

// counter

I:=0;

// battery information

INPUT({V,F},"Battery Information",

{"V = ","F = "},

{"Volts","Frequency (Hz)"});

chsubr();

END;

// Choose Subroutine

chsubr()

BEGIN

LOCAL ch;

CHOOSE(ch,"# of Components: "+STRING(I),

{"Add Resistor (R)",

"Add Capacitor (C)",

"Add Inductor (L)",

"Calculate"});

// Execute calculation subroutine

casubr(ch);

END;

// Calculation Subroutine

casubr(x)

BEGIN

LOCAL a,b;

IF x==1 THEN

INPUT({a,b},"Add Resistor (Ω)",

{"a =","bi ="});

Z0:=Z0+1/(a+b*i);

I:=I+1;

chsubr();

END;

IF x==2 THEN

INPUT({a,b},"Capacitor (farad)",

{"a =","bi="});

Z0:=Z0-1/(i/(2*π*F*(a+b*i)));

I:=I+1;

chsubr();

END;

IF x==3 THEN

INPUT({a,b},"Inductor (henry)",

{"a =","bi="});

Z0:=Z0+1/(i*2*π*F*(a+b*i));

I:=I+1;

chsubr();

END;

// Termination

IF x==4 THEN

Z0:=1/Z0;

PRINT();

PRINT("Total Resistance = "+Z0);

PRINT("Magnitude (Ω) = "+ABS(Z0));

PRINT("Phase Angle (°) ="+

STRING(−ARG(Z0)*180/π));

PRINT("Current (amps) = "+

STRING(V/ABS(Z0)));

RETURN Z0;

END;

END;

TI-84+: RLCPAREL

a+bi   // Complex mode

Radian  // Radians mode

0→Z

Disp “BATTERY”

Disp “V = VOLT”

Disp “F = FREQ (HZ)”

Prompt V,F

Lbl 0

Menu(“CIRCUIT”,”+ RESISTOR”,1,”+ CAPACITOR”,2,

“+ INDUCTOR”,3,”CALCULATE”,4)

Lbl 1

Input “R (OHMS):”,R

Z+1/R→Z

Goto 0

Lbl 2

Input “C (FARAD):”,C

Z-(2πFC)/i→Z

Goto 0

Lbl 3

Input “L (HENRY):”,L

Z+1/(i2πFL)→Z

Goto 0

Lbl 4

1/Z→Z

Disp “IMPEDANCE=”

Pause Z

Disp “MAGNITUDE=”

Pause abs(Z)

Disp “PHASE ANGLE (°)=”

Pause -angle(Z)*180/π

Disp “CURRENT (AMPS)=”

Pause V/abs(Z)

Sources:

ElectronicsTutorials.  Parallel RLC Circuit Analysis  URL: 

http://www.electronics-tutorials.ws/accircuits/parallel-circuit.html

Retrieved February 22, 2015

Van Valkenburg, Mac E. (Editor) and Wendy M. Middelton (Editor)

"Reference Data for Engineers: Radio, Electronics, Computer, and

Communications"  9th Edition.  Newnes, Butterworth-Heinemann:  Wolburn,

MA  2002.  Print.

This blog is property of Edward Shore.  2015.