TI-84 Plus CE and DM42: RLC Circuits

TI-84 Plus CE and DM42: RLC Circuits

The program RLC calculates:

(1) The total impedance across the entire circuit

(2) The phase angle, sometimes known as a power factor angle

(3) The total supply current

An RLC circuit is a circuit that connects one power supply to a resistor, an inductor, and a capacitor. The resistor, inductor, and capacitor can be connected in one of two ways: series or parallel. To calculate the total impedance (Z) and phase angle (θ), the rectangular to polar conversion function can be utilized.

In a general rectangular to polar conversion, (x, y) to (r, θ):

r = √(x^2 + y^2)

θ = arctan(y / x)

Formulas

Angular Frequency: ω = 2 * π * F	F = frequency in Hz V = supply voltage (volts) R = resistor in Ω (ohms) L = inductor in H (henrys) C = capacitance (farads) I = overall current (amps)
Series RLC Circuit - Formulas Z = √(R^2 + (ω*L – 1 / (ω*C))^2) θ = arctan ( (ω*L – 1 / (ω*C)) / R) I = V / Z	Series RLC Circuit – Set up for Rectangular to Polar Conversion x = ω*L – 1 / (ω*C) y = R Z = r
Parallel RLC Circuit - Formulas 1 / Z = √( (1/R)^2 + (1/(ω*L) – ω*C)^2) θ = arctan ( (1/(ω*L) – ω*C) / (1/R)) I = V / Z	Parallel RLC Circuit – Set up for Rectangular to Polar Conversion x = 1/(ω*L) – ω*C y = 1/R Z = 1/r

TI-84 Plus Program: RLC

ClrHome

Disp “RLC CIRCUIT”

Input “SUPPLY VOLTAGE? “, V

Input “FREQUENCY (HZ)? “, F

Input “RESISTANCE (OHMS)? “, R

Input “INDUCTOR (HENRYS)? “, L

Input “CAPACITOR (FARADS)? “, C

a+bi

Degree

2*π*F → W

Menu(“TYPE”, “SERIES”, 1, “PARALLEL”, 2)

Lbl 1

R+i*(W*L-1/(W*C)) → Z

abs(Z) → N

Goto 3

Lbl 2

(1/R)+i*(1/(W*L)-W*C) → Z

abs(Z)⁻¹ → N

Lbl 3

angle(Z) → θ

V/N → I

ClrHome

Disp “IMPEDANCE:”, N

Disp “PHASE ANGLE:”, θ

Disp “SUPPLY CURRENT:”, I

DM42, HP 42S Program: RLC

00 { 216-Byte Prgm }
01▸LBL "RLC"
02 "SUPPLY VOLTAGE?"
03 PROMPT
04 STO 01
05 "FREQUENCY?"
06 PROMPT
07 STO 02
08 "RESISTANCE?"
09 PROMPT
10 STO 03
11 "INDUCTOR?"
12 PROMPT
13 STO 04
14 "CAPACITOR?"
15 PROMPT
16 STO 05
17 DEG
18 2
19 STO 06
20 PI
21 STO× 06
22 RCL 02
23 STO× 06
24 "TYPE?"
25 AVIEW
26 PSE
27 "SERIES"
28 KEY 1 GTO 01
29 "PARA."
30 KEY 2 XEQ 02
31 MENU
32▸LBL 00
33 STOP
34 GTO 00
35▸LBL 01
36 CLMENU
37 EXITALL
38 RCL 06
39 RCL× 04
40 RCL 06
41 RCL× 05
42 1/X
43 -
44 RCL 03
45 →POL
46 STO 07
47 GTO 03
48▸LBL 02
49 CLMENU
50 EXITALL
51 RCL 06
52 RCL× 04
53 1/X
54 RCL 06
55 RCL× 05
56 -
57 RCL 03
58 1/X
59 →POL
60 1/X
61 STO 07
62▸LBL 03
63 "PHASE:"
64 AVIEW
65 PSE
66 VIEW ST Y
67 STOP
68 "IMPEADANCE:"
69 AVIEW
70 PSE
71 VIEW ST X
72 STOP
73 RCL 01
74 RCL÷ 07
75 "SUPPLY CURRENT:"
76 AVIEW
77 PSE
78 VIEW ST X
79 .END.

