Plots of x^t + y^t = n^t (x, y, n are integers)

Happy Friday almost July 2013!

This is a series of plots of the following:

1. x^2 + y^2 = n^2
2. x^2 + y^2 = n^3
3. x^3 + y^3 = n^2
4. x^3 + y^2 = n^2
5. x^3 + y^2 = n^3

For x, y, and n all integers. Plots are pointed for combinations where the result, n, is an integer. The range tested is 0 ≤ x ≤ 200 and 0 ≤ y ≤ 200. I used the TI nSpire CX CAS iOS app.

How many points?

1. x^2 + y^2 = n^2, 703 points
2. x^2 + y^2 = n^3, 55 points
3. x^3 + y^3 = n^2, 97 points
4. x^3 + y^2 = n^2, 375 points
5. x^3 + y^2 = n^3, 213 points, mostly when y=0

Program Outline: (for plot 1, similar format for the rest)
Define test()
Prgm
xs:={ }
ys:={ }
For k,0,200
For l,0,200
If iPart(√(k^2+l^2))=0 Then
xs:=augment(xs,{k})
ys:=augment(ys,{l})
EndIf
EndFor
EndFor
EndPrgm


And now to the fun part... Enjoy!

That's it for now - as always thanks for your support and words of encouragement and your questions. :)

Eddie


This blog is property of Edward Shore. 2013

Integers: x^5 + y^5 = n^2, x^2 + y^2 = n^5, x^2 + y^3 = n^2 and x^3 + y^2 = n^3

Let x, y, and n be integers.

x^2 + y^2 = n^5

x and y tested: 1 ≤ x ≤ 30, 1 ≤ y ≤ 30

What I found: (there may be more outside the range I tested)
4^2 + 4^2 = 2^5
(Thank you Bill Zimmerly for pointing out my typo! (32 is not 5^3))

HP 32sii Program:

LBL E
x^2
x<>y
x^2
+
5
x√y
RTN

---

x^5 + y^5 = n^2

x and y tested: 1 ≤ x ≤ 30, 1 ≤ y ≤ 30

Again, I am looking for combinations where x, y, and n are all integers.

In the range tested I found:
2^5 + 2^5 = 8^2
8^5 + 8^5 = 256^2
18^5 + 18^5 = 1944^2

HP 32Sii Program:

LBL F
5
y^x
x<>y
5
y^x
+
√
RTN

---

The next program will cover two explorations. I will present the program first, then the equations.

HP32Sii Program:
LBL G
x^2
x<>y
3
y^x
+
ENTER
√ \\ √(x^2 + y^3)
R/S
x<>y
3
x√y \\cube root of (x^2 + y^3)
RTN

I used this program for two tests. The area tested was 1 ≤ x ≤ 16 and 1 ≤ y ≤ 16. I am looking for combinations where x, y, and n are integers.

x^2 + y^3 = n^2

2^3 + 1^2 = 3^2
3^3 + 3^2 = 6^2
4^3 + 6^2 = 10^2
5^3 + 10^2 = 15^2
6^3 + 3^2 = 15^2
8^3 + 8^2 = 24^2
12^3 + 6^2 = 42^2
12^3 + 11^2 = 43^2
3^3 + 13^2 = 14^2
4^3 + 15^2 = 17^2
6^3 + 15^2 = 21^2
10^3 + 15^2 = 35^2
15^3 + 15^2 = 60^2

x^2 + y^3 = n^3

7^3 + 13^2 = 60^2

---

Happy June Solstice!

Eddie


This blog is property of Edward Shore. 2013

Integers: x^2 + y^2 = n^3, x^3 + y^3 = n^2, x^2 - y^2 = n^3, x^3 - y^3 = n^2

Let x, y, n be integers. I explore x and y for 1 through 15. I use an HP 32Sii to help me with the calculations.

x^2 + y^2 = n^3

