BASIC vs. Python: Mean and Standard Deviation by an Iterative Method

BASIC vs. Python: Mean and Standard Deviation by an Iterative Method

Calculators Used:

BASIC: Sharp EL-5500 III

Python: Casio fx-CG 100

Introduction

The following code calculates the sum, mean, and standard deviation of a data set. The method that will be used is from voidware.com, which suggests an iterative method, as follows (Voidware):

M_0 = 0, S_0 = 0, n = 0

Loop with data point X:

M_n+1 = M_n + (X – M_n) ÷ (n + 1)

S_n+1 = S_n + (X – M_n) × (X – M_n+1)

n = n + 1

When all the data as been tabulated:

S = √(S ÷ (n – 1))

M: mean

S: standard deviation

Source

“Standard Deviation” Voidware. http://www.voidware.com/sd.htm Website was last updated in 2018. Last Retrieved July 4, 2025.

BASIC: Sharp EL-5500 III

10 PRINT "ONE VAR STATS"

12 CLEAR

30 INPUT "DATA? "; X

32 E=M+(X-M)*(N+1)

34 S=S+(X-M)*(X-E)

36 N=N+1

38 M=E

40 U=U+X

42 INPUT "MORE? (1=YES) "; C

44 IF C=1 THEN 30

60 S=√(S/(N-1))

70 PRINT "# DATA= "; N

72 PRINT "SUM= "; U

74 PRINT "MEAN= "; M

76 PRINT "STD DEV= "; S

78 END

Notes:

CLEAR: clears all the variables A-Z and resets their values to zero

PRINT: pauses the screen while the message is displayed

Python: Casio fx-CG 100

(Can be we used with any calculator with Python)

# one var stat without the math module

# voidware.com/sd.htm

def onevar(data):

  # set up

  m,s,u,n=0,0,0,0

  for i in data:

    e=m+(i-m)/(n+1)

    s+=(i-m)*(i-e)

    n+=1

    m=e

    u+=i

  s=(s/(n-1))**0.5

  return [n,u,m,s]

Notes:

We can store multiple values to variables at once. Example:

var4, var3, var2, var1 = value1, value2, value3, value4

Storage Arithmetic:

s+=expression -> s=s+expression

s-=expression -> s=s-expression

s*=expression -> s=s*expression

s/=expression -> s=s/expression

Example

Data set:

n = 1: x = 105

n = 2: x = 107

n = 3: x = 86

n = 4: x = 96

n = 5: x = 113

Data Structure: [105, 107, 86, 96, 113]

Results:

# DATA: 5 (N)

SUM: 507 (U)

MEAN: 101.4 (M)

STD DEV: 10.54988151 (S)

Eddie

All original content copyright, © 2011-2026. Edward Shore. Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited. This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author.

The author does not use AI engines and never will.

Sharp EL-5500 III: Slots: Triples and Cherries Pay

Sharp EL-5500 III:  Slots:  Triples and Cherries Pay

BAR | BAR | BAR

   7    |   7    |   7

   🍒  |   🍒   |  🍒

Note: Symbols that are produced by Unicode should, but may not show up on all browsers. Please make sure your browsers are updated to the latest version.  

Take a Spin

This program is a three reel slot simulator, each with ten symbols:

0:  BAR

1:  Cherry (🍒)

2:  Orange

3:  Plum

4:  Bell (🔔)

5:  Lemon (🍋)

6:  Watermelon (🍉)

7:  Seven

8:  Apple (🍎)

9:  Shamrock (☘)

To see the version for the HP 32SII, please click here:  https://edspi31415.blogspot.com/2018/06/hp-32s-ii-two-versions-of-slots.html

🍒 | 🍒 | 🍒

Each spin has an ante of 25¢.  The results appear in the form 0.###  (ignore the left most 0.)  See the Take a Spin section above for the symbols used in the game.

The payouts are these:

A cherry in any one slot (0.1xy, 0.x1y, or 0.xy1):  $1.00

Any two cherries (0.11x, 0.1x1, 0.x11):  $10.00

Three BARS (0.000):  $35.00  ($15 + $20)

Three Sevens (0.777):  $70.00  ($50 + $20)

Any other triple (0.xxx, x≠0 and x≠7):  $20.00

