Fun with Radio Shack EC-4019 and Casio fx-3800P

Fun with Radio Shack EC-4019 and Casio fx-3800P

First blog entry of the 10th year of this blog (4/11/2020 - 4/11/2021).  I can't expression enough gratitude for your support and comments - Eddie

Sums

n
∑ x  = (n^2 + n) / 2
x = 1

Program (9 steps):

ENT
Kin 1
x^2 
+
Kout 1
=
÷ 
2 
= 

Execution:  [ # ] n [ RUN ]

where [ # ] represents program keys [ I ], [ II ], [ III ], and [ IV ] in RUN mode ( [ MODE ] [ . ] )

Example:  n = 48, Result:  1176

n
∑ x^2 = n * ((n/3 + 1/2) * n + 1/6 )
x=1

Program (16 steps):

ENT
Kin 1
*
(
Kout 1
x^2
÷ 
3
+
Kout 1
÷
2 
+
6
1/x
=

Execution:  [ # ] n [ RUN ]

Example:  n = 48, Result:  38024

Horner's Rule:  Cubic Polynomials

Calculate p(x) by Horner's Rule where:

p(x) = a*x^3 + b*x^2 + c*x + d = x * ( x * ( a*x + b ) + c ) + d

Program (16 steps):

Kout 5
+
Kout 1
*
(
Kout 4
+ 
Kout 1
* 
(
Kout 2
*
Kout 1
+ 
Kout 3
=

Execution:  x [ Kin ] 1, a [ Kin ] 2, b [ Kin ] 3, c [ Kin ] 4, d [ Kin ] 5.   Press [ # ]

Example:  x = K1 = 50, a = K2 = 1, b = K3 = 4, c = K4 = 5, d = K5 = -200
Result:  135,050

Head Winds And Cross Winds

Head Winds:
HW = K * cos(D - HDG - V)

Cross Winds:
RCW = K * sin(D - HDG - V)

where:
K = wind velocity (mi/hr)  (K1)
D = wind direction with 0° due North, clockwise (degrees)  (K2)
HDG = airplane direction with 0° due North, clockwise (degrees)  (K3)
V = compass adjustment   (K4)

Mode 4: Degrees

Program (13 steps):

Mode
4        //  Degree mode
Kout 1
P → R 
(
Kout 2 
-
Kout 3
-
Kout 4
= 
HLT   // HW
X ←→ Y  // RCW

Execution:
K [ Kin ] 1,  D [ Kin ] 2,  HDG [ Kin ] 3,  V [ Kin ] 4.  Press [ # ].

Example:
K = 25 mi/hr = K1
D = 240° = K2
HDG = 280°  = K3
V = 0  = K4

Results:
HW:  19.15111108 mi/hr
RCW:  -16.09699024 mi/hr

Source:  HP 65 Aviation Pac-1 Hewlett Packard.  1974

Rate of Climb

Rate of Climb (ft/min):
ROC = TAS * ALT ÷ √( DIST^2 + ALT^2 )

where:
TAS = true airplane speed (ft/min)   (K1)
ALT = vertical distance (ft)   (K2)
DIST = horizontal distance (ft)   (K3)

Conversion factors:
1 knot = 101.269 ft/min
1 nautical mile = 6072.12 ft

Program (13 steps):

Kout 1
*
Kout 2
÷
(
Kout 2
x^2
+ 
Kout 3
x^2
)
√
=

Execution:
TAS [ Kin ] 1,  ALT [ Kin ] 2,  DIST [ Kin ] 3.  Press [ # ].

Example:
TAS = 4,300 ft/min = K1
ALT = 3,000 ft = K2
DIST = 81,425 ft = K3

Result:  ROC: 158.3205808 ft/min

Source:  HP 65 Aviation Pac-1 Hewlett Packard.  1974

Modulus

For positive integers N, M:
N mod M = ( N / M - int(N / M) ) * M

Results lie in the interval [ -int( M / 2 ), int( M / 2 ) ]

Program (16 steps):

MODE
7
0     // Fix 0 mode 
Kout 2
1/x
*
Kout 1
= 
Kin 3
- 
Kout 3
RND   // round displayed number to settings
=
*
Kout 2
=

Execution:
N [ Kin ] 1,  M  [ Kin ] 2.  Press [ # ].

Examples:

48 mod 17 = -3  (equivalent to 48 mod 17 = 14)

721 mod 21 = 7


Eddie

All original content copyright, © 2011-2020.  Edward Shore.   Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited.  This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author.

HP 42S/DM42/Free42: Rate of Climb and Descent, Head and Cross Winds

HP 42S/DM42/Free42:   Rate of Climb and Descent, Head and Cross Winds

Rate of Climb and Descent

The solver CLIMB creates a solver of the equation:

ROC = TAS * ALT / √(DIST^2 + ALT^2)

ROC:  rate of climb, usually in ft/min
TAS:  true airspeed of the airplane, usually in knots
ALT:  (vertical distance) the change in elevation, take into the account the height of your airplane, the height of the mountain or obstacle to be cleared plus desired clearance height, usually in feet
DIST:  (horizontal distance) distance to the mountain or obstacle to be cleared

For the solver to accurate, you must keep the units consistent (feet or nautical miles for distance,  ft/min or knots for speed and rate of climb)

Conversion factors:

1 knot = 101.269 ft/min

1 nautical mile = 6076.12 ft

HP 42S/DM42/Free42 Solver program CLIMB

00 { 61-Byte Prgm }
01▸LBL "CLIMB"
02 MVAR "TAS"
03 MVAR "ALT"
04 MVAR "DIST"
05 MVAR "ROC"
06 RCL "TAS"
07 RCL× "ALT"
08 RCL "DIST"
09 X↑2
10 RCL "ALT"
11 X↑2
12 +
13 SQRT
14 ÷
15 RCL- "ROC"
16 .END.

Example:
TAS = 90 knots = 9114.21 ft/min
ALT = 5000 ft
DIST = 16 nautical miles = 97217.92 ft

Solve for ROC:  468.1328 ft/min

Link to download (climb_solver.raw):  https://drive.google.com/open?id=1Zd_Gyj8RJ_ehaozjBB9hfP5Gj_s1QBAS

Head Winds and Cross Winds

The program WINDS calculates the head wind and cross wind (right is positive, left is negative) given the following inputs:

D:  reported wind direction
HDG:  heading of the aircraft
V:  compass magnetic variation, if any 

The directions are entered in degrees, measured from true north, clockwise

K:  reported wind velocity

Head wind:
HW = K cos(D - HDG - V)

Cross wind:
CW = K sin(D - HDG - V)

We can use the polar to rectangular conversion function with the following convention:

θ = D - HDG - V
r = K

HP 42S/DM42/Free42 Program WINDS

00 { 79-Byte Prgm }
01▸LBL "WINDS"
02 DEG
03 "WIND DIR?"
04 PROMPT
05 "HEADING?"
06 PROMPT
07 -
08 "COMP VAR?"
09 PROMPT
10 -
11 "WIND VELOCITY?"
12 PROMPT
13 →REC
14 "Y:CROSS X:HEAD"
15 AVIEW
16 STOP
17 RTN
18 .END.

Example:
Wind Direction:  30°
Heading of Aircraft:  350°
No compass adjustment
Wind Velocity:  20 knots

Results:
Y: cross winds:  12.8558 knots (from the right)
X:  head winds:  15.3209 knots

Link to download (winds_head_and_cross.raw):  https://drive.google.com/open?id=1RoIKgbnAWmT36pLn6MHMqKXmUw19e3wh

Source:

"Rate of Climb and Descent" and "Head Winds and Cross Winds"   HP 65 Aviation Pac 1.  Hewlett Packard, 1974

Eddie

All original content copyright, © 2011-2020.  Edward Shore.   Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited.  This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author.

Fun with the FX-603P Emulator

Fun with the FX-603P Emulator

Author for the Emulator:  Martin Krischik

Link to Emulator (Android):  https://play.google.com/store/apps/details?id=net.sourceforge.uiq3.fx603p&hl=en

Web Page:  http://fx-602p.krischik.com/index.php/FX-603P/HomePage

Cost: $5.99 (there is an fx-602P scientific calculator emulator for $4.99, similar programming language but only 10 programming spaces instead of 20)

The app is emulates the 1990 Casio fx-603P calculator.

Decibels to Pressure

Program: (29 steps)

“DB?”  HLT  ÷ 20  = 10^x  *  2E-5  = “Pressure:” HLT

Examples:

DB = 30 dB; Result:  6.32455532 * 10^-4 N/m^2

DB = 120 dB; Result:  20 N/m^2

Turn Performance

Given a plane’s true air speed (TAS in knots), stall speed (in knots), and required bank turn (in degrees), the following are calculated:

1. G force

2.  Normal stall speed for the plane during the turn (knots)

3.  Turn diameter (nautical miles)

4.  Time it takes for the turn to be complete (in minutes)

Formulas:

G = 1/(cos(bank))

Stall speed = normal stall speed * √G

Diameter = TAS^2 / (34208 * tan(bank))

Time = (0.0055 * TAS) / tan(bank)

Memory Registers:

Input:

M00 = TAS, M01 = Stall speed, M02 = Bank

Output:

M03 = G force, M04 = resulting stall speed, M05 = diameter, M06 = time

Program: (110 steps)

DEG “TAS?” HLT Min00

 “Norm. Stall?” HLT  Min01

 “Bank?” HLT Min02

MR02 cos 1/x Min03 “G:” HLT

MR03 √ * MR01 = “Stall Speed:” HLT

MR00 x^2 ÷ ( MR02 tan * 34208 ) = Min05 “Diameter:” HLT

0.0055 * MR00 ÷ MR02 tan “Time:” HLT Min06

Notes: 

DEG:  [ MODE ] [ 4 ]

Example:

Inputs:

TAS: 123 knots

Norm. Stall:  60 knots

Bank:  44.8°

Results:

G:  1.409302674

Stall Speed: 71.22843498 knots

Diameter:  0.445363387 n.m.

Time: 0.681239424 minutes (about 40.87 seconds)

Source:  “Turn Performance” HP 65 Aviation Pac-1 Hewlett Packard.  1974

.

Sum of a Function

This program uses the subroutine (under P9 with the variable MinF, or any register M04 or after) to calculate the summation:

Σ f(x) for x = a to b

The sum is stored in M03.

Note: when entering a new f(x), clear P9 (MODE, 3, P9, AC) first before entering the new function.  It’s a lot cleaner.

Main Program:  (34 bytes)

0 Min03

“a?” HLT Min01

“b?” HLT Min02

MR02 – MR01 + 1 = Min00

Lbl0

MR01 GSBP9 M+03

1 M+01

DSZ Goto0

MR03 “Σ=”

Note: 

Lbl0:  [ LBL] [ 0 ]

GSBP9: [GSB] [ P9 ]

Goto0:  [ GOTO ] [ 0 ]

The character Σ:  (in ALPHA) [SHIFT] [ 7 ]

Memory F:  [ Min ], [ MR ], etc.  [EXE] for F.

Examples:

Σ n^2 + 3*n – 6 for n = 1 to 8 

Subroutine:

Min0F x^2 + 3 * MR0F – 6 =

Result:  264

Σ (n^3 – 1)/(n^2 + 1) for n = 0 to 11

Subroutine:

( Min0F x^y 3 – 1 ) /div (MR0F x^2 + 1 ) =

Result: 61.6582396282

Combinations: where Repetition is allowed

The program calculates the number of combinations where repeats are allowed.

nHr = (n + r – 1)! / (r! * (n -1)!)

Program:  (39 steps)

“n?” HLT Min01

“r?” HLT Min02

( MR01 + MR02 – 1) x!

÷ ( MR02 x! * ( MR01 – 1 ) x! )

= “nHr=”

Examples:

Input: n = 5, r = 3.  Result:  35

Input: n = 12, r = 6.  Result:  12376

Aviation:  Rate of Climb

This program calculates the rate-of-climb (ft/min) when plane increases the elevation (in feet) given the distance to the mountain (in nautical miles, n.m.) and the true air speed (TAS, in knots). 

Formula:

ROC = ( TAS * ΔALT  ) / (60 * √(dist^2 + (ΔALT/6077.1155)^2) )

Program: (88 steps)

6077.1155 Min0F

“TAS (knots)?” HLT Min01

“CHG ALT (ft)?” HLT Min02

“DIST (n.m.)?” HLT Min03

( MR01 * MR02 ) ÷

( 60 * ( MR03 x^2 + (

MR02 ÷ MR0F ) x^2

)   √ = “ROC:”

Example:

Input:

TAS = 87 knots

CHG ALT = 4800 ft

DIST = 13.3 n.m.

Result:

522.3878955 ft/min

Source:  “Rate of Climb and Descent” HP 65 Aviation Pac-1 Hewlett Packard.  1974

Eddie

All original content copyright, © 2011-2018.  Edward Shore.   Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited.  This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author.  Please contact the author if you have questions.