Saturday, August 28, 2021

TI-95 ProCalc: Industrial Calculations

 TI-95 ProCalc: Industrial Calculations


Flag Sequence for Degree Mode

RF 33 RF 34

A Sample of Utility Calculations

F1:  >DB:  Decibel Function, DB = 20 * log x
F2:  IDB:  Inverse Decibel Function, x = 10^(DB ÷ 20)
F3:  PAR:  Resistance of two parallel circuits.  R = 1 ÷ ( 1÷a + 1÷b)
F4:  ANG:  Convert from Frequency to Angular Velocity. ω = 2 * π * f
F5:  FRQ:  Convert from Angular Velocity to Frequency.  f = ω ÷ ( 2 * π )

The first two functions (F1 and F2) were inspired by a unique key on the 1977 Casio fx-110 scientific calculator.  

Source:
"Casio fx-110"  Voidware.  http://www.voidware.com/calcs/fx110.htm Accessed May 30, 2021


TI-95 ProCalc File UTL

CLR 'READY' 

DFN F1: >DB @ 01

DFN F2: IDB @ 02

DFN F3: PAR @ 03

DFN F4: ANG @ 04

DFN F5: FRQ @ 05

HLT 

LBL 01 CLR 'X?' BRK LOG * 20 = 'DB=' GTL 06

LBL 02 CLR ( 'DB?' BRK / 20 ) INV LOG = 'X=' GTL 06

LBL 03 CLR ( 'A?' BRK 1/x + 'B?' BRK 1/x ) 1/x  = 'Z=' GTL 06

LBL 04 CLR 'FRQ?' BRK * 2 * PI = 'ANG=' GTL 06

LBL 05 CLR 'ANG?' BRK / ( 2 * PI ) = 'FRQ='

LBL 06 COL 16 MRG = HLT

Stairs

Inputs:

RISE:  The floor-to-floor rise of the staircase. 

MAX RISER HGHT:  The maximum allowable rise height.

TREAD WIDTH:  The desired tread width of each stair.

Outputs:

N:  Number of Stairs

TRH:  True riser height of the stair

#TRD:  Number of treads

RUN:  Total theoretical run from the first stair to the top.

INC:  Incline of the stair in degrees

STR:  Length of the stringer

All amounts are assumed to be in inches and all amounts are precise (no rounding to the nearest 1/8th inch or 1/16 inch, etc).

Formulas Used:

N = int( rise ÷ DRH ) + 1

TRH = rise ÷ N

#TRD = N - 1

RUN = #TRD * TREADWIDTH

INC = atan( TRH ÷ TREADWIDTH)

STR = T * TREADWIDTH ÷ cos INC

TI-95 ProCalc File STR
Size:  184 bytes

RF 33 RF 34 CLR 'STAIRS' PAU

CLR 'RISE (IN)?' BRK STO R

CLR 'MAX RISER HGHT?' BRK STO H

CLR 'TREADWIDTH?' BRK STO W

( RCL R / RCL H ) INT + 1 = STO N 

CLR 'N=' COL 16 MRG N BRK

RCL R / RCL N = STO T 

CLR 'TRH=' COL 16 MRG T BRK

RCL N - 1 = STO E 

CLR '#TRD=' COL 16 MRG E BRK

RCL E * RCL W = STO U 

CLR 'RUN=' COL 16 MRG U BRK

( RCL T / RCL W ) INV TAN STO A 

CLR 'INC=' COL 15 MRG A CHR 223 BRK

RCL E * RCL W / RCL A COS = STO S 

CLR 'STR=' COL 16 MRG S HLT

Example

Input:  
RISE:  120 in
MAX RISER HGHT:  7.5 in
TREADWIDTH:  10 in

Results:
N = 17
TRH = 7.058823529 in
#TRD = 16
RUN = 160 in
INC = 35.21759297°
STR = 195.8461369 in

Travel and Run of a Rolling Pipe

Inputs:

A: Bend angle in degrees

Y: Roll distance 

Z:  Vertical Offset

Outputs:

L:  length of the pipe

R:  set back of the pipe 

All amounts are assumed to be in inches and all amounts are precise (no rounding to the nearest 1/8th inch or 1/16 inch, etc).

Formulas Used:

Let W = √( Y^2 + Z^2 )

Then:

L = W ÷ (90° - cos A)

R = √(L^2 - W^2)

Source:

Heckman, Kurt  "Rolling Offset (run)"  vCalc Last Modified March 10, 2021  https://www.vcalc.com/wiki/KurtHeckman/Rolling+Offsets+%28run%29  Accessed June 5, 2021


TI-94 ProCalc File PIP
Size:  120 bytes

RF 33 RF 34 

CLR 'PIPE ROLL OFFSET' PAU

CLR 'BEND ANGLE?' BRK STO A

CLR 'ROLL DIST?' BRK STO Y

CLR 'OFFSET?' BRK STO Z

( RCL Y x^2 + RCL Z x^2 ) SQR = STO W

/ ( 90 - RCL A ) COS = STO L

'LEN=' COL 16 MRG L BRK

( RCL L x^2 - RCL W x^2 ) SQR = STO X

'SET=' COL 16 MRG X HLT

Example:

Inputs:
Bend Angle: 40°
Roll Distance: 6"
Vertical Offset: 6"

Results:
Travel = 13.20075441"
Setback = 10.11236456"

Coming Up:   Let's get Sharp

Retro Month - Sharp EL-5500 III (also known as the PC-1403) Pocket Computer - every Saturday in September 2021 


Eddie

All original content copyright, © 2011-2021.  Edward Shore.   Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited.  This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author. 

  Casio fx-7000G vs Casio fx-CG 50: A Comparison of Generating Statistical Graphs Today’s blog entry is a comparison of how a hist...