Fun with the TI-81: Part II

Fun with the TI-81:  Part II

Please check out yesterday's blog entry for Part I.  Now let's continue.

TI-81 Decimal to Fraction:  DECTOFRAC
(148 bytes)

This program converts a number X to fraction as an approximation.  Each successful approximation is displayed until the absolute value of the error falls below 10^-12.  This program is based on a program written for the Radio Shack TRS-80 (see source). 

Variables:
X = Number
H = numerator
I = denominator
Y = error
Used: A, B, C, D, E, F, G, J

Program:
Disp "X="
Input X
IPart X → A
1 → B
X - A → C
0 → D
1 → E
1 → F
0 → G
Lbl 2
A * F + D → H
A * G + E → I
H / I - X → Y
ClrHome
Disp H
Disp "/"
Disp I 
Disp "ERR="
Disp Y
Pause
If abs Y<1e-12 font="">
Stop
C → J
B - A * C → C
J → B
F → D
H → F
G → E 
I → G
Goto 2

Example:
X = 4.7995
4 / 1,  ERR = -.7995
5 / 1,  ERR = .2005
13 / 4, ERR = -.0495
24 / 5,  ERR = 5E-4
1915 / 399, ERR = -1.253133E-6
9599 / 2000, ERR = 0

4.7995 = 9599/2000

Source:

Craig, John Clark  119 Practical Programs for the TRS-80 Pocket Computer  Tabs Books Inc.:  Blue Ridge, PA.  1982 ISBN 0-8306-0061-1 (Paperback)

TI-81 Simple Logistic Regression:  LOGISFIT 
(71 bytes)

The program LOGISFIT fits the statistical data to the equation:

y = 1 / (a + b*e^x)

This program uses the linear regression fit with the following translations:

x' = e^(-x), y' = 1/y

This fit will is good for all data except when y = 0.

Instructions: 
1.  Enter the data through the Stat Edit menu. 
2.  Run LOGISFIT.  The data will be altered. 

Program:
1 → I
Lbl 1
e^( -{x}(I) ) → {x}(I)
{y}(I)⁻¹ → {y}(I)
IS>( I, Dim{x} )
Goto 1
LinReg
Disp "Y=1/(a+be^(X))"
Disp "a"
Disp a
Disp "b"
Disp b

Example:
x1 = 0.5
y1 = 0.384
x2 = 1
y2 = 0.422
x3 = 1.5
y3 = 0.45
x4 = 2
y4 = .468
x5 = 2.5
y5 = .48

Results:
a = 2.001859259
b = .9942654005

Equation:
y = 1 / (2.001859259 + .9942654005*e^x)

Source:

Shore, Edward.  "HP Prime and TI-84 Plus CE: Simple Logistic Regression"  Eddie's Math and Calculator Blog. 2017.  http://edspi31415.blogspot.com/2017/04/hp-prime-and-ti-84-plus-ce-simple.html
Retrieved August 17, 2019

TI -81 Confidence Intervals: INTERVAL
(184 bytes)

The program INTERVAL calculates a confidence interval given the sample's mean (M), variance (V), and number of data points (N).  A Z scored is selected when the user selects one of three confidence levels: 

99%  (0.5% on each side of the curve, Z = 2.575829586)
95%  (2.5% on each side of the curve, Z = 1.959963986)
90%.  (5% on each side of the curve, Z = 1.644853627)

The interval lies between ( M - Z * V/√N,  M + Z * V/√N )

Notes:
1.  Z is used as an control variable and the Z score.
2.  The percent symbol is built of three characters, the degree symbol (°), the forward slash by pressing the [ ÷ ] key (/), the decimal point (.).

Program:
0 → Z
Disp "MEAN="
Input M
Disp "VAR="
Input V
Disp "N="
Input N
Lbl 0
ClrHome
Disp "1. 99°/."
Disp "2. 95°/."
Disp "3. 90°/."
Input P
If P=1
2.575829586 → Z
If P=2
1.959963986 → Z
If P=3
1.644853627 → Z
If Z=0
Goto 0
M + Z * V / √N → U
M - Z * V / √N → V
Disp "INTERVAL"
Disp U
Disp V