Note: You can use any line numbering system, I used the line numbers 1400-1499 for this program. The first “D” on line 1400 is optional, but is there to make the program a defined program for the EL-5500 III, running it by pressing [DEF] [ D ].  If you are using another calculator, this may not be an option, so ignore the “D” in that case.

Sharp EL-5500 III Program Slots: Triples and Cherries Pay

1400: “D”: PAUSE “Slots”   

1402: CLEAR

1404: INPUT “Bankroll: $”; J

1406: P = 0

1408: J = J - .25

1410: N = .1*(RND 10-1)+.01*(RND 10-1)+.001*(RND 10 – 1)

1412: PRINT USING “########”; 1000*N

1414: S = N/.111

1416: IF (S-INT(S)) = 0 THEN 1450

1418: X = N: GOSUB 1430

1420: X = S: GOSUB 1430

1422: X = S: GOSUB 1430

1424: J = J + INT(TEN (P – 1))  // TEN: 10^x

1426: GOTO 1470

1430: I = INT(X*10)

1432: S = 10*X – I

1434: IF I = 1 THEN LET P = P + 1

1436: RETURN

1450: IF S = 0 THEN LET J = J + 35

1452: IF S = 7 THEN LET J = J + 50

1454: IF S<>0 AND S<>7 THEN LET J = J + 20

1456: GOTO 1470

1470: PRINT “Bank $”; USING “##########.##”; J

1472: INPUT “1 = Again ? :”, C

1474: IF C = 1 THEN 1406

1476: END

Eddie

All original content copyright, © 2011-2018.  Edward Shore.   Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited.  This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author.  Please contact the author if you have questions.

Fun with the Sharp EL-5500 III (May 2018 Edition)

Fun with the Sharp EL-5500 III   (May 2018 Edition)

The EL-5500 III is one of my favorite pocket programming device, small, portable, and has my favorite programming language: BASIC. 

Let’s get started.

Note:  Substitute line numbers with labels that you find fit.  Add defined labels to the first line if you would like.  Labels can come from the bottom two rows of the QWERTY keyboard (A row and Z row).

