Saturday, June 29, 2019

HP 42S/DM42/Free 42: Auto Solvers

HP 42S/DM42/Free 42:  Auto Solvers

Introduction

This blog entry has four solvers for use the on the HP 42S (or Free42, DM42) in the subject of automobiles:

1.  Displacement, Bore, Strokes
2.  Gear Ratio, MPH, RPM
3.  Quarter Mile Estimation:  Elapsed Time, Car's Weight, Horsepower
4.  Tire Sizes

If you  are entering these programs by hand, I suggest that you create the needed variables ahead of time by storing an arbitrary value (it doesn't matter) into the variable.  Therefore when you recall the variables, they will be available in the soft menu.  Activate the solvers by pressing the orange shift key ([SHIFT]) [ 7 ] (SOLVER).

Link to the programs can be downloaded here:  https://drive.google.com/file/d/1N4wpO9Q-Mhyp51kdubAh5guf2xZhp8Tc/view?usp=sharing

1.  Displacement, Bore, Strokes  (File:  displacement.raw)

00 { 79-Byte Prgm }
01▸LBL "DISPMNT"
02 MVAR "DISPMNT"
03 MVAR "BORE"
04 MVAR "STROKE"
05 MVAR "#CYLIN"
06 PI
07 4
08 ÷
09 RCL "BORE"
10 X↑2
11 ×
12 RCL× "STROKE"
13 RCL× "#CYLIN"
14 RCL- "DISPMNT"
15 .END.

Variables:

(DISPM):  displacement of the a cylinder (cubic inches)
(BORE):  diameter of the cylinder (inches)
(STRO):  distance traveled by the piston (inches)
(#CYLI):  number of cylinders

Equation:

π/4 * bore^2 * stroke * #cylinders - displacement = 0

Example:

Bore = 4 in
Stroke = 3.5 in
4-cylinder engine

Result:  Displacement = 175.9292 in^3

2.  Gear Ratio, MPH, RPM  (File:  gearratio.raw)

00 { 74-Byte Prgm }
01▸LBL "GEARRTO"
02 MVAR "RPM"
03 MVAR "MPH"
04 MVAR "TIREDIA"
05 MVAR "GEARRAT"
06 PI
07 RCL× "RPM"
08 RCL× "TIREDIA"
09 RCL÷ "MPH"
10 1056
11 ÷
12 RCL- "GEARRAT"
13 .END.

Variables:

(RPM):  the tire's revolution per minute
(MPH):  speed of the vehicle (miles/hour)
(TIREDI): diameter of the tire (inches)
(GEAR):  gear ratio = transmission ratio * final drive ratio

Equation:

(RPM * π * tire_diameter) / (MPH * 1056) - gear_ratio = 0

Example:

RPM = 3,400 rpm
Tire Diameter = 28 in
Gear Ratio = 3.85

Result:  MPH = 73.5635 mph

3.  Quarter Mile Estimation:  Elapsed Time, Car's Weight, Horsepower
(File:  quartermile.raw)

00 { 52-Byte Prgm }
01 ▸ LBL "QRTMI"
02 MVAR "ET"
03 MVAR "WEIGHT"
04 MVAR "HP"
05 5.825
06 RCL "WEIGHT"
07 RCL÷ "HP"
08 3
09 1/X
10 Y↑X
11 ×
12 RCL- "ET"
13 .END.

Variables:

(ET): elapsed time for the car to travel 1/4 mile (seconds)
(WEIG):  weight of the car including passengers, drivers, fuel, and other items carried (pounds)
(HP):  horsepower

Equation:

(weight/horsepower)^(1/3) * 5.825 - elapsed_time = 0

Note:  MPH = (horsepower/weight)^(1/3) * 234 = 1363.05/elapsed_time

Example:

Weight:  3,540 lb
HP:  215 hp

Result:

ET: 14.8190
(MPH = 91.9802 mph,  [SHIFT] (TOP.FCN) ( 1/X ) 1363.05 [ * ])

4.  Tire Sizes (file name:  tiresize.raw)

00 { 87-Byte Prgm }
01 ▸ LBL "TIRESZE"
02 MVAR "SECWDTH"
03 MVAR "RIMDIA"
04 MVAR "ASPECT"
05 MVAR "TIREDIA"
06 2
07 RCL× "SECWDTH"
08 RCL× "ASPECT"
09 2540
10 ÷
11 RCL+ "RIMDIA"
12 RCL- "TIREDIA"
13 .END.

Variable:

(SECW):  section width (millimeter)
(RIMDI):  rim diameter (inches)
(ASEPC):  aspect ratio
(TIREDI):  tire diameter (inches)

On a side of a tire, we can get three of the four values by from a code that looks like this:

P235 / 75R17

P:  passenger car  (L for light trucks)
235:  section width
75:  aspect ratio
R:  radial tire
17: rim diameter

Equation:

(2 * section_width * aspect_ratio) / 2540 + rim_diameter - tire_diameter = 0

Example:  Use the stats of the tire above to calculate tire diameter.

Result:  30.8780 in

Source:

John Lawlor.  "Auto Math Handbook:  Mathematical Calculations, Theory, and Formulas for Automotive Enthusiasts"  HPBooks:  New York 1992  ISBN 1-55788-020-4

Eddie

All original content copyright, © 2011-2019.  Edward Shore.   Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited.  This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author.

  Casio fx-7000G vs Casio fx-CG 50: A Comparison of Generating Statistical Graphs Today’s blog entry is a comparison of how a hist...