Example:
Input:  n = 100, M = 156.39, V = 10.94, 99% confidence interval
Results: 
162.2079576
156.5720424

Source:
Kelly, Kathy A., Robert E. Whitsitt II, M. Deal LaMont, Dr. Ralph A. Olivia, et all.  Scientific Calculator Sourcebook   Texas Instruments Inc.  1981.  (no ISBN number is given)

TI-81 Fresnel Polarization:  MICROPOL
(120 bytes)

Given a microwave transferring from one medium to another with the initial angle with respect to the plane surface that separates the mediums, the following are calculated:

1.  Angle of refraction, θt
2.  Fresnel Horizontal Polarization, R_H
3.  Fresnel Vertical Polarization, R_V

The Law of Refraction:
n1 sin θi = n2 sin θt

Fresnel Horizontal Polarization:
R_H = sin(θ_i - θ_t) / sin(θ_i + θ_t)

Fresnel Vertical Polarization:
R_V = tan(θ_i - θ_t) / tan(θ_i + θ_t)

Variables:
N = n_1  (index of refraction of medium 1)
M = n_2  (index of refraction of medium 2)
θ = θ_i  (angle of incidence)
Z = θ_t (angle of refraction)
H = R_H (Fresnel horizontal polarization)
V = R_V (Fresnel vertical polarization)

Note:  Angles are in degrees

Program:
Deg
Disp "N1="
Input N
Disp "θ="
Input θ
Disp "N2="
Input M
sin⁻¹ (Nsin θ / M) → Z
sin(θ-Z) / sin(θ+Z) → H 
tan (θ-Z) / tan (θ+Z) → V
Disp "REFRACT θ=" 
Disp Z
Disp "H-POLAR="
Disp H
Disp "V-POLAR="
Disp V

Example:
Inputs:  N1 = 1.001, θ = 40°, N2 = 1.333
Results:
REFRACT θ = 28.86146514°
H-POLAR = .2071186671
V-POLAR = .0761259908

Source:
Barue, Geraud  Microwave Engineering:  Land & Space Communications  John Wiley & Sons: Hoboken, NJ 2008.  ISBN 978-0-470-08996-5

TI-81 Hyperbolic Circles: Circumference and Area:  HYPCIRCL
(61 bytes)

The program HYPCIRCL calculates the circumference and area of a circle in hyperbolic space.  Note that this not the same as (normal, regular, everyday) circles in Euclidean space. 

Circumference of a hyperbolic circle: C = 2 π sinh(R)

Area of a hyperbolic circle:  A = 4 π sinh(R/2)^2

Program:
Disp "HYP CIRCLE"
Disp "R="
Input R
2π sinh R → C
4 π (sinh(R/2))² → A
Disp "C="
Disp C
Disp "A="
Disp A

Example:
Input: R = 3
Results: 
C = 62.94416455
A = 56.97380062

Source:
Series, Caroline  "Hyperbolic Geometry MA 448"  2010. Edited Jan. 4, 2013

Eddie

All original content copyright, © 2011-2019.  Edward Shore.   Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited.  This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author.

HP Prime: Best Regression Fit

HP Prime:  Best Regression Fit

The program BESTFIT compares a set of regressions to determine a best fit.  This simulates a feature presented on the Hewlett Packard HP 48S, HP 48G, HP 49G, and HP 50g.  BESTFIT compares the correlations of the following four regression models:

1.  Linear:  y = a * x + b

2.  Logarithmic:  y = a * ln x + b

3.  Exponential:  y = b * a^x   (y = b * e^(ln a * x))

4.  Power: y = b * x^a

The output is a two element list:  a string of the best fit equation and its corresponding correlation.

HP Prime Program:  BESTFIT

EXPORT BESTFIT(L1,L2)

BEGIN

// 2017-11-02 EWS

// Simulate Best Fit

// HP 48GX,49G,50g

