HP 12C Platinum: Present Value of a Fractional Year

 HP 12C Platinum: Present Value of a Fractional Year

This blog features the HP 12C Platinum, HP 10BII+, and HP 22S calculators.

Short Term Transactions

Here is the scenario: A bank offers a short term bond, which last less than one year, which pays $100.00 at maturity date. The interest rate stated is an annual interest rate. While determining a pricing schedule, one banker uses an HP 12C Platinum calculator while another uses the HP 10BII+ calculator. They both use the TVM (time value of money) keys. A 365-day year is used.

FV = -100, I% (see table), N (see table), PMT = 0, Solve for PV, P/Y = 1

Term (days)	N = term ÷ 365 (to five decimal places) (for reference)	I%	HP 12C Platinum (to 5 decimal places)	HP 10BII+ (to 5 decimal places)
89	0.24384	5	98.79551	98.81737
141	0.38630	5	97.99973	98.02800
181	0.49589	5	97.58054	97.60958
365	1	5	95.23810	95.23810
89	0.24384	8	98.08664	98.14091
141	0.38630	8	96.83753	96.90714
181	0.49589	8	96.18425	96.25548
365	1	8	92.59259	92.59259

As you can see, the results are different! Why?

According to HP-12C Solutions Handbook (see the Source section), when it comes to fractional periods, simple interest is used instead of compound interest in the TVM solver. Most financial calculators, such as HP 10BII+ always uses compound interest.

Cash flow convention states that:

1. Cash inflows, such as deposits, are positive.

2. Cash outflows, such as payments, are negative.

3. In most problems, the present value and future value have opposite signs.

Respecting cash flow convention, the formulas for present value are:

Simple Interest:

P = -F ÷ (1 + D ÷ 365 × I ÷ 100)

Compound Interest:

P = -F ÷ (1 + I ÷ 100) ^ (D ÷ 365)

where:

P = present value (PV)

F = future value (FV)

I = annual interest rate

D = number of days

If leap years, substitute 366 for 365. If we are working with 30/360 day years, substitute 360 for 365.

These formulas are set up to be entered in calculators with equation solvers such as the HP 22S. I have used the HP 22S to verify each of the results above.

Now why is the results the say when the term exactly 365? It’s pretty simple to prove:

Simple Interest:

P_simple = -F ÷ (1 + 365 ÷ 365 × I ÷ 100) = -F ÷ (1 + I ÷ 100)

Compound Interest:

P_compound = -F ÷ (1 + I ÷ 100) ^ (365 ÷ 365) = -F ÷ (1 + I ÷ 100) = P_simple

When the Term Exceeds One Year

Let’s say the $100.00 bond lasts for 545 days, about one year and a half. This time the interest rate is 7%.

On the HP 12C, any fractional period is treated with simple interest. The HP 12C’s TVM solver (and the HP 12C Platinum) treats the timeline as such.

365 days: full period, compound interest	180 days: partial year, simple interest
PV	FV = -$100.00

To break it down, the HP 12C starts determining the value after 365 days.

N = 180 ÷ 365

I = 7

FV = -100

PV ≈ 96.66314

P = -(-100) ÷ (1 + 180 ÷ 365 × 7 ÷ 100) ≈ 96.66314

365 days: full period, compound interest	180 days: partial year, simple interest
PV	FV = -$100.00
	96.66314

From here, the HP 12C uses that value to calculate final present value. Since we are now working with a full period (one year in this case), compound interest is used with n = 1:

N = 1

I = 7

FV ≈ -96.66314 (treated as an outflow and becoming the acting future value)

