HP 42S DM42 Smith Chart Conversions

HP 42S DM42 Smith Chart Conversions

Smith Conversions

Introduction

The program SMITH brings generates a custom menu that allows the user to convert between four factors: 

RL:  return loss
p:  reflection coefficient
s:  voltage standing ratio
SWR:  standing wave ratio

p = 10^-(RL/20)
s = (1 + p)(1 - p)
SWR = 20 * log s

Programs here:

HP 42S/DM42 Program:  SMITH

00 { 111-Byte Prgm }
01▸LBL "SMITH"
02 "RL>p"
03 KEY 1 GTO 01
04 "p>s"
05 KEY 2 GTO 02
06 "s>SWR"
07 KEY 3 GTO 03
08 "SWR>s"
09 KEY 4 GTO 04
10 "s>p"
11 KEY 5 GTO 05
12 "p>RL"
13 KEY 6 GTO 06
14 MENU
15▸LBL 07
16 STOP
17 GTO 07
18▸LBL 01
19 +/-
20▸LBL 04
21 20
22 ÷
23 10↑X
24 RTN
25▸LBL 02
26 STO 00
27 1
28 +
29 1
30 RCL- 00
31 ÷
32 RTN
33▸LBL 05
34 STO 00
35 1
36 -
37 1
38 RCL+ 00
39 ÷
40 RTN
41▸LBL 06
42 1/X
43▸LBL 03
44 LOG
45 20
46 ×
47 RTN
48 .END.

Example 1

Convert SWR of 12 to RL:

[XEQ]  (SMITH)
12  (SWR>s)  (s>p) (p>RL)

Result:  4.45901

Conversions Between Complex Reflection Coefficient and Impedance

It is recommended that you set the calculator to Degree and Polar modes.  To enter complex numbers in polar mode,

Z→R:  Convert from impedance to complex reflection coefficient
Stack:  Z, Z0 (characteristic impedance)

Γ = (Z/Z0 - 1) / (Z/Z0 + 1)

R→Z:  Convert from complex reflection coefficient to impedance
Stack:  Z0, Γ

Z = Z0 * (1 + Γ) / (1 - Γ)

HP 42S/DM42 Programs:  Z→R and R→Z

00 { 19-Byte Prgm }
01▸LBL "Z→R"
02 ÷
03 ENTER
04 ENTER
05 1
06 -
07 X<>Y
08 1
09 +
10 ÷
11 RTN
12 .END.

00 { 20-Byte Prgm }
01▸LBL "R→Z"
02 ENTER
03 ENTER
04 1
05 +
06 X<>Y
07 1
08 -
09 +/-
10 ÷
11 ×
12 RTN
13 .END.

Example 2

In a system with the resistance of 66 Ω has the impedance of 10 ∠ 15°.  What is the reflection coefficient?

(Degree and Polar Mode)
10 [ENTER] 15 [(shift)] (COMPLEX) 66 
[XEQ]  ( Z→R )

Result:  0.40469 ∠ -163.92848

Example 3

What is the impedance of a system with a reflection coefficient of 0.86∠50° with a resistor of 125 Ω?

(Degree and Polar Mode)
125 [ENTER] 0.86 [ENTER] 50 [(shift)] (COMPLEX)
[XEQ] (  R→Z )

Result:  246.80096 ∠ 78.82055°

Source: 

Step-by-Step Solutions For Your HP Calculator: Engineering Applications (HP-32S).  Hewlett Packard.  Edition 1. Corvallis, OR  June 1988

Eddie

All original content copyright, © 2011-2019.  Edward Shore.   Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited.  This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author.

HP Prime and HP 42S: Noise Figure and Noise Voltage

HP Prime and HP 42S:  Noise Figure and Noise Voltage

Notes:  The programs for the HP 42S format are designed to work with the HP 42S's solver.  The programs were created using Thomas Okken's Free42, and should also be compatible with the Swiss Micros DM42.

Noise Figure

Given system temperature (in Kelvins), this program calculates the noise figure (in Decibels), which describes the noise performance of an amplifier.  The noise figure is described as the difference between the noise output of an actual receiver to an ideal, noiseless receiver.  A noiseless receiver is said to have a resistor operating at room temperature, 290 K (about 16.85°C or 62.33°F). The lower the noise figure, the better.

Formula:

F = 10 * log(T/290 + 1)

where:

F = noise figure (dB)
T = system temperature (K)

HP Prime Program Function:  NOISEDB

EXPORT NOISEDB(T)
BEGIN
// Noise Figure in dB
// Input: T: Temperature (K)
// 2019-01-04 EWS
10*LOG(T/290+1);
END;

HP 42S Program for Solver:  NSEFG