// initialize

LOCAL clist,m,c,v,s,n;

clist:={0,0,0,0};

// test

// correlation is linear only

// requires approx()

// linear y=a*x+b

clist[1]:=approx(correlation(L1,L2));

// log y=a*LN(x)+b

c:=approx(correlation(LN(L1),L2));

IF IM(c)==0 THEN

clist[2]:=c;

END;

// exponential y=b*e^(a*x)

c:=approx(correlation(L1,LN(L2)));

IF IM(c)==0 THEN

clist[3]:=c;

END;

// power y=b*a^x

c:=approx(correlation(LN(L1),LN(L2)));

IF IM(c)==0 THEN

clist[4]:=c;

END;

// test

// POS(L0^2,MAX(L0^2))

m:=POS(clist^2,MAX(clist^2));

c:=clist[m];

IF m==1 THEN

v:=linear_regression(L1,L2);

s:=STRING(v[2])+"+"+STRING(v[1])+

"*X";

RETURN {s,c};

END;

IF m==2 THEN

v:=logarithmic_regression(L1,L2);

s:=STRING(v[2])+"+"+STRING(v[1])+

"*LN(X)";

RETURN {s,c};

END;

IF m==3 THEN

v:=exponential_regression(L1,L2);

s:=STRING(v[2])+"*"+STRING(v[1])+

"^X";

RETURN {s,c};

END;

IF m==4 THEN

v:=power_regression(L1,L2);

s:=STRING(v[2])+"*X^"+

STRING(v[1]);

RETURN {v,s};

END;

END;

Examples – BESTFIT:

Example 1:

X	y
1.05	10.45
2.28	11.33
4.20	16.38
6.34	28.87

Result: {“7.78250037344*1.21713132288^X”, 0.981261724397}

Example 2:

X	Y
-10	82
-5	41
5	-42
10	-79

Result:  {“0.5+ -8.1*X”, -0.999801918343}

Example 3:

X	Y
10	2.278
11	2.666
12	2.931
13	3.212

Result:  {“-5.79464870365+3.51429873838*LN(X)”, 0.998295735284}

BESTFIT2:  An Extended Version

Version 2 adds the following regressions: 

5.  Inverse:  y = b + a/x

6.  Simple Logistic:  y = 1/(b + a*e^(-x))

7.  Simple Quadratic:  y = b + a*x^2

8.  Square Root:  y = √(a*x + b)

HP Prime Program:  BESTFIT2

EXPORT BESTFIT2(L1,L2)

BEGIN

// 2017-11-02 EWS

// Simulate Best Fit

// HP 48GX,49G,50g

// additional models

// initialize

LOCAL clist,m,c,v,s;

clist:={0,0,0,0,0,0,0,0};

// test

// correlation is linear only

// requires approx()

// linear y=a*x+b

clist[1]:=approx(correlation(L1,L2));

// log y=a*LN(x)+b

c:=approx(correlation(LN(L1),L2));

IF IM(c)==0 THEN

clist[2]:=c;

END;

// exponential y=b*e^(a*x)

c:=approx(correlation(L1,LN(L2)));

IF IM(c)==0 THEN

clist[3]:=c;

END;

// power y=b*a^x

c:=approx(correlation(LN(L1),LN(L2)));

IF IM(c)==0 THEN

clist[4]:=c;

END;

// inverse y=b+a/x

IF POS(L1,0)==0 THEN

clist[5]:=approx(correlation(1/L1,

L2));

END;

// simple logistic

IF POS(L2,0)==0 THEN

clist[6]:=approx(correlation(e^(−L1),

1/L2));

END;

// simple quadratic

clist[7]:=approx(correlation(L1^2,

L2));

// square root

IF ΣLIST(L2≥0)==SIZE(L2) THEN

clist[8]:=approx(correlation(L1,

L2^2));

END;

// test

// POS(L0^2,MAX(L0^2))

m:=POS(clist^2,MAX(clist^2));

c:=clist[m];

IF m==1 THEN

v:=linear_regression(L1,L2);