2^2 + 2^2 = 2^3
2^2 + 11^2 = 5^3
5^2 + 10^2 = 5^3

Program:

LBL A
x^2
x<>y
x^2
+
3
1/x
y^x
RTN

x^3 + y^3 = n^2

1^3 + 2^3 = 3^2
2^3 + 2^3 = 4^2
8^3 + 4^3 = 24^2
8^3 + 8^3 = 32^2

Program:

LBL B
3
y^x
x<>y
3
y^x
+
√
RTN

x^2 - y^2 = n^3, x > y

15^2 - 10^2 = 5^3
15^2 - 3^2 = 6^3
14^2 - 13^2 = 3^3
10^2 - 6^2 = 4^3
6^2 - 3^2 = 3^3
3^2 - 1^2 = 2^3

Program:

LBL C
x^2
x<>y
x^2
x<>y
-
3
x√y
RTN

x^3 - y^3 = n^2, x > y

14^3 - 7^3 = 49^2
10^3 - 6^3 = 28^2
8^3 - 7^3 = 13^2

Program:

LBL D
3
y^x
x<>y
3
y^x
x<>y
-
√
RTN

If you want to find more integer triplets, happy exploring!

To all the dads out there - Happy Father's Day! To my dad, I am so proud of you!

Until next time,

Eddie


Happy One Week from the Summer Solstice!


This blog is property of Edward Shore. 2013

HP35S Music Pitch: Next Half-Step Up and Down

HP35S Music Pitch: Next Half-Step Up and Down

Source: "Sourcebook for Programmable Calculators" Texas Instruments (TI-58/59) - 1978 (,I believe, apologize if get the year wrong)

next pitch = original pitch * (twelfth root of 2) ≈ original pitch * 1.05946309436

Pitch is in HZ (Hertz)

256 Hz one octave lower than Middle C
512 Hz Middle C
1024 Hz one octave higher than Middle C

Steps: C C# D D# E F F# G G# A A# B

HP35S Program:
Next half-step up: pitch, XEQ M001
Next half-step down: pitch, XEQ M009
Repeat each step with R/S, stop whenever you like

M001 LBL M
M002 2
M003 12
M004 1/x
M005 y^x
M006 *
M007 R/S
M008 GTO M001
M009 2
M010 12
M011 1/x
M012 y^x
M013 ÷
M014 R/S
M015 GTO M009


Program made on 4/27/2013

Have fun and thanks for your support! Always appreciate the comments and followers! Eddie

This blog is property of Edward Shore. 2013

HP 35S: Sun Altitude, Azimuth, Solar Pond Absorption

HP 35S: Sun Altitude, Azimuth, Solar Pond Absorption

Source: Sun Altitude, Azimuth, Solar Pond Absorption, HP 67/97 Energy Conservation December 1978, Author: HP

Input:

This program asks for:

