HP 42S/DM42/Free42: Predicting Freezing Levels and Turn Performance

HP 42S/DM42/Free42:  Predicting Freezing Levels and Turn Performance

Predicting Freezing Levels

The program FREEZE calculates the freezing elevation heights for two situations:

Dry:  Freezing level in clear weather.   The Aviation Pac (see source below) uses a drop rate of 2 °C/1000 ft in its calculation.

Wet:  Freezing level in clouds on a relatively clear day.  Accuracy tends to lessen for cloudy or rainy days.  The Aviation Pac (see source below) uses a drop rate of 1.5   °C/1000 ft in its calculation.

In general, the freezing level is calculated as:

FL = ALT + T * drop rate

ALT = altitude of the observer
T = temperature

The program FREEZE allows the user to choose from a set of units: (Fahrenheit vs. Celsius,  feet vs. meters).

1.  °F, ft
2.  °C, ft
3.  °F, m
4.  °C, m

HP 42S/DM42/Free42 Program FREEZE

00 { 204-Byte Prgm }
01▸LBL "FREEZE"
02 "TEMP?"
03 PROMPT
04 CLMENU
05 "°F FT"
06 KEY 1 GTO 01
07 "°C FT"
08 KEY 2 GTO 02
09 "°F M"
10 KEY 3 GTO 03
11 "°C M"
12 KEY 4 GTO 04
13 MENU
14▸LBL 00
15 STOP
16 GTO 00
17▸LBL 01
18 32
19 -
20 1ᴇ3
21 ×
22 ENTER
23 ENTER
24 3.6
25 ÷
26 X<>Y
27 2.7
28 ÷
29 GTO 05
30▸LBL 02
31 1ᴇ3
32 ×
33 ENTER
34 ENTER
35 2
36 ÷
37 X<>Y
38 1.5
39 ÷
40 GTO 05
41▸LBL 03
42 32
43 -
44 1ᴇ3
45 ×
46 ENTER
47 ENTER
48 1.09728
49 ÷
50 X<>Y
51 0.82296
52 ÷
53 GTO 05
54▸LBL 04
55 1ᴇ3
56 ×
57 ENTER
58 ENTER
59 0.6096
60 ÷
61 X<>Y
62 0.4572
63 ÷
64 GTO 05
65▸LBL 05
66 "ALTITUDE?"
67 PROMPT
68 STO+ ST Z
69 STO+ ST Y
70 R↓
71 CLMENU
72 EXITALL
73 "Y: DRY X:WET"
74 AVIEW
75 STOP
76 RTN
77 .END.

Example:
Temperature:  40 °F
Altitude:  3970 ft  (choose °F, ft)

Results:
Dry:  6192.2222 ft
Wet:  6932.9630 ft

Download freeze_level.raw here:  https://drive.google.com/open?id=13rIbpyxaR73DZnP-kau4r5i1PvQPo-_u

Turn Performance

The program TURN calculates four parameters when it comes to performance of an aircraft:

1.  The G-force

2.  The stall speed when bank angle is considered

3.  The diameter of an airplane's 360° turn

4.  The time it takes an airplane to turn 360°

The program sets the calculator to Degrees Mode.  The units are in feet for distance and knots for speed.

Memory Registers Used:

Input:
R01 = bank angle, in degrees (prompted)
R02 = true airspeed, TAS, in knots (prompted)
R03 = stall speed, in knots (prompted)

Output:
R04 = G-Force
R05 = turn diameter in nautical miles
R06 = time for a 360° to be completed in minutes
R07 = stall speed when bank angle is considered, in knots

HP 42S/DM42/Free42 Program TURN

00 { 157-Byte Prgm }
01▸LBL "TURN"
02 DEG
03 "SPEED IN KNOTS"
04 AVIEW
05 PSE
06 PSE
07 "TRUE AIR SPEED?"
08 PROMPT
09 STO 02
10 "NORM STALL?"
11 PROMPT
12 STO 03
13 "BANK? °"
14 PROMPT
15 STO 01
16 COS
17 1/X
18 STO 04
19 "G FORCE:"
20 ARCL ST X
21 AVIEW
22 STOP
23 SQRT
24 RCL× 03
25 STO 07
26 "STALL: "
27 ARCL ST X
28 AVIEW
29 STOP
30 RCL 01
31 TAN
32 1/X
33 RCL× 02
34 ENTER
35 ENTER
36 RCL× 02
37 34028
38 ÷
39 STO 05
40 "DIA: "
41 ARCL ST X
42 ├" N.M."
43 AVIEW
44 STOP
45 X<>Y
46 55ᴇ-4
47 ×
48 STO 06
49 CLA
50 ARCL ST X
51 ├" MIN"
52 AVIEW
53 .END.