Comments are followed by double slashes (//), they are not typed.

Sharp EL-5500 III Program:  Net Present Value

2  PAUSE “NET PRESEN VALUE”

4  CLEAR    // clears all the variables

6  INPUT “CF0:”; N, “RATE:”; I

8  J = 1

10 INPUT “FLOW:”; F, “FREQ:”; K

12 FOR L=1 TO K: N = N + F/(1 + I/100)^J: J = J+1

14 NEXT L

16 INPUT “MORE=1: “; L   // enter 1 to enter more cash flows, anything else to end entry

18 PRINT USING “#############.##”; “NPV: “; N

20 END

Example:

CF0:  -7,000,  Interest Rate:  8%

Flow 1:  2,000, Freq 1: 1  (enter 1 for MORE)

Flow 2:  1,500, Freq 2: 2  (enter 1 for MORE)

Flow 3:  2,500, Freq 3: 2  (we are at the end, enter anything other than 1 at MORE)

Result:

NPV:  2443.06

Sharp EL-5500 III Program: Synthetic Division

2 PAUSE “Synthetic Division”: CLEAR

4 PRINT “P(X)/(X – R)”: WAIT 59   // WAIT 59 is about 1 second

6 INPUT “DEGREE:”; N

8 DIM P(N): DIM Q(N)

10 FOR I=1 TO N

12 PRINT “COEF OF X^”; N-I

14 INPUT P(I): Q(I) = P(I)

16 NEXT I   // there is no line 18

20 INPUT “R:”; R

22 FOR I=0 TO N-1

24 Q(I+1) = R*Q(I) + P(I+1)

26 NEXT I

28 E = Q(N)

30 PRINT “Q(X) = “

32 FOR I=0 TO N-1

34 PRINT Q(I); “X^”; N-I-1

36 WAIT 150  // about 2.5 seconds

38 NEXT I

40 PRINT “+”; E; “/(X-“; R; “)”: END

Example:  (x^4 – 2*x^3 + 1) / (x – 1)

Degree: 4

Coefficients:  1, -2, 0, 0, 1

R: 1

Result: 1, -1, -1, -1, no remainder

x^3 – x^2 – x – x

Sharp EL-5500 III Program: Vector Basics

Cross product, dot product, norm of two vectors, angle between two vectors

2 PAUSE “Vector Basics”

4 INPUT “X1:”; X1, “Y1:”; Y1, “Z1:”; Z1  \\ vector 1

6 INPUT “X2:’; X2, “Y2:”; Y2, “Z2:”, Z2  \\ vector 2

8 C1 = Y1*Z2 – Y2*Z1: C2 = -X1*Z2 + X2*Z1: C3 = X1*Y2 – X2*Y1  // cross product

10 D = X1*X2 + Y1*Y2 + Z1*Z2  \\ dot product

12 N1 = √(SQU X1 + SQU Y1 + SQU Z1): N2 = √(SQU X2 + SQU Y2 + SQU Z2)  // norm, SQU is the x^2 key

14 DEGREE

16 A = ACS( D/(N1*N2))  // angle between vectors, ACS is ACOS

18 PRINT “CROSS X: ”; C1

20 PRINT “CROSS Y: ”; C2

22 PRINT “CROSS Z: ”; C3

24 PRINT “DOT: ”; D

26 PRINT “NORM V1: “; N1

28 PRINT “NORM V2: “; N2

30 PRINT “ANGLE: “; A

32 END

Example:  V1 = [-2, 3, 0] and V2 = [ 4, 2, -11]

Cross: [-33, -22, -16]

Dot: -2

Norm V1: 3.605551275

Norm V2: 11.87434209

Angle: 92.67749998°

Sharp EL-5500 III: Atwood Machine

M1:  mass hanging on the left side of the machine

M2:  mass hanging on the right side of the machine

The program asks to choose a unit system.  Enter 1 for US units (feet, pounds, seconds, g = 32.174 ft/s^2), anything else for SI units (meters, kilograms, seconds, g = 9.80665 m/s^2).

2 PAUSE “Atwood Machine”

4 INPUT “1: US, ELSE: SI “; I

6 IF I=1 THEN LET G=32.174

8 IF I<>1 THEN LET G=9.80665

10 INPUT “M1: “; M1, “M2: “; M2

12 A = (M1 – M2)*G / (M1 + M2)

14 T = M1 * (G-A)

16 PRINT “Accel.: “; A

18 PRINT “Tension: “: T

20 END

Example:  M1 = 11.82 kg, M2 = 9.38 kg, use SI units (enter anything other than 1 at the 1:US, ELSE:SI prompt)

Results:

Accel.: 1.128689906 m/s^2

Tension: 102.5734883 N

Eddie

All original content copyright, © 2011-2018.  Edward Shore.   Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited.  This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author.  Please contact the author if you have questions.

HP Prime, TI-84 Plus CE, Sharp EL-5500 III: Pythagorean Triples

HP Prime, TI-84 Plus CE, Sharp EL-5500 III:  Pythagorean Triples

  

Criteria

The program PYTHA calculates a Pythagorean triple.  A Pythagorean triple is a set of three positive integers A, B, and C that represent the lengths of a right triangle, with C being the hypotenuse.  Hence, A^2 + B^2 = C^2. 

Pythagorean triples can be generated with three arbitrary positive integers M, N, and K with the following criteria:

1.  M > N

2.  M and N are coprime.  That is, gcd(M, N) = 1 (gcd, greatest common denominator)

A, B, and C are generated by:

A = K * (M^2 – N^2)

B = K * (2 * M * N)

C = K * (M^2 + N^2)

Verification

We can verify that the above formulas for A, B, and C work by showing A^2 + B^2 = C^2.

A^2 + B^2

= (K * (M^2 – N^2))^2 + (K * 2 * M * N)^2

= (K * M^2 – K * N^2)^2  + 4 * K^2 * M^2 * N^2

= K^2 * M^4 – 2 * K^2 * M^2 * N^2 + K^2 * N^2 + 4 * K^2 * M^2 * N^2

= K^2 * M^4 + 2 * K^2 * M^2 * N^2 + K^2 * N^2

= (K * M^2 + K * N^2)^2

= K^2 * (M^2 + N^2)^2

= C^2

Programs

HP Prime Program PYTHA

EXPORT PYTHA(M,N,K)

BEGIN

// 2017-02-08 EWS

// Pythagorean Triangle

LOCAL A,B,C;

// checks (not for minimum)

M:=IP(M); N:=IP(N); K:=IP(K);

IF M≤0 OR N≤0 OR

gcd(M,N)≠1 OR M≤N THEN

RETURN "INVALID"; KILL;

END;

// calculations

A:=K*(M^2-N^2);

B:=K*(2*M*N);

C:=K*(M^2+N^2);

RETURN {A,B,C};

END;

TI-84 Plus Program PYTHA

"EWS 2017-02-08"

Prompt M,N,K

iPart(M)→M

iPart(N)→N

iPart(K)→K

If M≤0 or N≤0 or K≤0 or M≤N or gcd(M,N)≠1

Then

Disp "INVALID"

Stop

End

K*(M²-N²)→A

K*(2*M*N)→B

K*(M²+N²)→C

Pause {A,B,C}

Sharp EL-5500 III Pythagorean Triple

(RUN 450 (line numbers are arbitrary))

450 PAUSE “Pythagorean Triple”

455 INPUT “M:”; M, “N:”; N, “K:”; K

460 IF M<=0 OR N<=0 OR K<=0 OR M<=N THEN 480

462 A = K*(M^2 - N^2)

464 B = K*2*M*N

466 C = K*(M^2 + N^2)

468 IF A^2 + B^2 <> C^2 THEN 480

470 PRINT A; “^2+”; B; “^2=”; C; “^2”

472 END

480 PRINT “INVALID”

482 END

Examples:

M: 2, N: 1, K: 1. Result:  A: 3, B: 4, C: 5

M: 7, N: 2, K: 1. Result:  A: 45, B: 28, C: 53

M: 5, N: 3, K: 2. Result:  A: 32, B: 60, C: 68

Source:

“Pythagorean Triple” Wikipedia. Last Modified February 7, 2017. 

https://en.wikipedia.org/wiki/Pythagorean_triple

Accessed February 7, 2017

Have a great day, love you all for the support,

Eddie

This blog is property of Edward Shore, 2017

Fun with the Sharp EL-5500 III

Fun with the Sharp EL-5500 III

See my review for the EL-5500 III here:  http://edspi31415.blogspot.com/2017/01/retro-review-sharp-scientific-computer.html

Even though the EL-5500 III has one programming space, we can fit many programs in it.  One of the great features is that how programs take relatively little space.  Obviously you can change the line numbers, the sequence of lines are most important.

Euclid Algorithm – RUN 10

10 PAUSE “GCD: A>B”

18 INPUT “A: “; A, “B: “; B

20 C = A – INT(A/B)*B

30 IF C = 0 THEN 40

32 A = B

34 B = C

36 GOTO 20

40 PRINT “GCD = “; B

46 END

My first program on the EL-5500 III.  We can probably make the coding more efficient.  PRINT with a proceeding WAIT pauses execution until [ ENTER ] is pressed.

The command END ends the program execution and allows the space to have more than one routines.

Examples:

A: 100, B: 20.  Result:  GCD = 20

A: 63, B: 60.  Result:  GCD = 3

Binomial Expansion – RUN 50

50 PAUSE “(Ax + B)^n”

55 INPUT “A: “;A, “B: “;B, “N: “,N

60 FOR I=0 TO N

65 C = FACT(N) / (FACT(I) * FACT(N-I))

70 T = C * A^(N-I) * B^I

75 PRINT T; “*x^”; N-I

80 NEXT I

85 END

The command PAUSE shows the text for about 0.85 seconds.

This program displays each coefficient one at time.

Example:  A = 3, B = -2, N = 3.  Expand (3 – 2x)^3.

Result:  27, -54, 36, -8  (27x^3 – 54x^2 + 36x – 8)

Days Between Dates – RUN 100

100 PAUSE “Days between Dates”

112 INPUT “M1:”; M1, “D1:”; D1, “Y1:”; Y1

113 INPUT “M2:”; M2, “D2:”; D2, “Y2:”; Y2

115 M = M1: D = D1: Y = Y1

117 GOSUB 140

119 F1 = F

121 M = M2: D = D2: Y = Y2

123 GOSUB 140

125 F2 = F

127 N = F2 – F1

129 PRINT “# DAYS: “; N

131 END

140 IF M > 2 THEN 150

142 X = 0: Z = Y – 1

144 GOTO 160

150 X = INT(.4 * M + 2.3): Z = Y

160 F = 365 * Y + 31* (M – 1) + D + INT(Z/4) – X

165 RETURN

If I had it my way, every calculator that isn’t a basic 4-function calculator will have a Days Between Dates function.

Example:  November 4, 1986 to January 12, 2017

M1:  11, D1: 4, Y1: 1986 

M2: 1, D2: 12, Y2: 2017

Result:  11,027

Power of a Complex Number – RUN 200

This calculates (a + bi)^n

200 PAUSE “(A + Bi)^n”

203 INPUT “A: “;A, “B: “;B, “n: “;N

205 IF A<>0 THEN 210

207 A = A^N: GOTO 220

210 R = √(A^2 + B^2)^N

212 T = ATN(B/A)*N

214 A = R * COS T

216 B = R * SIN T

220 PRINT A; “+”; B; “i”

225 END

The command <> means not equals (≠) and ATN is the arctangent function.

Examples:

(2 + 3i)^3:  A = 2, Bi = 3.  Result: -46 + 9i

(-5 + i)^2:  A = -5, Bi = 1.  Result: 24 – 10i

Error Function Approximation – RUN 250

250 PAUSE “APPROX ERF(X)”

252 CLEAR

254 DIM A(3)

256 E = 0

260 INPUT “X > 0 : “; X

262 T = RCP(1 + .47047 * X)

270 FOR I = 1 TO 3

272 READ A(I)

274 E = E + A(I) * T^I

276 NEXT I

280 DATA .3480242, -.0958798, .7478556

290 E = 1 – E * EXP(-(X^2))

292 PRINT “ERF : “, F

294 CLEAR

296 END

Use the command CLEAR to clear all the variables.  At this point, I will use this command both at the beginning and end of calculations.  The command RCP is the reciprocal.  Finally, EXP is from e^x function, not the [EXP] key.

Example:

x = 0.53, erf ≈ 0.546455764

x = 0.88, erf ≈ 7.86708E-01 = 0.786708

Keep in mind this approximation is accurate 2.5 parts in 10^-5.

Source:  Smith, Jon M.  Scientific Analysis on the Pocket Calculator  John Wiley & Sons: New York. 1975.  ISBN 0-471-79997-1

Simpson’s Rule – RUN 300

Calculates the numeric integral ∫ f(x) dx from x = L to x = U.

You can edit the function at line 342.  In BASIC-PRO mode, call up line 342 by LIST 342.  Edit as desired.

300 PAUSE “Simpsons Rule”

302 CLEAR

304 INPUT “LOWER: “; L, “UPPER: “; U, “PARTS (even): “; N

306 RADIAN

308 X = L: GOSUB 340: T = F

310 X = U: GOSUB 340: T = T + F

314 H = (U – L)/N

320 FOR I = 1 TO N-1

322 X = L + I * H: GOSUB 340

324 R = I/2 – INT(I/2)

326 IF R = 0 THEN LET T = T + 2*F

328 IF R <> 0 THEN LET T = T + 4*F

330 NEXT I

332 T = T * H/3

334 PRINT “Integral: “, T

336 CLEAR

338 END

340 REM f(x)

342 F = [insert f(X) here]

344 RETURN

Note:  I finally learn why LET is included in BASIC.  In an IF-THEN statement, if you want to assign a value or calculation to a variable, you will need a LET command.

I use a REM (remark) command on line 340.  REM is for comments and nothing said after REM is executed.

Examples:

342 F = X^2 – 1

L = -2, U = 2, N = 14.  Result:  1.333333334 (Actual: 4/3 ≈ 1.333333333)

342 F = √(X – 1)

L = 2, U = 3, N = 14.  Result: 1.218951372 (Actual:  ≈ 1.2158951416)

Dancing Star Demo – RUN 400

400 PAUSE “Dancing Star Demo”

405 CLEAR

410 S$ = “         “  (9 spaces)

415 FOR I = 1 TO 48

420 N = RND 7 + 1

425 T$ = MID$(S$, 1, N-1) + “*” + MID$(S$, N+1, 9-(N+1))

430 WAIT 15: PRINT T$

440 NEXT I

445 BEEP 3: CLEAR: END

This is just show a dancing asterisk (*) on the screen.

WAIT 15: PRINT T$:   This causes the string T$ after a quarter of a second.  WAIT operates in 1/60 seconds.

RND n:  This is the random command.  If n = 1, the result is between 0 and 1. 

BEEP n:  This makes the EL-5500 III beep n times. 

Eddie

This blog is property of Edward Shore, 2017.

Retro Review: Sharp Scientific Computer EL-5500 III

Retro Review:  Sharp Scientific Computer EL-5500 III

Company:  Sharp

Type:  Scientific, BASIC

Years Made: 1985 - 1991

Batteries:  2 CR-2032 batteries

Memory/RAM: 6,878 bytes

Basic Features

The EL-5500 III operates in two main modes:  CALC (calculator) and BASIC (programming mode).  The CALC mode has two additional sub-modes:  Matrices and Statistics (Linear Regression).   You can also convert numbers between Decimal (base 10) and Hexadecimal (base 16). 

The matrix mode uses RAM and has two matrices in storage: X and Y.  Thankfully, Sharp printed matrix operations on their hard case, includes arithmetic, scalar arithmetic, inverse, squaring, transpose, and determinant.  Given how the EL-5500 III has was released over 30 years ago, I image someone has come up with a good program to find eigenvalues.   X not only serves an input matrix but an output. With the one line screen, elements are shown one at a time.

In CALC mode, calculations are in AOS mode (algebraic, with the one-variable argument functions such as the logarithmic and trig functions are executed after the number is entered), and the equals key ( [ = ] ) completes operations.  However, in BASIC mode, calculations are entered the way they are written, and they are completed when the [ ENTER ] key is pressed.

For example:  to calculate log(6):

CALC Mode:  6 [ log ]

BASIC Mode:  [ log ] 6 [ ENTER ]

There is no built-in complex number mode.

The Keyboard

The keys are small, but no so small that I don’t have to use a stylus or aid to press them.  The keys are easy to the touch.  I am also impressed on how light the keyboard is, which is impressive for 1980s portable keyboard. Yet the keyboard is steady and the keys give a solid response.  Sharp did a great job with this model.

Programming

As mentioned before, the EL-5500 III has 6,878 bytes, somewhat comparable to the TI-74.  Also similar to the TI-74, there is only one program space.  You can fit multiple programs in the EL-5500 III as long as you organize your line numbers correctly.  However, the EL-5500 III has definable keys with the following available labels: A, S, D, F, G, H, J, K,L, ‘, Z, X, C, C, V, B, N, M, SPC. 

To label a program, follow this format:

Line number  “key” : command

…

END

Use the [DEF] key to run labeled programs. 

The EL-5500 III has a beep sound (via BEEP command).  I think am I going to start using beeps in programs when I can. 

The ability to type lower case is present through the [SML] which toggles lower case on and off.

The classic mathematical BASIC commands are available:  DELETE, NEW, GOTO, STR$, VAL, DATA, READ, DIM, FOR loops, IF tests, GOSUB, INPUT, PRINT, ON GOTO/GOSUB, and the almost completely unnecessary LET.

LIST is used instead of FETCH.

FOR loops:

FOR var = starting value TO ending value [ STEP increment ] … NEXT var

IF tests:

IF conditional test THEN do this one command if test is true

IF conditional test THEN go to this line number (no GOTO is necessary)

LET assigns a value to a variable.  However it is not required.  For example, both statements listed will store 5 to the variable A:

LET A = 5

A = 5

Strings are concentrated with a plus sign while multiple commands can be stringed together with a colon.

Line numbers are needed to organize the statements.  I wish line numbers were brought back in modern calculators that used basic.   According to the EL-5500 III manual, the available line numbers range from 1 to 65279.

Most commands also have short cut keywords.  For example, RAD., RADI., and RADIANS set radians mode, while P. and PR. can both be used for PRINT.  When entered, the EL-5500 III will complete the abbreviations with their full word counterparts.  This was created to save time.

Accessories

The EL-5500 III can be attached to a CE-126P, a combination thermal printer and cassette player interface.  Yes, the CE-126P can be connected to a compatible cassette tape player, which the player is used to record programs.     

Final Verdict

The EL-5500 III is a pleasure to hold and use.  Despite the screen being small, the text on the screen is crisp and easy to read.  The most likely place to find EL-5500 III computers for sale is eBay, which is where I purchased mine.  Prices do vary, I paid $38.  I didn’t get any accessories though.  I recommend buying one if you are interested.  

Programs using the EL-5500 III to come in the future (along with my beloved HP 71B).

P.S. The EL-5500 III is not the calculator/computer used in the 1984 movie Ghostbusters.  That was the Radio Shack TRS-80 PC-4.  (http://www.gbfans.com/equipment/other/radio-shack-pc-4-calculator/ )

Eddie

This blog is property of Edward Shore, 2017