D = days after March 21 (later will be sun's declination : 23.45 sin (D * .9856°) )
L = latitude given in D.MMSS (degrees minutes seconds) format (avoid ±90°)
T = time before solar noon (12:00 PM), if the time is after noon, enter hours as a negative (example: 3:00 PM → -3)
N = index of refraction of surface/fluid (see below)

---

Index of Refraction for Common Objects:

Water: 1.33
Ice: 1.309
Glass: 1.52
Diamond: 2.42

---

Formulas: (Degrees Mode)

Sun Declination
D = 23.45 * sin( days after March 21 * .9856°)

Altitude of the Sun (H):
H = asin (cos L * cos D * cos (15 * T) + sin L * sin D)

Azimuth of the Sun (A): (degree from latitude ground wise north)
A = acos ( (sin H * sin L - sin D) ÷ (cos L * cos H) )

Fraction of the surface penetrated by the sun that hour (T):
T = 2 * n * (x^2 + y^2) * sin H * cos R
Where
R = asin (cos H ÷ n)
x = (cos R + n * sin H)^-1
y = (sin H + n * cos R)^-1

Example 1:

Input:
D = 68 (May 28), L = 46°, T = 4 (8:00 AM), N = 1.33 (water)

Output:
H (altitude) = 35.98991°
A (azimuth) = 84.40835°
F (fraction of coverage) = 0.95943

Example 2:

Input:
D = 90 (June 19), L = 23°, T = -3 (3:00 PM), N = 2.42 (diamond)

Output:
H = 48.81756°
A = 99.85903°
F = 0.82156

---

Program:

U001 LBL U
U002 INPUT D \\ declination
U003 DEG
U004 0.9856
U005 *
U006 SIN
U007 23.45
U008 *
U009 STO D \\ altitude
U010 COS
U011 INPUT L
U012 HMS→ \\ or → H
U013 STO L
U014 COS
U015 *
U016 INPUT T
U017 15
U018 *
U019 COS
U020 *
U021 RCL L
U022 SIN
U023 RCL D
U024 SIN
U025 *
U026 +
U027 ASIN
U028 STO H
U029 VIEW H \\ azimuth
U030 SIN
U031 RCL L
U032 SIN
U033 *
U034 RCL D
U035 SIN
U036 -
U037 RCL L
U038 COS
U039 RCL H
U040 COS
U041 *
U042 ÷
U043 ACOS
U044 STO A
U045 VIEW A

U046 RCL H \\ fraction
U047 COS
U048 INPUT N
U049 ÷
U050 ASIN
U051 STO R
U052 COS
U053 RCL H
U054 SIN
U055 RCL* N
U056 +
U057 1/x
U058 x^2
U059 RCL H
U060 SIN
U061 RCL R
U062 COS
U063 RCL* N
U064 +
U065 1/x
U066 x^2
U067 +
U068 RCL* N
U069 2
U070 *
U071 RCL H
U072 SIN
U073 *
U074 RCL R
U075 COS
U076 *
U077 STO F
U078 VIEW F
U079 RTN

---

This blog is property of Edward Shore. 2013

HP35S Fraunhofer Diffraction - Spherical

HP35S Fraunhofer Diffraction - Spherical
Source: HP 67/97 Optics Pac, June 1978

This version takes advantage of the HP's integral function. The trade off is that two labels are required. On the plus side, this program can be typed directly into a 32Sii or 33S.

Labels: F (Main), G (Integral)

Variables:

D = diameter in microns (10^-6 meters)
L = wavelength of light in microns (10^-6 meters)
A = θ, angle of the slit, entered in degrees

Formulas:

X = π D ÷ L
W = X sin A
J = int(cos(T - W sin T) dT, 0, π)/π
I = (X^2 J ÷ W)^2

Output:

Bessel function of the first kind (J) - paused for 2 seconds;
Fraunhofer Intensity (I) - dimensionless - as I understand it, this is how intense the diffraction is

Programs:

LBL F
INPUT D
INPUT L
÷
π
*
STO X
INPUT A
→RAD
STO A
SIN
*
STO W
RAD
0
π
FN= G
∫ FN dT
STO J \\ Bessel store in J for future use, if desired
PSE
PSE
RCL ÷ W
RCL X
x^2
*
x^2
RTN

LBL G
COS(T-W*SIN(T))/π \\ enter as an equation (press [EQN])
RTN

---

This blog is property of Edward Shore. 2013

HP 35S: Spherical Triangle

(First draft?)

Formulas:
sin A / sin a = sin B / sin b = sin C / sin c
cos A = - cos B cos C + sin B sin C cos a
cos a = cos b cos c + sin b sin c cos A

A, B, C are angles formed by the great circles (the "lines" of the Spherical triangle). Note that A + B + C > 180°. a, b, and c measure the arc length of great circles as angles measured from the center of the sphere.

Source: http://www.krysstal.com/sphertrig.html

Program: Label S
Calculator: HP 35S

I am not sure if I covered all possible scenarios.

Memory registers B and C are used for temporary purposes.

Given: B, A, b; Goal: a; Label S001
S001 LBL S
S002 SIN
S003 x<>y
S004 SIN
S005 ÷
S006 x<>y
S007 SIN
S008 ×
S009 ASIN
S010 RTN

Given: b, a, B; Goal: A; Label S011
S011 SIN
S012 x<>y
S013 SIN
S014 ×
S015 x<>y
S016 SIN
S017 ÷
S018 ASIN
S019 RTN

Given: a, b, c; Goal: A; Label S020
S020 STO C
S021 COS
S022 x<>y
S023 STO B
S024 COS
S025 ×
S026 x<>y
S027 COS
S028 x<>y
S029 -
S030 RCL B
S031 SIN
S032 RCL C
S033 SIN
S034 ×
S035 ÷
S036 ACOS
S037 RTN

Given: b, A, c; Goal: a; Label S038
S038 STO C
S039 SIN
S040 x<>y
S041 COS
S042 ×
S043 x<>y
S044 STO B
S045 SIN
S046 ×
S047 RCL C
S048 COS
S049 RCL B
S050 COS
S051 ×
S052 +
S053 ACOS
S054 RTN

Given: A, B, C; Find: a; Label S055
S055 STO C
S056 COS
S057 x<>y
S058 STO B
S059 COS
S060 ×
S061 x<>y
S062 COS
S063 +
S064 RCL B
S065 SIN
S066 RCL C
S067 SIN
S068 ×
S069 ÷
S070 ACOS
S071 RTN

---

Examples:


Given: B = 3.2145°, A = 2.2718°, b = 40°; XEQ S001; Result: a ≈ 65.4058°

Given: b = 60°, a = 40°, B = 4.95°; XEQ S011; Result A ≈ 3.6720°

Given: a = 4.11°, b = 5°, c = 6.03°; XEQ S020; Result A ≈ 42.5439°

Given: b = 3.996°, A = 49°, c = 6.314°; XEQ S038; Result a ≈ 4.7636°

Given: A = 124°, B = 45°, C = 76°; XEQ S055; Result a ≈ 124.4509°

Enjoy - hope this helps and have a great day!

Eddie

This blog is property of Edward Shore. 2013

HP 35S: Planar Triangles

This program is set to solve common problems in plane (regular) triangles.

The programs can be adapted to any side lengths and angles necessary.

Variables of Plane Triangles

Side length a with corresponding angle A,
Side length b with corresponding angle B, and
Side length c with corresponding angle C.

Labels and Stack Set Up: HP 35S

Angle-Angle-Side, Label P001, Stack: B, A, b, Goal: a

Side-Side-Angle, Label P009, Stack: b, a, B, Goal: A

Angle-Side-Angle, Label P015, Stack: b, A, c, Goal: a

Side-Side-Side, Label P033, Stack: a, b, c, Goal: A (angle corresponding to first side length entered)

* If you use a 15C, 32Sii, or other another RPN calculator, you will need to create four labels. The nice thing with the HP 35S is that you can create multiple programs within in one label. Memory registers B and C are temporary.

Program P (Planar Triangles)

\\ Angle-Angle-Side: Law of Sines
\\ Stack: B, A, b; Find: a

P001 LBL P
P002 x<>y
P003 SIN
P004 ×
P005 x<>y
P006 SIN
P007 ÷
P008 RTN

\\ Side-Side-Angle: Law of Sines
\\ Stack: b, a, B; Find: A
P009 SIN
P010 ×
P011 x<>y
P012 ÷
P013 ASIN
P014 RTN

\\ Side-Angle-Side: Law of Cosines
\\ Stack: b, A, c; Find: a
P015 STO C
P016 x<>y
P017 COS
P018 ×
P019 x<>y
P020 STO B
P021 ×
P022 2
P023 ×
P024 +/-
P025 RCL B
P026 x^2
P027 +
P028 RCL C
P029 x^2
P030 +
P031 √
P032 RTN

\\ Side-Side-Side: Law of Cosines
\\ Stack: a, b, c; Find: A
P033 STO C
P034 x^2
P035 x<>y
P036 STO B
P037 x^2
P038 +
P039 x<>y
P040 x^2
P041 -
P042 2
P043 ÷
P044 RCL÷ B
P045 RCL÷ C
P046 ACOS
P047 RTN

---

Examples (Degrees Mode Used):
AAS: B = 30, A = 40, b = 4; a ≈ 5.1423

SSA: b = 5, a = 4, B = 90°; A ≈ 53.1301°

SAS: b = 8, A= 30°, c = 9; a ≈ 4.5047

SSS: a = 5, b = 4, c = 3; A = 90°

---

Hope this helps. I plan to post a program regarding spherical triangles.

Take care,

Eddie


This blog is property of Edward Shore. 2013

HP 35S: Approximate Length of Sunlight During a Day

HP 35S: Length of Sunlight During a Day

Source: Total Daily Amount of Solar Radiation - HP 67/97 Energy Conservation Pac, December 1978, Author: Hewlett Packard

(This is a slight variation instead of a direct port)

Input

You are prompted for D and L where:
D = the number of days from March 21, a 365 day year is assumed
L = latitude (North as positive, South as negative), entered as D.MMSS (degrees-minutes-seconds) format

Output

Approximate number of hours of sunlight, in hours, minutes, seconds

Examples

Los Angeles, April 17: latitude of 34°03' N, 27 days after March 21
D = 27, L = 34.03, answer is approximately 12.573501 (12 hours, 57 minutes, 35.01 seconds)

Rome, September 1: latitude 41°51' N, 164 days after March 21
D = 164, L = 41.52, answer is approximately 12.532269 (12 hours, 53 minutes, 22.69 seconds)

Sydney, June 21: latitude 33°51'31" S, 92 days after March 21
D = 92, L = -33.5131, answer is approximately 9.443922 (9 hours, 44 minutes, 39.22 seconds)

Formulas

This version uses the estimate of sun declination:
D = 23.45 sin(d * 0.9856°)

Since 360/365.25 ≈ 0.985626283368

θ = acos(-tan L × tan D)

L = 24 * θ in radians ÷ π

Program
S001 LBL S
S002 DEG
S003 INPUT D
S004 0.9856
S005 ×
S006 SIN
S007 23.45
S008 ×
S009 INPUT L
S010 HMS→
S011 TAN
S012 x<>y
S013 TAN
S014 ×
S015 +/-
S016 ACOS
S017 ->RAD
S018 24
S019 ×
S020 π
S021 ÷
S022 ->HMS
S023 RTN


This blog is property of Edward Shore. 2013

HP 35S: Air Density & Density Altitude (Metric-US Conversion Factors included)

HP 35S: Air Density & Density Altitude (7 Digit Accuracy*)

*You can use 4 or 5 digits for the HP 15C and other RPN calculators on which each number takes a step. Slightly less accuracy but smaller program.

Source: Shelquist Engineering web page: http://wahiduddin.net/calc/density_altitude.htm

Formulas

Air Density:

D = P ÷ (R * T)
D = density in kg/m^3
P = pressure in Pascals (Pa)
T = temperature in Kelvins
R = specific gas constant = 287.05 J/(kg*°K)

Air Density Altitude: (where the plane/vehicle thinks it is)
H = 44.3307692 - 42.2665143 * D^0.2349695

H = air density in km

U.S.-SI Conversion Factors
Pressure: (convert and store in P)
1 inHg = 2275.5477799 lb/(ft*s^2) = 3386.3881579 Pa

Temperature Conversion Formula: (convert and store in T)
°K = 5/9 * (°F - 32) + 273.15

Length:
1 km = 3280.8398950 ft

Program
D001 LBL D
D002 INPUT P
D003 287.05
D004 INPUT T
D005 *
D006 ÷
D007 STO D
D008 VIEW D \\ display air density in kg/m^3
D009 0.2349696 \\ dimensionless constant
D010 y^x
D011 42.2665143
D012 *
D013 +/-
D014 44.3307692
D015 +
D016 STO H
D017 RTN \\ display density altitude


I chose to use SI units because the constants are much smaller than the formula would be in US units.

This blog is property of Edward Shore. 2013

HP35S: Distance to Horizon

HP35S Distance to Horizon

Calculator: HP 35S

Sources:
* HP 65 Navigation Pac-1 - published in 1974
* Bad Astronomy by Discovery Magazine: http://blogs.discovermagazine.com/badastronomy/2009/01/15/how-far-away-is-the-horizon/#.UYCEhMu9KSM
* Wikihow Article: http://m.wikihow.com/Calculate-the-Distance-to-the-Horizon

Input
Height above sea level, the height includes the height of the land (if any) and the distance to your eyes or eyepiece.

Output
Approximate distance to the horizon in miles.

Conversions
If you use metric, use these conversions before/after running the program:
1 m = 3.28083989501 ft
1 mi = 1.609344 km

Formula
Updated formula based on radius on Earth on average 3,959 miles.
D ≈ √(1.49922*H + H^2)
H is in feet, D is in miles

Example
H = 3 ft, D ≈ 3.67392 miles

Program
H001 LBL H
H002 ENTER
H003 ENTER
H004 1.49922
H005 *
H006 x<>y
H007 x^2
H008 +
H009 √
H010 RTN

This blog is property of Edward Shore. 2013

HP35S Vertical Curve: Elevation at Peak and at End Point

HP35S Vertical Curve: Elevation at Peak and Length

Source: Fundamental of Engineering Supplied-Reference Handbook 8th Ed, 2nd Revision, 2011, NCEES

Calculator: HP 35S

Input
I = initial height
G = grade 1; entering the curve (in decimal form)
H = grade 2; exiting the curve (in decimal form)
L = horizontal length of the curve

G and H are the opposite signs

If G>0 and H<0 a="" and="" curve="" g="" h="" has="" if="" peak.="" similarity="" the="">0, the curve has a valley.

The program listed prompts for the inputs.

Output
1. Point where the curve reaches extreme elevation
2. Press R/S to get the elevation at the extreme point.
3. Press R/S once more to get the elevation at the end of the curve.

None of the outputs are stored.

Formula
A = (G - H)/(2L)
X_extrema = -G/(2A)
Equation of the Curve: y = I + G*x + A*x^2

Examples
Uphill curve:
I = 1,000 ft
G = 7% = 0.07
H = -4% = -0.04
L = 1,368 ft

Point at peak elevation is 870.545 ft into the curve at 1,030.469 ft. The elevation at the end of the curve is 1,020.520 ft.

Downhill curve:
I = 1,580 ft
G = -3% = -0.03
H = 4.2% = 0.042
L = 2.3 mi = 12,144 ft

Point at trough elevation occurs 5,060 ft into the curve at elevation 1,504.1 ft. The elevation at the end of the curve is at 1,652.864 ft.

Program
V001 LBL V
V002 INPUT I
V003 INPUT G
V004 INPUT H
V005 INPUT L
V006 RCL H
V007 RCL - G
V008 2
V009 ÷
V010 RCL ÷ L
V011 STO A
V012 RCL G
V013 x<>y
V014 ÷
V015 2
V016 ÷
V017 +/-
V018 R/S \\ shows point where extreme elevation occurs
V019 XEQ V024
V020 R/S \\ shows extreme elevation
V021 RCL L
V022 XEQ V024 \\ shows ending elevation
V023 RTN
V024 ENTER \\ calculate y subroutine
V025 RCL × A
V026 RCL + G
V027 ×
V028 RCL + I
V029 RTN


This blog is property of Edward Shore. 2013

HP35S: Horizontal Curve - Finding Radius, Chord Length, and Arc Length

HP 35S: Horizontal Curve
Original: HP 33S Surveying Applications, Hewlett Packard, March 1978, pg. 46


Calculator
HP 35S

Input
(see diagram above)

T = Tangent Distance (length of segment from P.C. (Point of Curvature) to P.I. (Point of Tangent Intersection))
A = Central curve in degrees, minutes, seconds

This program prompts for tangent length and central angle

Output

The program gives the following results:
1. Radius of the horizontal curve (R)
2. Press R/S to get the Chord length (C)
3. Press R/S once more to get the arc length of the horizontal curve (L)

The program does not store any results.

Formulas
R = T × (tan(A/2))⁻¹
C = 2 × R × sin(A/2)
L = R × A in radians

Where
T = tangent distance
A = central angle
R = Radius
C = Chord Length
L = Arc Length

Example
Tangent Length: 172.45
Central Angle: 40°22'13" (enter as 40.2213)

Results:
Radius: 469.08079
Chord Length: 323.7172
Arc Length: 330.51163

Program
V001 LBL V
V002 DEG
V003 INPUT T
V004 INPUT A
V005 HMS→\\ sometimes named ->H
V006 STO A
V007 2
V008 ÷
V009 TAN
V010 1/x
V011 ×
V012 R/S \\ display Radius
V013 ENTER
V014 ENTER
V015 2
V016 ×
V017 RCL A
V018 2
V019 ÷
V020 SIN
V021 ×
V022 R/S \\ display Chord Length
V023 x<>y
V024 RCL A
V025 ->RAD
V026 ×
V027 RTN \\ display Arc Length

If you don't have the ->RAD function, you can substitute the following steps:
π, ×, 180, ÷

This blog is property of Edward Shore. 2013

HP15C: Julian Date from Gregorian Date

Thanks to the University of Texas at San Antonio Computer Science Department. The explanation and formulas can be found by clicking on this link.

Note: This program only works for dates on or after October 15, 1582. Thank you Dieter.


Calculator
HP 15C (can be adopted with any RPN keystroke calculator)

Input
Preload the following information into these registers:
R1 = month (1 for January, 12 for December)
R2 = date
R3 = year in four digits (example: 2013)

Output
R0 = Julian Date

Temporary
R4 = a = integer((14-month)/12)
R5 = y = year + 4800 - a

Formulas
(See link above)
a = integer((14-month)/12)
y = year + 4800 - a
m = month + 12a - 3
Julian Date = day + integer((153m+2)/5) + 365y + integer(y/4) - integer(y/100) + integer(y/400) - 32045

Assumptions: 12:00 PM Universal Time is assumed (that's 7:00 AM in Pacific Standard Time or 8:00 AM in Pacific Daylight Savings Time)

Program
LBL A
1
4
RCL - 1
1
2
÷
INT
STO 4
4
8
0
0
RCL + 3
RCL - 4
STO 5
RCL 2
STO 0
1
2
RCL × 4
RCL + 1
3
-
1
5
3
×
2
+
5
÷
INT
STO + 0
3
6
5
RCL × 5
STO + 0
RCL 5
4
÷
INT
STO + 0
RCL 5
1
%
CHS
INT
STO + 0
RCL 5
4
÷
1
%
INT
STO + 0
RCL 0
3
2
0
4
5
-
STO 0
RTN


In HP RPN calculators, a number followed by 1, %, divides said number by 100.

Example:

March 14, 1977 has a Julian Date of 2,443,217
April 28, 2012 has a Julian Date of 2,456,046
December 31, 2015 has a Julian Date of 2,457,388

This blog is property of Edward Shore. 2013