PV ≈ -(-96.6314 ÷ (1 + 7 ÷ 100) ^ (1) ≈ 90.33938

The final present value (and price) of this bond is 90.33938.

If we enter following the HP 12C Platinum:

N: 545 [ ENTER ] 365 [ ÷ ] [ N ] (≈ 1.49315)

I: 7 [ i ]

FV: 100 [ CHS ] [ FV ]

PMT: 0 [ PMT ]

[ PV ] → PV ≈ 90.33938

Enter the same problem on most other financial calculators, like the HP 10BII+, will result in a final present value of 90.39108. (P/Y = 1) This is because compounding interest is used for the entire time:

P = -(-100) ÷ (1 + 7 ÷ 100) ^ (545 ÷ 365) ≈ 90.39108

HP 12C Program: Present Value Using Compounding Interest Including Fractional Periods

The program calculates present value given the future value, interest, and the number of days using compounding interest for the entire period. A 365 day year is assumed.

Code: Key; Key Code

ENTER; 36

3; 3

6; 6

5; 5

÷; 10

1; 1

RCL i; 45, 12

%; 25

+; 40

x<>y; 34

y^x; 21

RCL FV; 45, 15

x<>y; 34

÷; 10

CHS; 16

GTO 000; 43,33,000 (GTO 00; 43, 33,00 for HP 12C Classic)

Future value is stored in FV and interest rate is stored in i. The number of days is on the X stack.

Source

Hewlett Packard. HP-12C Solutions Handbook. 2004. pg. 45 https://literature.hpcalc.org/official/hp12c-sh-en.pdf

Eddie

All original content copyright, © 2011-2026. Edward Shore. Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited. This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author.

HP 12C Platinum: RC Series Circuit Analysis

HP 12C Platinum: RC Series Circuit Analysis

The program was originally posted on the Museum of HP Calculators website (https://www.hpmuseum.org/forum/thread-24591-post-215436.html#pid215436).

A difference between the HP 12C Platinum and the HP 12C Classic is that the Platinum has a square function (x²). The square function is the g-shifted (blue) of the multiplication key.

Introduction and Program Code

Given the following of a RC series circuit:

Stack Z: E: voltage of the RC circuit

Stack Y: R: resistance of the resistor (R) in ohms (Ω)

Stack X: Xc: equivalent resistance of capacitor (Xc) in ohms (Ω)

What is calculated:

Stack Z: equivalent impedance of the RC series circuit in ohms (Ω), Z = √(R^2 + Xc^2)

Stack Y: current in amps (A), I = E ÷ Z

Stack X: true power in watts (W), P = I^2 * R

Program Code:

x^2	001	43, 20	beginning of the program
x<>y	002	34
STO 0	003	44, 0	store resistor
x^2	004	43, 20
+	005	40
√x	006	43, 21
PSE	007	43, 31	show impedance
ENTER	008	36
R↓	009	33
÷	010	10
PSE	011	43, 31	show current
ENTER	012	36
x^2	013	43, 20
R↓	014	33	stack manipulation (014 – 018)
R↓	015	33
x<>y	016	34
R↓	017	33
R↓	018	33
RCL 0	019	45, 0
×	020	20
GTO 000	021	43, 33, 000	finish program, show power

Example

E = 150 V

R = 19 Ω

Xc = 10 Ω

Results (to four decimal places):

Z ≈ 21.4709 Ω

I ≈ 6.9862 A

P ≈ 927.3319 W

Source

Noll, Edward M. Basic Electronics Math With a Scientific Calculator Howard W. Sams & Co, Inc. Indianapolis, IN. 1977. 0-672-21425-3 pp. 81-98

Eddie

All original content copyright, © 2011-2026. Edward Shore. Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited. This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author.

HP 12C Platinum: Property Value by Income and Reversion Method

HP 12C Platinum: Property Value by Income and Reversion Method

Property Valuation

One way to calculate the value of property is by its income and reversion value. 

In this case, the income is the estimated annual net income before taxes which is assumed to be "paid out" at the end of each year.  This income stream is sometimes known as an Inwood annuity cash flow.

The reversion value of a property is its future value based on factors like inflation, anticipated selling price at the end of the project, and the current market value.  The economic life of the property is not necessarily the remaining physical life of the property.   In a time value of money timeline, the reversion value would be received at the end of the project.

Calculating the value of the property using this income method uses three steps, as illustrated by the Board of Equalization (see the Source section below):

1.  Calculate the value of the income stream, called the net income before taxes (NBIT):

PV_income = NBIT ÷ (SFF + yield% + tax_rate%)

where:

SFF = yield% ÷ ((1 + yield%)^n - 1)

yield% and tax_rate% are expressed in decimal form (Example: 0.05 for 5%)

We can use the TVM keys to calculate ((1 + yield%)^n - 1) by setting the following values:

n,  yield → I/YR%, -1 → PV, 0 → PMT, solve for FV.

Then:  SFF = yield% ÷ FV

2.  Value of the reversion value.

PV_reversion = reversion_value × (1 + (yield% + tax_rate%))^(-n)

We can use the TVM keys to calculate (1 + (yield% + tax_rate%))^(-n)

by setting the following values:

n,  yield + tax_rate → I/YR%, 0 → PMT, -1 → FV, solve for PV.

3.  Calculate the total property value.

Property Value = PV_reversion + PV_income

HP 12C Platinum Program:  Property Value by Reversion Method

Store before running the program:

n =  number of years of remaining economical life of the property

i = yield interest rate

R7 = property tax rate

R8 = net income before taxes (NBIT)

R9 = expected revision value of the property (the value of the property at the end of it's economic life)

Code:

step;  key code;  key

001;  0;  0

002;  44,0;  STO 0

003;  1;  1

004;  16;  CHS

005;  13;  PV

006;  0;  0

007;  14;  PMT

008;  15;  FV

009;  1;  1

010;  30; - 

011;  22; 1/x

012;  45,12;  RCL i

013;  25;  %

014;  45,12;  RCL i

015;  1;  1

016;  25;  %

017;  34;  x<>y

018;  33;  R↓

019;  40;  +

020;  45, 7;  RCL 7

021;  1;  1

022;  25;  %

023;  34;  x<>y

024;  33;  R↓

025;  40;  +

026;  45, 8;  RCL 8

027;  34;  x<>y

028;  10;  ÷

029;  44,40,0;  STO+ 0

030;  45, 12; RCL i

031;  45, 7;  RCL 7

032;  40;  +

033;  12;  i

034;  1;  1

035;  16;  CHS

036;  15;  FV

037;  0;  0

038;  14;  PMT

039;  13;  PV

040;  45, 9;  RCL 9

041;  20;  ×

042;  44,40,0;  STO+ 0

043;  45,12;  RCL i

044;  45,7;  RCL 7

045;  30;  -

046;  12;  RCL i

047;  45,0;  RCL 0

048;  43,33,000;  GTO 000

Examples

Example 1

NBIT:  $7,588  (store in R8)

Reversion Value:  $236,000 (store in R9)

Tax Rate:  1.3%  (store 1.3 in R7)

Annual Rate:  8%  (store in i)

Years of Economical Life Remaining:  5  (store in n)

Property Value:  $180,092.06

Example 2

NBIT:  $12,000

Reversion Value:  $185,000

Tax Rate:  1.6%  

Annual Rate:  7.34%

Years of Economic Life Remaining:  10

Property Value:  $153,286.39

Sources

"Lesson 4 - Time Value of Money (The Income Approach to Value)"  California State Board of Equalization.  Accessed March 27, 2023. https://www.boe.ca.gov/info/iav/lesson4.htm

"Lesson 18 - Property Reversion:  Annuity plus Reversion Method (The Income Approach to Value" California State Board of Equalization.  Accessed March 27, 2023.  https://www.boe.ca.gov/info/iav/lesson18.htm

Eddie

All original content copyright, © 2011-2023.  Edward Shore.   Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited.  This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author. 

HP 12C: Last X: Sums and Products

HP 12C:   Last X:   Sums and Products

Introduction

It is possible to use the LST X feature on the HP 12C calculators assist us in quickly calculate sums or products  of a terms, especially when the list of terms are in a series. 

For today's blog, we are starting with a base amount, a, and then adding 1 to each term.   You can use a similar algorithm for a sequence where each term is doubled, tripled, 1 is subtracted from the previous term, and so on.  The key is to complete the adjustment, use storage arithmetic, and then use LST X.

Accessing LST X:

HP 12C (Classic):  [ g ] [ ENTER ]

HP 12C Platinum:  [ g ] [ + ]

These algorithms can be used in program. 


Sum:  a + (a+1) + (a+2)  + (a+3) + ....

Let n represent the storage register to be used.  On the HP 12C, only storage registers R0 through R4 (classic HP 12C).

Algorithm:

a 
STO n

Loop:  
LST X 
1     [ or 2, x  to double each term,  1, - to subtract 1, etc.]
+  
STO+ n    [stores what is in the X display to the Last X register]

Finish:  
RCL n


Example:  7 + 8 + 9 +10 = 34.   Use register 0 to store the sum.

7
STO 0

LST X
1
+
STO+ 0

LST X
1
+
STO+ 0

LST X
1
+
STO+ 0

RCL 0


Sum:  1/a + 1/(a+1) + 1/(a+2) + 1/(a+3) + ....

Algorithm:

a 
1/x
STO n

Loop:  
LST X 
1     
+  
1/x
STO+ n    

Finish:  
RCL n

Example:  1/7 + 1/8 + 1/9 + 1/10 ≈ 0.47897

7
1/x
STO 0

LST X
1
+
1/x
STO+ 0

LST X
1
+
1/x
STO+ 0

LST X
1
+
1/x
STO+ 0

RCL 0

Sum:  √a + √(a+1) + √(a+2) + √(a+3) + ...

Algorithm:

a 
√
STO n

Loop:  
LST X 
1     
+  
√
STO+ n    

Finish:  
RCL n

Try the algorithm on this example:  √7 + √8 + √9 + √10 ≈ 11.63646

Sum:  a^2 + (a+1)^2 + (a+2)^2 + (a+3)^2 + ...

Hint:  Use ENTER, x instead of 2, y^x

Algorithm:

a 
ENTER 
*
STO n

Loop:  
LST X 
1     
+  
ENTER
*
STO+ n    

Finish:  
RCL n

Try the algorithm on this example:  7^2 + 8^2 + 9^2 + 10^2 = 294

Let's move on to products.

Product:  a * (a+1) * (a+2) * (a+3) * ....

a 
STO n

Loop:  
LST X 
1     
+  
STOx n    

Finish:  
RCL n


Example:  7 * 8 * 9 * 10 = 5040.   Use register 0 to store the product.

7
STO 0

LST X
1
+
STOx 0

LST X
1
+
STOx 0

LST X
1
+
STOx 0

RCL 0

Product:  1/a * 1/(a+1) * 1/(a+2) * 1/(a+3) * ....

a 
1/x
STO n

Loop:  
LST X 
1     
+  
1/x
STOx n    

Finish:  
RCL n


Try the algorithm on this example 1/7 * 1/8 * 1/9 * 1/10 ≈ 0.0020

Product:  √a * √(a+1) * √(a+2) * √(a+3) * .......

a 
√
STO n

Loop:  
LST X 
1     
+  
√
STOx n    

Finish:  
RCL n


Try the algorithm on this example √7 * √8 * √9 * √10 ≈ 70.99296

Hopefully this will help your calculations on your RPN calculators faster and more effective,

Eddie

All original content copyright, © 2011-2020.  Edward Shore.   Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited.  This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author.

HP 12C: ARM Term if Renewed

HP 12C:  ARM Term if Renewed

Introduction

Situation:  An ARM Mortgage has one rate adjustment.  The mortgage calls for the payment to remain the same for the entire mortgage, even after the rate adjustment.  How long will it take to pay off the mortgage?  Specifically, how long will it take after the rate is adjusted (ARM term)? 

Example 1:

Original term: 30 years ( n = 360 )
Interest rate: 6%  ( i = 6/12 )
The interest rate scheduled to increase 0.25% in 4 years.

HP 12C Procedure

Any loan amount will do for this problem.  We'll use $1 for the loan amount in this example since we're only concerned with the ARM term.

Keystrokes:

(FIX 4 is set)

1.  Find the payment of the original mortgage.

Clear Finance Registers:   [ f ] [ x<>y ] (CLEAR FIN)
1 [ PV ]
30 [ g ] (12x) [ n ]
6 [ g ] (12÷) [ i ]
[PMT]   (Result:  -0.0060)

2.  Determine the balance of the mortgage at the date when the mortgage is adjusted (4 years).

4 [ g ] (12x) [ n ]
[ FV ]  (Result:  -0.9461)

3.  Transfer the balance to the new mortgage amount and enter the adjusted mortgage rate.

[CHS] [ PV ]
0 [ FV ]
[RCL] [ i ] 0.25 [ENTER] 12 [ ÷ ] [ + ] [ i ]
[ n ] (Result:  333.0000)

If the payment is kept the same, it would take another 333 payments to pay off the mortgage.  The ARM Term is 333.

The total time it takes to pay the mortgage is:

Pre-Adjustment Term + ARM Term

In this case, 381 payments (48 + 333).

The program presented here will calculate the ARM term.  This makes the assumption that the mortgage is only adjusted one time during its entire life.  This is similar to looking up the financial table ARM Term If Renewed Table (refer to source).

HP 12C Program:  ARM Term if Renewed

Keys:

01  1      
02  PV
03  0
04  FV
05  PMT
06  RCL 1 
07  n
08  FV
09  CHS
10  PV
11  0
12  FV
13  RCL i
14  RCL 2
15  +
16  i 
17  n
18 GTO 00   (HP 12C Platinum: GTO 000)

Key Codes:

01  1
02  13
03  0
04  15
05  14
06  45, 1
07  11
08  15
09  16
10  13
11  0
12  15
13  45, 12
14  45, 2
15  40
16  12
17  11
18  43, 33, 00  (HP 12C Platinum:  43, 33, 000)

Instructions:

Store the original number of periods in [ n ]
Store the original periodic interest rate in [ i ]
Store the number of months before the rate adjusts in R1.
Store the periodic adjustment (±r%) in R2.
Press [ R/S ]

Example:

Original term: 35 years
Original rate: 4.5%
The rate is adjusts +0.3% in 5 years.

35 [ g ] [ n ] (12x)
4.5 [ g ] [ i ] (12÷)
5 [ENTER] 12 [ x ] [STO] 1
0.3 [ENTER] 12 [ ÷ ] [STO] 2
[ R/S ]

Result:  391

The ARM term is 391 months.

Source:

Lincoln Title Company "Financial Conventional and ARM Payment Tables" Publication No. 493. Special Edition.  Financial Publishing Company: Boston, MA. May 1985 ISBN 0-87600-493-1

Eddie


All original content copyright, © 2011-2019.  Edward Shore.   Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited.  This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author.