Examples

Examples are rounded to five digits.

Series Circuit

Inputs:

SUPPLY VOLTAGE: 300 V

FREQUENCY: 70 Hz

RESISTANCE: 80 Ω

INDUCTOR: 0.09 H

CAPACITOR: 150 μF (150E-6)

Results:

IMPEDANCE (Z) ≈ 83.64599 Ω

PHASE ANGLE (θ) ≈ 16.97904°

CURRENT (I) ≈ 3.58654 A

Parallel Circuit

Inputs:

SUPPLY VOLTAGE: 240 V

FREQUENCY: 90 Hz

RESISTANCE: 60 Ω

INDUCTOR: 20 mH (20E-3)

CAPACITOR: 140 μF (140E-6)

Results:

IMPEDANCE (Z) ≈ 52.46010 Ω

PHASE ANGLE (θ) ≈ 29.05363°

CURRENT (I) ≈ 4.57491 A

Sources

“Impedance and Complex Impedance” https://www.electronics-tutorials.ws/accircuits/impedance.html

“Parallel RLC Circuit Analysis” https://www.electronics-tutorials.ws/accircuits/parallel-circuit.html

“Series RLC Circuit Analysis” https://www.electronics-tutorials.ws/accircuits/series-circuit.html

Electronics Tutorials. AspenCore, Inc. 2024. Retrieved October 7, 2024 and October 17, 2024.

Eddie

All original content copyright, © 2011-2025. Edward Shore. Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited. This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author.

TI-30Xa Algorithms: RLC Series Circuit

TI-30Xa Algorithms: RLC Series Circuit

The task is to calculate the total impedance and phase angle for an RLC circuit in a series. An RLC circuit contains a resistor ( R ), an inductor ( L ), and a capacitor ( C ) , all powered by a voltage supply. The resistor, inductor, and capacitor are all in a single path.

The three elements are measured in the following units:

Resistor ( R ): Ohms ( Ω )

Inductor ( L ): Henry ( H )

Capacitor ( C ): Farads ( F )

The impedance for the RLC circuit is calculated by:

Z = √( R^2 + ( (2 * π * f * L) - 1 / (2 * π * f * C) )^2 )

The phase angle is calculated by:

θ = arctan( ( (2 * π * f * L) - 1 / (2 * π * f * C) ) / R )

where: f = frequency in Hertz (Hz)

We can use the rectangular to polar conversion function (R>P) to calculate both the impedance and phase angle.

x = R

y = (2 * π * f * L) - 1 / (2 * π * f * C)

If we have an RL circuit, with no capacitor, then C = 0.

If we have an RC circuit, with no inductor, then L = 0.

If we have an LC circuit, with no resistor, then R = 0.

TI-30Xa Algorithm – RLC Circuit

Step 1: Store resistance in Memory 1.

R [ STO ] 1

Step 2: Calculate angular frequency, ω = 2 * π * f, store in memory 3.

2 [ × ] [ π ] [ × ] f [ = ] [ STO ] 3

Step 3: Calculate (2 * π * f * L) - 1 / (2 * π * f * C)

[ RCL ] 3 [ × ] L [ - ] [ ( ] [ RCL ] 3 [ × ] C [ ) ] [ 1/x ] [ = ] [ STO ] 2

If we have an RL circuit, Steps 2 and 3 can be shortened to:

2 [ × ] [ π ] [ × ] f [ × ] L [ = ] [ STO ] 2

If we have an RC circuit, Steps 2 and 3 can be shortened to:

[ ( ] 2 [ × ] [ π ] [ × ] f [ × ] C [ ) ] [ 1/x ] [ +/- ] [ = ] [ STO ] 2

Step 4: Calculate Impedance and Phase Angle:

[ RCL ] 1 [ 2^nd ] [ π ] (x<>y) [ RCL ] 2 [ 2^nd ] [ - ] (R>P)

What is shown: (r) Impedance

Press [ 2^nd ] [ π ] (x<>y) for phase angle (θ)

Examples

Example 1: RLC Series Circuit

R = 50 Ω