Example:

Input:
True Air Speed (cruising speed):  107 knots
Stall speed:  54 knots
Bank:  30°

Output:
G Force:  1.1547
Stall:  58.0268 knots
Diameter:  0.5828 nautical miles
Time:  1.0193 minutes  (about 1 minute, 1.1 seconds)

Download turn_performance.raw here:  https://drive.google.com/open?id=1a_JFufFZUrRho44j-q4q25gy_BAZckr0

Source:

"Predicting Freezing Levels" and "Turn Performance"   HP 65 Aviation Pac 1.  Hewlett Packard, 1974


Eddie

All original content copyright, © 2011-2020.  Edward Shore.   Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited.  This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author.

HP 42S/DM42/Free42: Rate of Climb and Descent, Head and Cross Winds

HP 42S/DM42/Free42:   Rate of Climb and Descent, Head and Cross Winds

Rate of Climb and Descent

The solver CLIMB creates a solver of the equation:

ROC = TAS * ALT / √(DIST^2 + ALT^2)

ROC:  rate of climb, usually in ft/min
TAS:  true airspeed of the airplane, usually in knots
ALT:  (vertical distance) the change in elevation, take into the account the height of your airplane, the height of the mountain or obstacle to be cleared plus desired clearance height, usually in feet
DIST:  (horizontal distance) distance to the mountain or obstacle to be cleared

For the solver to accurate, you must keep the units consistent (feet or nautical miles for distance,  ft/min or knots for speed and rate of climb)

Conversion factors:

1 knot = 101.269 ft/min

1 nautical mile = 6076.12 ft

HP 42S/DM42/Free42 Solver program CLIMB

00 { 61-Byte Prgm }
01▸LBL "CLIMB"
02 MVAR "TAS"
03 MVAR "ALT"
04 MVAR "DIST"
05 MVAR "ROC"
06 RCL "TAS"
07 RCL× "ALT"
08 RCL "DIST"
09 X↑2
10 RCL "ALT"
11 X↑2
12 +
13 SQRT
14 ÷
15 RCL- "ROC"
16 .END.

Example:
TAS = 90 knots = 9114.21 ft/min
ALT = 5000 ft
DIST = 16 nautical miles = 97217.92 ft

Solve for ROC:  468.1328 ft/min

Link to download (climb_solver.raw):  https://drive.google.com/open?id=1Zd_Gyj8RJ_ehaozjBB9hfP5Gj_s1QBAS

Head Winds and Cross Winds

The program WINDS calculates the head wind and cross wind (right is positive, left is negative) given the following inputs:

D:  reported wind direction
HDG:  heading of the aircraft
V:  compass magnetic variation, if any 

The directions are entered in degrees, measured from true north, clockwise

K:  reported wind velocity

Head wind:
HW = K cos(D - HDG - V)

Cross wind:
CW = K sin(D - HDG - V)

We can use the polar to rectangular conversion function with the following convention:

θ = D - HDG - V
r = K

HP 42S/DM42/Free42 Program WINDS

00 { 79-Byte Prgm }
01▸LBL "WINDS"
02 DEG
03 "WIND DIR?"
04 PROMPT
05 "HEADING?"
06 PROMPT
07 -
08 "COMP VAR?"
09 PROMPT
10 -
11 "WIND VELOCITY?"
12 PROMPT
13 →REC
14 "Y:CROSS X:HEAD"
15 AVIEW
16 STOP
17 RTN
18 .END.

Example:
Wind Direction:  30°
Heading of Aircraft:  350°
No compass adjustment
Wind Velocity:  20 knots

Results:
Y: cross winds:  12.8558 knots (from the right)
X:  head winds:  15.3209 knots

Link to download (winds_head_and_cross.raw):  https://drive.google.com/open?id=1RoIKgbnAWmT36pLn6MHMqKXmUw19e3wh

Source:

"Rate of Climb and Descent" and "Head Winds and Cross Winds"   HP 65 Aviation Pac 1.  Hewlett Packard, 1974

Eddie

All original content copyright, © 2011-2020.  Edward Shore.   Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited.  This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author.