Sunday, June 26, 2022

HP 33S Integral Demonstration and Programs

HP 33S Integral Demonstration and Programs


Integration


I'm going to start with a demonstration on how to calculate integrals with the HP 33S through the equation list.  The steps will be similar for the HP 32SII and the later HP 35S.  


1.  Enter the lower limit, press [ ENTER ], the higher limit.

2.  Press [ |→ ] [ STO ] (EQN), enter or select an equation.  

3.  Press [ |→ ] [ e^x ] ( ∫ ), to calculate the integration.  You will be prompted for the variable to integrate.  


Example:  Fresnel Integral 


Select Radians angle mode.  


Fresnel Sine:  

Equation:  SIN(SQ(T)), variable to integrate:  T   

Note:  [ x^2 ] -> SQ (square)

Use lower limit as 0.


S(2.4):   lower = 0, upper = 2.4,  S(2.4) ≈ 0.457864

S(5.8):   lower = 0, upper = 5.8,  S(5.8) ≈ 0.678004


Fresnel Cosine:

Equation:  COS(SQ(T)), variable to integrate:  T   

Use lower limit as 0.


C(2.4):   lower = 0, upper = 2.4,  C(2.4) ≈ 0.510157

C(5.8):   lower = 0, upper = 5.8,  C(5.8) ≈ 0.695845


Source:

"Fresnel Integral"  Wikipedia  https://en.wikipedia.org/wiki/Fresnel_integral  Retrieved May 2, 2022


Atmospheric Parameters


Given the height (H) in meters, the following can be estimated:


Temperature in Celsius  (°C):

T ≈ 15.04 - 0.00649 * H


Pressure in kilopascals (kPa):

P ≈ 101.29 * ((T + 273.15) / 288.08)^5.256

(note, the source had 273.1 but I had 27.3.15 for better accuracy)


Atmospheric Density (km/m^3):

D ≈ P/(0.2869 * (T + 273.15))


Program:

HP 33S:  Size: LN = 174, CK = 7625


A0001  LBL A

A0002  15.04

A0003  0.00649

A0004  INPUT H

A0005  ×

A0006  -

A0007  STO T

A0008  VIEW T

A0009  273.15

A0010  +

A0011  288.08

A0012  ÷

A0013  52.56

A0014  y^x

A0015 101.29

A0016  ×

A0017  STO P

A0018  VIEW P

A0019  0.2869

A0020  273.15

A0021  RCL+ T

A0022  ×

A0023  ÷

A0024  STO D

A0025  VIEW D

A0026  RTN


Example:

H = 50 m


Results:

T ≈ 14.715580 °C  (about 58.4879 °F)

P ≈ 100.894225 kPa

D ≈ 1.221648 kg/m^3


Source:

"Engineering Formula Sheet"  Project Lead The Way. https://www.madison-lake.k12.oh.us/userfiles/680/Classes/16192/IED-Review%20Engineering%20Formula%20Sheet.pdf   Last Retrieved April 29, 2022 


Legendre Polynomials


The value of Legendre Polynomials can be calculated using a closed formula from Rodrigues' formula:


P_n(x) = Σ( comb(n, k) * comb(n+k, k) * ((x - 1)/2)^k,  k= 0, n)


Program:  

HP 33S:  

LBL L:  Size:  LN = 30, CK = 14EC

LBL M: Size:  LN = 105, CK = AA05


Run XEQ L.  


L0001  LBL L

L0002  0

L0003  STO P

L0004  INPUT X

L0005  INPUT N

L0006  STO K

M0001  LBL M

M0002  RCL N

M0003  RCL K

M0004  nCr

M0005  RCL N

M0006  RCL+ K

M0007  LASTx

M0008  nCr

M0009  ×

M0010  -1

M0011  RCL+ X

M0012  2

M0013  ÷

M0014  RCL K

M0015  y^x

M0016  ×

M0017  STO+ P

M0018  DSE K

M0019  GTO M

M0020  1

M0021  STO+ P

M0022  RCL P

M0023  RTN


Examples:

N = 2, X = 0.25;  Result:  -0.406250

N = 3, X = -0.46;  Result:  0.446660

N = 4, X = 0.73;  Result:  -0.380952


Source:

"Legendre polynomials"  Wikipedia.  https://en.wikipedia.org/wiki/Legendre_polynomials  Updated April 6, 2022.  Last Accessed April 29, 2022.  


Eddie 


All original content copyright, © 2011-2022.  Edward Shore.   Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited.  This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author. 


  Casio fx-7000G vs Casio fx-CG 50: A Comparison of Generating Statistical Graphs Today’s blog entry is a comparison of how a hist...