L = 3.8 H

C = 0.7 F

f = 40 Hz

Step 1: Store resistance in Memory 1.

50 [ STO ] 1

Step 2: Calculate angular frequency, ω = 2 * π * f, store in memory 3.

2 [ × ] [ π ] [ × ] 40 [ = ] [ STO ] 3 (251.3274123)

Step 3: Calculate (2 * π * f * L) - 1 / (2 * π * f * C)

[ RCL ] 3 [ × ] 3.8 [ - ] [ ( ] [ RCL ] 3 [ × ] 0.0007 [ ) ] [ 1/x ] [ = ] [ STO ] 2

(949.36000616)

Step 4: Calculate Impedance and Phase Angle:

[ RCL ] 1 [ 2^nd ] [ π ] (x<>y) [ RCL ] 2 [ 2^nd ] [ - ] (R>P)

Impedance: 950.6758262

Phase Angle: 86.9851854°

Example 2: RLC Series Circuit

R = 450 Ω

L = 1.15 H

C = 3.5 μF = 3.5 * 10^-6 F

f = 60 Hz

Step 1: Store resistance in Memory 1.

450 [ STO ] 1

Step 2: Calculate angular frequency, ω = 2 * π * f, store in memory 3.

2 [ × ] [ π ] [ × ] 60 [ = ] [ STO ] 3 (376.9911184)

Step 3: Calculate (2 * π * f * L) - 1 / (2 * π * f * C)

[ RCL ] 3 [ × ] 1.15 [ - ] [ ( ] [ RCL ] 3 [ × ] 3.5 [ EE ] 6 [ +/- ] [ ) ] [ 1/x ] [ = ] [ STO ] 2

(-324.3408952)

Step 4: Calculate Impedance and Phase Angle:

[ RCL ] 1 [ 2^nd ] [ π ] (x<>y) [ RCL ] 2 [ 2^nd ] [ - ] (R>P)

Impedance: 554.7044405

Phase Angle: -35.78246242°

Source

“Impedance and Complex Impedance” Electronics Tutorials. AspenCore, Inc. 2024. Retrieved October 7, 2024. https://www.electronics-tutorials.ws/accircuits/impedance.html

This wraps up the TI-30Xa Algorithm Series. Next up will be a series on the Casio fx-991CW.

I want to wish you all a Happy New Year and a prosperous, sane, and happy 2025! Be safe, everyone, it’s a very crazy world we live in.

Eddie

All original content copyright, © 2011-2024. Edward Shore. Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited. This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author.

HP Prime and TI-84+: RLC Parallel Circuit and Impedance

RLC Parallel Circuits and Impedance

 

Parallel RLC Circuit

The program RLCPAREL calculates:

* The total impedance of the circuit, and its magnitude in ohms

* Phase angle in a circuit in degrees.

* Current of the series in amps.

Input:

Battery/Source:  enter voltage and frequency

Add as many resistors (R) (in Ohms Ω), capacitors (C) (in farad), and inductors (L) (in henrys) as needed.

Notes:

HP Prime program only:  On the input screen, enter the real (a) and imaginary (if needed) (bi) parts separately.  Complex numbers can be directly entered on the TI-84+ program.

Example:

Parallel circuit powered by a 14 V, 5000 Hz battery.  The circuit has:

a resistor of 100 Ω, a capacitor of 3.2*10^-6 farads, and an inductor of 0.082 henrys.

Results:

Total Resistance:

0.987305540105 – 9.88715235955*i

Magnitude:

9.93632497508

Phase Angle:

84.2974952432

Current:

1.40897163037

HP Prime:  RLCPAREL

// Impedance of a Parallel

// EWS 2015-02-22

// Turn allow complex from real input on

// Declare subroutines

chsubr();

casubr();

// Main Routine

EXPORT RLCPAREL()

BEGIN

// initial steps

Z0:=0;

// radian mode

HAngle:=0;

// counter

I:=0;

// battery information

INPUT({V,F},"Battery Information",

{"V = ","F = "},

{"Volts","Frequency (Hz)"});

chsubr();

END;

// Choose Subroutine

chsubr()

BEGIN

LOCAL ch;

