TI-60 Geometry: Intersection and Angle Between Two Lines

TI-60 Geometry: Intersection and Angle Between Two Lines

We have two lines in the standard form:

y = R1 * x + R2

y = R3 * x + R4

where R1, R3 are the slopes and R2, R4 are the y-intercepts, which are stored prior to executing the programs.

TI-60: Intersection Point

x = (R4 – R3) / (R1 – R3), y = R1 * x + R2

Step Key Code	Key	Step Key Code	Key
00 53	(	14 54	)
01 71	RCL	15 95	=
02 04	4	16 13	R/S
03 75	-	17 65	×
04 71	RCL	18 71	RCL
05 02	2	19 01	1
06 54	)	20 85	+
07 55	÷	21 71	RCL
08 53	(	22 02	2
09 71	RCL	23 95	=
10 01	1	24 13	R/S
11 75	-	25 22	RST
12 71	RCL
13 03	3

TI-60: Angle Between Two Lines

Θ = arctan(abs((R1 – R3) / (1 + R1 * R3)))

Step Key Code	Key	Step Key Code	Key
00 53	(	13 65	×
01 71	RCL	14 71	RCL
02 01	1	15 03	3
03 75	-	16 54	)
04 71	RCL	17 95	=
05 03	3	18 96	x²
06 54	)	19 86	√x
07 55	÷	20 12	R/S
08 53	(	21 34	RST
09 01	1
10 85	+
11 71	RCL
12 01	1

Examples

	Intersection Point: (x, y)	Angle: Θ (degrees)
y = -2 * x + 3 y = 3 * x + 4	(-0.2, 3.4)	45°
y = x + 8 y = 3 * x – 6	(7, 15)	26.56505118°
y = 4 * x – 6 y = 2 * x + 1	(3.5, 8)	12.52880771°

May I close with this: Happy Birthday, Susan Sarandon!

Eddie

All original content copyright, © 2011-2025. Edward Shore. Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited. This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author.

The author does not use AI engines and never will.

TI-84 Plus: Intersection of two lines – program by Jack Kesler

TI-84 Plus:  Intersection of two lines – program by Jack Kesler

Special thanks to Jack Kessler for providing the program CPXINT.  CPXINT uses complex numbers to determine:

* The equation of a line between two points.  CPXINT uses two lines:

            y = Ax + B for coordinates N1, E1 and N2, E2.

            y = Cx + D for coordinates N3, E3 and N4, E4

* The intersection of the two lines, labeled by point N5, E5.

Keep in mind N is for North (y axis) and E is for East (x axis).

TI-84 Plus Program CPXINT – Jack Kesler

Note:  Initialize all the variables by choosing option 1, SETUP.  Choose 2 for input, 3 for equations of the lines, and 4 for intersection.

ClrHome

Disp "LINE INT"

Disp "USNG CPX"

Disp "VER. 1.0"

Pause

ClrHome

Lbl 50

Menu("CPXINT","SETUP",89,"INP PTS",90,"COMP LINS",91,"COMP INT",92,"EXIT",93)

End

Lbl 89

ClrHome

ClrAllLists

11→dim(L₁)

{2,2}→dim([A])

{2,1}→dim([B])

Goto 50

Lbl 90

ClrHome

Disp "INP CRDS:"

Input "N1= ",T

T→L₁(1)

Input "E1= ",T

T→L₁(2)

Input "N2= ",T

T→L₁(3)

Input "E2= ",T

T→L₁(4)

Input "N3= ",T

T→L₁(5)

Input "E3= ",T

T→L₁(6)

Input "N4= ",T

T→L₁(7)

Input "E4= ",T

T→L₁(8)

ClrHome

Goto 50

Lbl 91

ClrHome

a+bi

L₁(2)+L₁(1)i→I

L₁(4)+L₁(3)i→J

angle(J-I)→θ

If θ=90 or θ=­90

Then

real(I)→B

0→[A](1,1)

1→[A](1,2)

B→[B](1,1)

0→A

Else

tan(θ)→A

imag(I)-A*real(I)→B

1→[A](1,1)

­A→[A](1,2)

B→[B](1,1)

End

Disp "Y=A*X+B"

Disp "A= ",A

Disp "B= ",B

Pause

ClrHome

L₁(6)+L₁(5)i→I

L₁(8)+L₁(7)i→J

angle(J-I)→θ

If θ=90 or θ=­90

Then

real(I)→D

0→[A](2,1)

1→[A](2,2)

D→[B](2,1)

0→C

Else

tan(θ)→C

imag(I)-C*real(I)→D

1→[A](2,1)

­C→[A](2,2)

D→[B](2,1)

End

Disp "Y=C*X+D"

Disp "C= ",C

Disp "D= ",D

Pause

ClrHome

Real

Goto 50

Lbl 92

ClrHome

If A=C

Then

Disp "PARLLEL LINES"

Disp "NO SOLUTION"

Pause

ClrHome

Goto 50

End

[A]^-1*[B]→[D]

Disp "N5= ",[D](1,1)

[D](1,1)→L₁(9)

Disp "E5= ",[D](2,1)

[D](2,1)→L₁(10)

Pause

ClrHome

Goto 50

Lbl 93

ClrHome

Stop

Example:

Line 1:  N1 = 0, E1 = 1, N2 = 7, E2 = 2. 

Line 2:  N3 = 4, E3 = 3,  N4 = 4, E3 = -3

Results:

Y = AX + B:  A = 0,  B =  4

Y = CX + D:  C = 7,  D = -7

Intersection:  N5 = 4,  E5 = 1.571428571

Thank you Jack! 

Eddie

This blog is property of Edward Shore, 2016