s:=STRING(v[2])+"+"+STRING(v[1])+

"*X";

END;

IF m==2 THEN

v:=logarithmic_regression(L1,L2);

s:=STRING(v[2])+"+"+STRING(v[1])+

"*LN(X)";

END;

IF m==3 THEN

v:=exponential_regression(L1,L2);

s:=STRING(v[2])+"*"+STRING(v[1])+

"^X";

END;

IF m==4 THEN

v:=power_regression(L1,L2);

s:=STRING(v[2])+"*X^"+

STRING(v[1]);

END;

// inverse

IF m==5 THEN

v:=linear_regression(1/L1,L2);

s:=STRING(v[2])+"+"+STRING(v[1])+

"/X";

END;

// simple logistic

IF m==6 THEN

v:=linear_regression(e^(−L1),

1/L2);

s:="1/("+STRING(v[2])+"+"+

STRING(v[1])+"*e^(−X))";

END;

// simple quadratic

IF m==7 THEN

v:=linear_regression(L1^2,L2);

s:=STRING(v[2])+"+"+STRING(v[1])+

"*X^2";

END;

// square root

IF m==8 THEN

v:=linear_regression(L1,L2^2);

s:="√("+STRING(v[2])+"+"+

STRING(v[1])+"*X)";

END;

RETURN {s,c};

END;

Examples – BESTFIT2:

Example 4:

X	y
1.05	10.45
2.28	11.33
4.20	16.38
6.34	28.87

Result:  {“9.0573970192+0.48023219108*X^2”, 0.994491728382}

Example 5:

X	y
1	8.4853
2	8.9443
4	9.7980
7	10.9546

Result: {“√(63.9995089183+8.00048914762*X”, 0.999999999759}

Example 6:

X	y
1	1
2	-0.5
3	-1
4	-1.25

Result:  {“-2+3/X”, 1}

Eddie

This blog is property of Edward Shore, 2017

HP 20S and HP 21S: Simple Logistic Regression

HP 20S and HP 21S:  Simple Logistic Regression

For the HP Prime and TI-84 Plus CE versions, please click here:  http://edspi31415.blogspot.com/2017/04/hp-prime-and-ti-84-plus-ce-simple.html

This program attempts to fit a simple logistic curve of data (X, Y) to the equation:

y = 1/(A + B*e^(-x))

By the following transformations:

X’ = e^(-X)  

Y’ = 1/Y

And performing linear regression analysis on X’ and Y’.   Note that the data point which includes Y = 0 is not allowed. 

The keystrokes for the HP 20S and HP 21S are slightly different.  Each program will be shown separately.

Input:

Initialize the data:  XEQ A

For each data point:  x, [INPUT], y, XEQ B

Calculate the parameters:  XEQ C.  B is shown first, then A.

HP 20S Program: Simple Logistic Regression

STEP	CODE	KEY
01	61, 41, A	LBL A
02	61, 75	CLRΣ
03	61, 26	RTN
04	61, 41, B	LBL B
05	15	1/X
06	51, 31	SWAP
07	32	+/-
08	12	e^x
09	51, 31	SWAP
10	16	Σ+
11	61, 26	RTN
12	61, 41, C	LBL C
13	61, 16	m, b
14	26	R/S
15	51, 31	SWAP
16	61, 26	RTN

HP 21S Program: Simple Logistic Regression

STEP	CODE	KEY
01	61, 41, A	LBL A
02	61, 75	CLRΣ
03	61, 26	RTN
04	61, 41, B	LBL B
05	15	1/X
06	51, 31	SWAP
07	32	+/-
08	12	e^x
09	51, 31	SWAP
10	16	Σ+
11	61, 26	RTN
12	61, 41, C	LBL C
13	51, 14	m, b
14	26	R/S
15	51, 31	SWAP
16	61, 26	RTN

Like the last post (minimum and maximum), this is one of my favorite programs I have done this year.  I think the Wheatstone circuit would also make the list.

Eddie

This blog is property of Edward Shore, 2017