CHOOSE(ch,"# of Components: "+STRING(I),

{"Add Resistor (R)",

"Add Capacitor (C)",

"Add Inductor (L)",

"Calculate"});

// Execute calculation subroutine

casubr(ch);

END;

// Calculation Subroutine

casubr(x)

BEGIN

LOCAL a,b;

IF x==1 THEN

INPUT({a,b},"Add Resistor (Ω)",

{"a =","bi ="});

Z0:=Z0+1/(a+b*i);

I:=I+1;

chsubr();

END;

IF x==2 THEN

INPUT({a,b},"Capacitor (farad)",

{"a =","bi="});

Z0:=Z0-1/(i/(2*π*F*(a+b*i)));

I:=I+1;

chsubr();

END;

IF x==3 THEN

INPUT({a,b},"Inductor (henry)",

{"a =","bi="});

Z0:=Z0+1/(i*2*π*F*(a+b*i));

I:=I+1;

chsubr();

END;

// Termination

IF x==4 THEN

Z0:=1/Z0;

PRINT();

PRINT("Total Resistance = "+Z0);

PRINT("Magnitude (Ω) = "+ABS(Z0));

PRINT("Phase Angle (°) ="+

STRING(−ARG(Z0)*180/π));

PRINT("Current (amps) = "+

STRING(V/ABS(Z0)));

RETURN Z0;

END;

END;

TI-84+: RLCPAREL

a+bi   // Complex mode

Radian  // Radians mode

0→Z

Disp “BATTERY”

Disp “V = VOLT”

Disp “F = FREQ (HZ)”

Prompt V,F

Lbl 0

Menu(“CIRCUIT”,”+ RESISTOR”,1,”+ CAPACITOR”,2,

“+ INDUCTOR”,3,”CALCULATE”,4)

Lbl 1

Input “R (OHMS):”,R

Z+1/R→Z

Goto 0

Lbl 2

Input “C (FARAD):”,C

Z-(2πFC)/i→Z

Goto 0

Lbl 3

Input “L (HENRY):”,L

Z+1/(i2πFL)→Z

Goto 0

Lbl 4

1/Z→Z

Disp “IMPEDANCE=”

Pause Z

Disp “MAGNITUDE=”

Pause abs(Z)

Disp “PHASE ANGLE (°)=”

Pause -angle(Z)*180/π

Disp “CURRENT (AMPS)=”

Pause V/abs(Z)

Sources:

ElectronicsTutorials.  Parallel RLC Circuit Analysis  URL: 

http://www.electronics-tutorials.ws/accircuits/parallel-circuit.html

Retrieved February 22, 2015

Van Valkenburg, Mac E. (Editor) and Wendy M. Middelton (Editor)

"Reference Data for Engineers: Radio, Electronics, Computer, and

Communications"  9th Edition.  Newnes, Butterworth-Heinemann:  Wolburn,

MA  2002.  Print.

This blog is property of Edward Shore.  2015.

HP Prime and TI-84+: RLC Series Circuit and Impedance

RLC Series

 

RCL Series Circuit

The program RLCSERIES (RLCSERIE for TI-84+) calculates:

·     *    The total impedance of the circuit, and its magnitude in ohms

·     *    Phase angle in a circuit in degrees.

·     *    Current of the series in amps.

Input:

Battery/Source:  enter voltage and frequency

Add as many resistors (R) (in Ohms Ω), capacitors (C) (in farad), and inductors (L) (in henrys) as needed. 

Notes:

HP Prime program only:  On the input screen, enter the real (a) and imaginary (if needed) (bi) parts separately.  Complex numbers can be directly entered on the TI-84+ program.

Example:

Series circuit powered by a 14 V, 5000 Hz battery.  The circuit has: a resistor of 100 Ω, a capacitor of 3.2*10^-6 farads, and an inductor of 0.082 henrys.

Results:

Total Resistance:

100 + 2566.158792*i

Magnitude:

2568.10649035

Phase Angle:

87.7683842611°

Current:

5.45148733225 * 10^-3

HP Prime: RLCSERIES

// Impedance of a Series

// EWS 2015-02-22

// Turn allow complex from real input on

// Declare subroutines