00 { 35-Byte Prgm }
01▸LBL "NSEFG"
02 MVAR "F"
03 MVAR "T"
04 RCL "T"
05 290
06 ÷
07 1
08 +
09 LOG
10 10
11 ×
12 RCL "F"
13 -
14 END

Example (Fix 4):

Input:  T = 57.8°F, convert it to Kelvins, enter 287.4833 K (approximately)
Result:  F = 2.9914 dB

Noise Voltage

Given the noise bandwidth (in Hertz) and the resistance (in Ω), calculate the open-circuit voltage (in RMS volts).

Formula:

e_n = √(1.6*10^-20 * B * R)

where:

e_n = open circuit voltage noise (RMS volts)
B = bandwidth (Hz)
R = resistance (Ω)

HP Prime Program Function: NOISEVOLT

EXPORT NOISEVOLT(b,r)
BEGIN
// Noise Voltage in V
// Input: B=bandwidth (Hz)
// Input: R=resistor (Ω)
// input numbers only
√(1.6ᴇ−20*b*r);
END;

HP 42S Program for Solver:  NSEVT

00 { 37-Byte Prgm }
01▸LBL "NSEVT"
02 MVAR "B"
03 MVAR "R"
04 MVAR "En"
05 16ᴇ-21
06 RCL× "B"
07 RCL× "R"
08 SQRT
09 RCL- "En"
10 .END.

Example (FIX 4):

Input:  B = 31,000 Hz, R = 950 Ω
Result:  e_n = 6.8644e-7 V

Sources: 

Ball, John A.  Algorithms For RPN Calculators  John Wiley & Sons: New York  1978.  ISBN 0-471-03070-8

Eddie

All original content copyright, © 2011-2018.  Edward Shore.   Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited.  This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author.  Please contact the author if you have questions.

Update to the Big Font Math Reference

Original post:  https://edspi31415.blogspot.com/2018/04/april-11-2018-seven-years.html

I added several sections to the Big Math Reference document, which you can download on the right side of the blog.

What is added:

* Days Between Dates Algorithm
*  Astronomy Formulas: Kepler's 3rd Law, Parallax, Luminosity, Schwartzchild Radius
*  Physics:  Projectile Motion, Linear Motion, Angular Motion
*  Electronics:  Ohm's Law, Resistance

Eddie

Casio fx-3650p and HP 21S: Minimum Loss Matching

Casio fx-3650p and HP 21S: Minimum Loss Matching

This program takes the incoming impedances Z0 (from left) and Z1 (from right), and determines the resistance R1 and R2, with the corresponding minimum loss.  The program assumes that Z0 and Z1 are both positive and Z0 ≥ Z1. 

Formulas Used:

R1 = Z0 * √(1 – Z1/Z0)

R2 = Z1 / √(1 – Z1/Z0)

Minimum loss = 20 * log (√(Z1/Z0) + √(Z1/Z0 -1))

Casio fx-3650P

Input:  X = Z0, Y = Z1

Program (49 steps):

? → X : ? → Y : Y ÷ X → M :

X √ ( 1 – M → A ◢

Y √ ( 1 – M → B ◢

20 log ( √ M ^-1 + √ ( M ^-1 – 1 → C

HP 21S

Input:  Z0 gets stored in register 0, Z1 gets stored in register 1

Program (44 steps):

Step	Code	Key	Notes
01	61, 41, C	LBL C	Start the program
02	22, 1	RCL 1	Z1
03	45	÷
04	22, 0	RCL 0	Z0
05	74	=
06	21, 4	STO 4
07	33	(
08	1	1
09	65	-
10	22, 4	RCL 4
11	34	)
12	11	√
13	21, 5	STO 5
14	55	*
15	22, 0	RCL 0
16	74	=
17	21, 2	STO 2
18	26	R/S	Display R1
19	22, 1	RCL 1
20	45	÷
21	22, 5	RCL 5
22	74	=
23	21, 3	RCL 3
24	26	R/S	Display R2
25	33	(
26	22, 4	RCL 4
27	15	1/x
28	11	√
29	75	+
30	33	(
31	22, 4	RCL 4
32	15	1/x
33	65	-
34	1	1
35	34	)
36	11	√
37	34	)
38	51, 13	LOG
39	55	*
40	2	2
41	0	0
42	74	=
43	21, 5	STO 5	Display minimum loss (Z)
44	61, 26	RTN

Example:

Input:  Z0 = 50, Z1 = 45

Results: R1 = 15.8113883008, R2 = 142.302494708, Min Loss = 2.84419586692

Source:  Casio Scientific Formula 128 fx-1000F/fx-5000F owner’s manual, 1987

Eddie

This blog is property of Edward Shore, 2017