chsubr();

casubr();

// Main Routine

EXPORT RLCSERIES()

BEGIN

// initial steps

Z0:=0;

// radian mode

HAngle:=0;

// counter

I:=0;

// battery information

INPUT({V,F},"Battery Information",

{"V = ","F = "},

{"Volts","Frequency (Hz)"});

chsubr();

END;

// Choose Subroutine

chsubr()

BEGIN

LOCAL ch;

CHOOSE(ch,"# of Components: "+STRING(I),

{"Add Resistor (R)",

"Add Capacitor (C)",

"Add Inductor (L)",

"Calculate"});

// Execute calculation subroutine

casubr(ch);

END;

// Calculation Subroutine

casubr(x)

BEGIN

IF x==1 THEN

INPUT(R,"Add Resistor","R =",

// Impedance of a Series

// EWS 2015-02-22

// Turn allow complex from real input on

// Declare subroutines

chsubr();

casubr();

// Main Routine

EXPORT RLCSERIES()

BEGIN

// initial steps

Z0:=0;

// radian mode

HAngle:=0;

// counter

I:=0;

// battery information

INPUT({V,F},"Battery Information",

{"V = ","F = "},

{"Volts","Frequency (Hz)"});

chsubr();

END;

// Choose Subroutine

chsubr()

BEGIN

LOCAL ch;

CHOOSE(ch,"# of Components: "+STRING(I),

{"Add Resistor (R)",

"Add Capacitor (C)",

"Add Inductor (L)",

"Calculate"});

// Execute calculation subroutine

casubr(ch);

END;

// Calculation Subroutine

casubr(x)

BEGIN

LOCAL a,b;

IF x==1 THEN

INPUT({a,b},"Resistor (Ω)",

{"a =","bi="});

Z0:=Z0+(a+b*i);

I:=I+1;

chsubr();

END;

IF x==2 THEN

INPUT({a,b},"Capacitor (farad)",

{"a =","bi="});

Z0:=Z0-i/(2*π*F*(a+b*i));

I:=I+1;

chsubr();

END;

IF x==3 THEN

INPUT({a,b},"Inductor (henry)",

{"a =","bi="});

Z0:=Z0+i*2*π*F*(a+b*i);

I:=I+1;

chsubr();

END;

// Calculation

IF x==4 THEN

PRINT();

PRINT("Impedance = "+Z0);

PRINT("Magnitude (Ω) = "+ABS(Z0));

PRINT("Phase Angle (°) ="+

STRING(ARG(Z0)*180/π));

PRINT("Current (amps) = "+

STRING(V/ABS(Z0)));

RETURN Z0;

END;

END;

TI-84+: RLCSERIE

a+bi   // Complex mode

Radian  // Radians mode

0→Z

Disp “BATTERY”

Disp “V = VOLT”

Disp “F = FREQ (HZ)”

Prompt V,F

Lbl 0

Menu(“CIRCUIT”,”+ RESISTOR”,1,”+ CAPACITOR”,2,

“+ INDUCTOR”,3,”CALCULATE”,4)

Lbl 1

Input “R (OHMS):”,R

Z+R→Z

Goto 0

Lbl 2

Input “C (FARAD):”,C

Z-i/(2πFC)→Z

Goto 0

Lbl 3

Input “L (HENRY):”,L

Z+i2πFL→Z

Goto 0

Lbl 4

Disp “IMPEDANCE=”

Pause Z

Disp “MAGNITUDE=”

Pause abs(Z)

Disp “PHASE ANGLE (°)=”

Pause angle(Z)*180/π

Disp “CURRENT (AMPS)=”

Pause V/abs(Z)

Sources:

ElectronicsTutorials.  Series RLC Circuit Analysis  URL: 

http://www.electronics-tutorials.ws/accircuits/series-circuit.html

Retrieved February 22, 2015

Van Valkenburg, Mac E. (Editor) and Wendy M. Middelton (Editor)

"Reference Data for Engineers: Radio, Electronics, Computer, and

Communications"  9th Edition.  Newnes, Butterworth-Heinemann:  Wolburn,

MA  2002.  Print.

This blog is property of Edward Shore.  2015.