Casio fx-9750GIII: Equatorial to Galactic Coordinates Conversions

Casio fx-9750GIII: Equatorial to Galactic Coordinates Conversions 

Introduction

Coordinate Systems

There are several coordinate systems used by astronomers to determine the placement of celestial objects, such as stars, galaxies, planets, and black holes, in our night skies.

Two coordinate systems are:

Equatorial System:

The equatorial system frames the University with the Earth's center as the center of the university.  

Right Ascension (α):   Customarily stated in hours, minutes, and seconds (H°M°S°).   Each hour is equivalent to 15 degrees.  The right ascension at 0 hours is aligned where the sun would be during the vernal equinox.  

Declination (δ):   Customarily stated in degrees, minutes, and seconds (D°M°S°).  

Galactic System:

The galactic system frames the University, aligning it with the Milky Way Galaxy.  The center of the system is our Sun.  The galactic longitude at 0 degrees aligns with the center of our galaxy (Sagittarius A*).

Galactic Longitude (l):  Customarily stated in degrees, minutes, and seconds (D°M°S°).  

Galactic Latitude (b):  Customarily stated in degrees, minutes, and seconds (D°M°S°).  

The program EQT2GLT converts equatorial coordinates (α, δ) to galactical coordinates (l, b).  

b = arcsin( cos δ × cos 27.1284° × cos(α - 192.8595°) + cos δ × cos 27.1284° )

l = 

arctan( ( sin δ - sin b × sin 27.1284° ) ÷ ( cos δ × sin(α -192.8595°) × cos 27.1284°) + 32.93117169°

=  atan2((sin δ - sin b × sin 27.1284°), (cos δ × sin(α -192.8595°) × cos 27.1284°)) + 32.93117169°

b is in hours, from -90 to 90 degrees.

l is in degrees, from 0 to 360 degrees.  Be sure to consider quadrants in your calculation.   

The program GLT2EQT converts galactical coordinates (l, b) to equatorial coordinates (α, δ).  

δ = arcsin( (cos b × cos 27.1284° × sin( l - 32.93117169° ) + sin b × sin 27.1284° )

α = arctan( ( cos b × cos( l - 32.93117169° ) ) ÷ ( sin b × cos 27.1284° - cos b × sin 27.1284° × sin( l - 32.93117169° ) ) + 192.8595°

= atan2((cos b × cos(l - 32.93117169°),(sin b × cos 27.1284° - cos b × sin 27.1284° × sin(l-32.93117169°)) + 192.8595°

δ is in degrees, from -90 to 90 degrees.  

α is in hours, from 0 to 24 hours.  Be sure to consider quadrants in your calculation.   Remember that 1 hour is equivalent to 15 degrees.  

The equations are from Practical Astronomy With Your Calculator by Peter Duffett-Smith, with the constants updated for J2000.0.

From the "Conversion of coordinates" page of Tobias Westmeier's webpage, the J2000.0 of the north pole are:

α0 ≈ 192.8595°  (12h 51m 26.28s)

δ0 ≈ 27.1284°  (27°07'42.24")

(Sources:   Duffett-Smith, Westmeier - refer to the Source section)

For more details, please refer to the Equatorial to Galactic Coordinates:  Updating the Constants posted on January 6, 2023.   

Casio fx-9750GIII Program:  EQT2GLT

a+bi

Deg

"EQUATORIAL -> GALACTIC"

"J2000.0"

"R.A. IN H°M°S°"

?->A

"DEC. IN D°M°S°"

?->D

15*A->A

192.8595->R

27.1284->E

32.93117169->C

sin^-1 (cos D*cos E*cos (A-R)+sin D*sin E)->B

sin D-sin B*sin E->Y

cos D*sin (A-R)*cos E->X

Arg (X+Yi)->T

Y<⇒T+360->T

T+C->L

ClrText

"B="

B ▶DMS◢

"L="

L ▶DMS

Note:  The calculator is set to the following modes: degrees, and rectangular complex mode. 

Example:  

The star Hamal in the constellation Aries (Alpha Arietis) is located approximately at:

α = 2 hours, 7 minutes, 10 seconds

δ = 23°27'44"

Enter hours-minutes-seconds and degrees-minutes-seconds by pressing [ OPTN ], [ F6 ] ( > ), [ F5 ] (ANGL), [ F4 ] (°''').

b:  -36°12'22.12"

L:  144°34'33.2"

Casio fx-9750GIII Program:  EQT2GLT

a+bi

Deg

"GALACTIC_->_EQUATORIAL"

"J2000.0"

"B (LAT) IN D°M°S°"

?->B

"L (LONG) IN D°M°S°"

?->L

192.8595->R

27.1284->E

32.93117169->C

sin^-1 (cos B*cos E*sin (L-C)+sin B*sin E)->D

cos B*cos (L-C)->Y

sin B*cos E-cos B*sin E*sin (L-C)->X

Arg (X+Yi)->T

R+T->A

A>360⇒A-360->A

A÷15->A

ClrText

"R.A.="

A ▶DMS◢

"DEC="

D▶DMS

Example:

The star Regulus in the constellation Leo (Alpha Leonis) is located approximately at:  

b:  48°56'03"

l:  226°25'36"

α:  10°08'22.31"  (10 hr, 8 min, 22.31 sec)

δ:  11°58'02.14"

Note:  The results are approximated.  

Sources

"Equatorial coordinate system"  Wikipedia.  Last Edited April 10, 2023.  Accessed December 10, 2023.  https://en.wikipedia.org/wiki/Equatorial_coordinate_system

"Galactic coordinate system" Wikipedia.  Last Edited April 21, 2023.  Accessed November 23, 2023.  https://en.wikipedia.org/wiki/Galactic_coordinate_system

Duffett-Smith, Peter.  Practical Astronomy With Your Calculator  Second Edition.  Cambridge University Press: Cambridge, UK.  1981.  

ISBN: 0 521 28411 2  (paperback) 

National Aeronautics and Space Administration (NASA).   "Coordinate Calculator"  NASA/IPAC Extragalactic Database.  Operated by the California Institute of Technology.  2023.   Accessed November 26, 2023.  https://ned.ipac.caltech.edu/coordinate_calculator?in_csys=Equatorial&in_equinox=J2000.0&obs_epoch=2000.0&ra=17h45m40.036s&dec=-29d00m28.17s&pa=0.0&out_csys=Galactic&out_equinox=J2000.0

Westmeier, Tobias.   "Conversion of coordinates"  Homepage of Tobias Westmeier.  The University of Western Australia.  Last Modified 26 September 2023.   Accessed November 26, 2023.   https://www.atnf.csiro.au/people/Tobias.Westmeier/index.php

Eddie

All original content copyright, © 2011-2024.  Edward Shore.   Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited.  This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author. 

Equatorial to Galactic Coordinates: Updating the Constants

Equatorial to Galactic Coordinates:  Updating the Constants 

Introduction

There are several coordinate systems used by astronomers to determine the placement of celestial objects, such as stars, galaxies, planets, and black holes, in our night skies.   

Equatorial System

The most common system is the Equatorial System.  Imagine a sphere which represents the Universe with the center of the Earth as the center.   The coordinates are the right ascension (α) and the declination (δ).

Right ascension (α):  The right ascension is the angular distance from the vernal equinox, going eastward traveling with the celestial equator. The 0 point is the vernal equinox.   The vernal equinox, which generally takes place around March 20 or 21, is when the sun is over the Earth's equinox heading north.  The lengths of daytime and nighttime are equal.   For the northern hemisphere, it's the first day of spring, and for the southern hemisphere, it's the first day of autumn.  Sometimes, the vernal equinox is called the First Point of Aries (♈).  The range of the right ascension is from 0 hours to 24 hours.   Each hour is equivalent to 15° (15 degrees).

Declination (δ): The declination is the angular distance north (above) or south (below) the celestial equator.  The range of declination is from -90° to +90°.

Galactical System

The galactic coordinate system focuses on aligning with our Milky Way Galaxy, with our Sun as the center of the sphere.  

Galactic Longitude (l):  The galactic longitude measures the angular distance from the center of the Milky Way Galaxy, increasing in the eastward direction.   The range of the galactic longitude is from 0° to 360°, with the 0° point at the Galactic Center, which lies in the constellation Sagittarius the Archer.   (Sagittarius A*)

Galactic Latitude (b):  The galactic latitude is the angle northward from the galactic equator, and it's range is from -90° (south pole located in the constellation Sculptor) to 90° (north pole located in the constellation Coma Berenices).

Practical Astronomy:  With Updated Constants

A popular resource for astronomical calculations is the book Practical Astronomy With Your Calculator by Peter Duffett-Smith.  

On page 48 of Practical Astronomy With Your Calculator, Duffett-Smith provides these equations for converting from equatorial (α, δ) to galactic (l, b) coordinates:

b = arcsin( cos δ × cos 27.4° × cos(α - 192.25°) + cos δ × cos 27.4° )

l = arctan( ( sin δ - sin b × sin 27.4° ) ÷ ( cos δ × sin(α -192.25°) × cos 27.4°) + 33°

Note that in calculation, α, δ, b, and l must be in decimal degrees.   Usually the coordinates are given in hours-minutes-seconds or degrees-minutes-seconds, and the quantities must be converted before calculation.   

The numerical constants?   Those are the 1950.0 coordinates of the north galactic pole with  α0 = 192.25° = 12h 49m and δ = 27.4° = 27°24'.  

Obviously, in 2024, we would be working with the epoch J2000.0 coordinates of the north galactic pole.   If we want to work the J2000.0 coordinates in the above formulas, the constants must be changed.

From the "Conversion of coordinates" page of Tobias Westmeier's webpage, the J2000.0 of the north pole are:

α0 ≈ 192.8595°  (12h 51m 26.28s)

δ0 ≈ 27.1284°  (27°07'42.24")

I choose to use these coordinates because it provides more decimal places than what is presented in the Galactic coordinate page of Wikipedia.

This leaves us with updated equations:

b = arcsin( cos δ × cos 27.1284° × cos(α - 192.8595°) + cos δ × cos 27.1284° )

l = 

arctan( ( sin δ - sin b × sin 27.1284° ) ÷ ( cos δ × sin(α -192.8595°) × cos 27.1284°) + C

We need to determine the value of C.

I'm going to use our galactic center, Sagittarius A*, as a reference point, with the coordinates as determined by NASA/IPAC Extragalactic Database's Coordinator Calculator tool:

Sagittarius A*:

Equatorial Coordinates

α ≈ 266.41681667° (17h 45m 40.036s)

δ ≈ -29.007825° (-29°00'28.17")

Galactic Coordinates

l ≈ 359.94418679°  (359°56'39.072")

b ≈ -0.04610951° (-0°2'45.994")

(Theoretically, this should be l0 = 0°, b0 = 0°).

Substituting the following data into equation for l (only the second equation has C):

l = 

arctan( ( sin δ - sin b × sin 27.1284° ) ÷ ( cos δ × sin(α -192.8595°) × cos 27.1284°) + C

359.94418679°  = 

arctan( ( sin -29.007825°  - sin -0.04610951°  × sin 27.1284° ) ÷ ( cos -29.007825°  × sin(266.41681667° - 192.8595°) × cos 27.1284°) + C

359.94418679°  = arctan( (-0.4845538612°)  ÷ (+0.7465187073°)) + C

We have to keep in mind that anytime we are working with astronomical math, we have to mind the coordinate system.  

359.94418679°  = atan2(0.7465187073°, -0.4845538612°) + C

359.94418679°  = arg(0.7465187073° - 0.4845538612° × i) + C   (where i = √-1)

Note:  

atan2(0.7465187073°, -0.4845538612°) = -32.98698493°

To put this answer in the range of 0° to 360°:

-32.98698493° + 360° = 327.0130151°

359.94418679°  = 327.0130151° + C   

C = 32.93117169

Our final updated equations are:

b = arcsin( cos δ × cos 27.1284° × cos(α - 192.8595°) + cos δ × cos 27.1284° )

l = 

arctan( ( sin δ - sin b × sin 27.1284° ) ÷ ( cos δ × sin(α -192.8595°) × cos 27.1284°) + 32.93117169

and will be used in the programs coming up this weekend.

Sources

"Equatorial coordinate system"  Wikipedia.  Last Edited April 10, 2023.  Accessed December 10, 2023.  https://en.wikipedia.org/wiki/Equatorial_coordinate_system

"Galactic coordinate system" Wikipedia.  Last Edited April 21, 2023.  Accessed November 23, 2023.  https://en.wikipedia.org/wiki/Galactic_coordinate_system

Duffett-Smith, Peter.  Practical Astronomy With Your Calculator  Second Edition.  Cambridge University Press: Cambridge, UK.  1981.  

ISBN: 0 521 28411 2  (paperback) 

National Aeronautics and Space Administration (NASA).   "Coordinate Calculator"  NASA/IPAC Extragalactic Database.  Operated by the California Institute of Technology.  2023.   Accessed November 26, 2023.  https://ned.ipac.caltech.edu/coordinate_calculator?in_csys=Equatorial&in_equinox=J2000.0&obs_epoch=2000.0&ra=17h45m40.036s&dec=-29d00m28.17s&pa=0.0&out_csys=Galactic&out_equinox=J2000.0

Westmeier, Tobias.   "Conversion of coordinates"  Homepage of Tobias Westmeier.  The University of Western Australia.  Last Modified 26 September 2023.   Accessed November 26, 2023.   https://www.atnf.csiro.au/people/Tobias.Westmeier/index.php

Eddie

All original content copyright, © 2011-2024.  Edward Shore.   Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited.  This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author. 

Casio fx-CG 50: Solar Panel Calculations

 Casio fx-CG 50: Solar Panel Calculations

Note:  The calculator programs can be modified for the monochrome Casio graphing calculators by removing the Color commands (Black, Blue, etc.).  The programs use ClrText and Locate to generate a result screen.

Optimum Tilt of a Solar Panel

The program SLRPANEL estimates the optimum tilt of a solar panel given your latitude (North/South), time of day, and day of the year.  The program assumes a 365 day year.   

For the time of day, enter the time in hours before noon.  Example:  For 9:00 AM, enter 3.   For 3:00 PM, enter -3.   

The declination of the sun is estimated at:

δ ≈ -23.44° * (cos(360°/365° * (n + 10)))

n = number of days from January 1, n = 0 for January 1.  

The program is listed in text file mode.

Casio fx-CG50 Program: SLRPANEL

(464 bytes)

'ProgramMode:RUN

Deg

ClrText

Locate 1,1,"SOLAR PANEL TILT"

Yellow Locate 1,3,"EWS 2022"

For 1->I To 750:Next

ClrText

"365 DAY YEAR ASSUMED"

"MONTH"?->M

"DAY"?->D

"HOURS FROM NOON"?->T

"LATITUDE (N//S)"?->L

0->X

M>2=>Int (0.4*M+2.3)->X

31*(M-1)+D-X-1->N

(-)23.44*(cos (360/365*(N+10)))->E

sin^-1 (sin L*sin E+cos E*cos L*cos (15*T))->H

sin^-1 (sin (15*T)*cos E/cos H)->Z

Z=0=>1Exp(-)9->Z

2/3*(tan^-1 (tan H/tan Z)-30)->P

ClrText

Black Locate 1,1,"MONTH:"

Blue Locate 8,1,M

Black Locate 11,1,"DAY:"

Blue Locate 16,1,D

Black Locate 1,3,"DEC:"

Blue Locate 7,3,E

Blue Locate 21,3,"_deg_"

Black Locate 1,5,"TILT:"

Blue Locate 7,5,P

Blue Locate 21,5,"_deg_"

Example:

April 30, 11:30 AM, at Latitude 40°20'11"

Inputs:

Month:  4

Day:  30

Hours From Noon:  0.5

Latitude:  40°20°11°   ( [ OPTN ], [ F6 ] ( > ), [ F5 ] (ANGLE), [ F4 ] ( ° ' " ))

Result Screen:

MONTH:  4   DAY: 30

DEC:  14.18251427 °

TILT:  34.39287954 °

Solar Energy Reflected

Given an incidence angle and the type of material, the program SOLARENG estimates the ratio of solar reflected.   The program offers three types of material:

Glass, average index of refraction of 1.52 is used

Silicon, average index of refraction of 3.45 is used

Diamond, average index of refraction of 2.417 is used

The program is listed in text file mode.

Casio fx-CG50 Program: SOLARENG

(324 bytes)

'ProgramMode:RUN

Deg

"INCIDENCE ANGLE"?->I

Menu "MATERIAL","GLASS",1,"SILICON",2,"DIAMOND",3

Lbl 1:1.52->R:Goto 4

Lbl 2:3.45->R:Goto 4

Lbl 3:2.417->R:Goto 4

Lbl 4

sin^-1 (sin I/R)->W

0.5*((sin (I-W))^<2>/(sin (I+W))^<2>+(tan (I-W))^<2>/(tan (I+W))^<2>)*100->P

ClrText

Black Locate 1,1,"AT ANGLE "

Black Locate 10,1,I

Black Locate 21,1,"_deg_"

Green Locate 1,2,"INDEX="

Red Locate 9,2,R

Green Locate 1,3,"REFLECT="

Red Locate 9,3,P

Red Locate 21,3,"%"

Example:

Incidence Angle: 6°, glass

Inputs:

INCIDENCE ANGLE: 6

MATERIAL: 1: GLASS

Result Screen:

AT ANGLE 6 °

INDEX = 1.52

REFLECT = 4.25820312 %

HP 32S and HP 32SII Week:  May 2, 2022 - May 6, 2022

Source:

Rosenstein, Morton.  Computing With the Scientific Calculator Casio 1986  ISBN-13:  978-1124161433

Eddie

All original content copyright, © 2011-2022.  Edward Shore.   Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited.  This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author. 

HP 11C (and Emulators): Sun's Approximate Declination, Altitude, and Azimuth

HP 11C (and Emulators):  Sun's Approximate Declination, Altitude, and Azimuth

Introduction

The following program calculates three positions for our Sun in our Solar System:

1.  Declination of the Sun (δ = 0° at the Equinoxes)
2.  Altitude of the Sun (height of the sun)
3.  Azimuth of the Sun (degree from latitude ground-wise north)
 
Formulas Used:

Inputs:
D = days after the vernal equinox (usually March 20 or March 21)
L = latitude given in D.MMSS format (avoid ±90°)
T = time before solar noon (12 PM).  Example: 9 AM, T= 3.  3 PM, T = -3.

Declination:
δ = 23.45 * sin(D * 0.9856)

Altitude:
H = asin(cos L * cos D * cos(15 * T)) + sin L * sin D)

Azimuth:
A = acos((sin H * sin L - sin D) / (cos L * cos H))

Before running the program, store D in R1, L in R2, and T in R3.

HP 11C Program: Sun Declination, Altitude, Azimuth

001 42, 21, 13 LBL C
002 43, 7 DEG
003 45, 1 RCL 1
004 48 .
005 9 9
006 8 8
007 5 5
008 6 6
009 20 ×
010 23 SIN
011 2 2
012 3 3
013 48 .
014 4 4
015 5 5
016 20 ×
017 44, 4 STO 4
018 31 R/S
019 24 COS
020 45, 2 RCL 2
021 43, 2 →H
022 24 COS
023 20 ×
024 45, 3 RCL 3
025 1 1
026 5 5
027 20 ×
028 24 COS
029 20 ×
030 45, 2 RCL 2
031 43, 2 →H
032 23 SIN
033 45, 4 RCL 4
034 23 SIN
035 20 ×
036 40 +
037 43, 23 ASIN
038 44, 5 STO 5
039 31 R/S
040 23 SIN
041 45, 2 RCL 2
042 43, 2 →H
043 23 SIN
044 20 ×
045 45, 4 RCL 4
046 23 SIN
047 30 -
048 45, 2 RCL 2
049 43, 2 →H
050 24 COS
051 45, 5 RCL 5
052 24 COS
053 20 ×
054 10 ÷
055 43, 24 ACOS
056 44, 6 STO 6
057 43,32 RTN


Example 1:
Stored Data: 
R0 = 184 (approximately September 21),
R1 = -14° 50' 12" (entered as -14.5012)
R2 = 0 (noon)

Output:
δ ≈ 13.1576°
H ≈ 62.0058°
A = 180.0000°

Example 2:
Stored Data: 
R0 = 68 
R1 = 46°
R2 = 4 (8 AM)

Output:
δ ≈ 21.5892°
H ≈ 35.9899°
A ≈ 84.4083°

Sources:

Hewlett Packard.  "Sun Altitude, Azimuth, Solar Pond Absorption", HP 67/97 Energy Conservation December 1978.
Shore, Edward.  "HP 35S: Sun Altitude, Azimuth, Solar Pond Absorption"  Eddie's Math and Calculator Blog:  http://edspi31415.blogspot.com/2013/06/hp-35s-sun-altitude-azimuth-solar-pond.html  June 7, 2013

Eddie

All original content copyright, © 2011-2018.  Edward Shore.   Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited.  This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author.  Please contact the author if you have questions.

HP Prime and Casio fx-9860GII/Prizm: Angular Distance Between Stars

HP Prime and Casio fx-9860GII/Prizm:  Angular Distance Between Stars

Given the right ascension (α) and declination (δ) of two stars of the same epoch (J2000.0 is the most current), the distance between the stars are:

d = acos( sin δ1 * sin δ2 + cos δ1 * cos δ2 * cos (α1 – α2) )

The distance is usually given in decimal degrees.

Enter α in terms of hours, minutes, seconds (standard notation) and δ in terms of degrees, minutes, seconds (standard notation).

HP Prime Program:   ANGSTAR

EXPORT ANGSTAR(α1,δ1,α2,δ2)

BEGIN

// 2017-06-08 EWS

// Angular Angle

// Degrees

HAngle:=1;

LOCAL d;

α1:=15*α1;

α2:=15*α2;

d:=ACOS(SIN(δ1)*SIN(δ2)+

COS(δ1)*COS(δ2)*COS(α1-α2));

RETURN →HMS(d);

END;

Casio fx-9860GII/Prizm Program:  ANGSTAR

Deg

“RA 1: “?→A

“DEC1: “?→B

15A→A

“RA 2: “?→C

“DEC2: “?→D

15C→C

cos¯¹ (sin B * sin D + cos B * cos D * cos (A-C))→E

E>DMS

Example

Distance between Regulus (A) in Leo and Sadalmelik in Aquarius:

(data via Wikipedia)

Regulus:  α = 10h8m23.11s,  δ = +11°58’01.95”

https://en.wikipedia.org/wiki/Regulus

Sadamelik:  α = 22h5m47.03593s, δ = -0°19’11.4568”

https://en.wikipedia.org/wiki/Alpha_Aquarii

Distance:  168°20’05.1793”

Source:

Meeus, Jean.  Astronomical Algorithms  William-Bell, Inc.  Richmond, VA 1991.  ISBN 0-943396-35-2

Please stay safe, happy, and sane. Happy computing,

Eddie

I hope to have the new Casio Prizm FX-CG50 soon for review as I ordered one last Friday. 

This blog is property of Edward Shore, 2017.

HP Prime: Solar Position (Right Ascension, Declination, Altitude, Azimuth)

HP Prime: Solar Position (Right Ascension, Declination, Altitude, Azimuth)

Input:

* Month

* Date

* Year

* Local Time (your local standard time – do not adjust for daylight savings time)

* Longitude

* Latitude

Local Time:  Use a 24 Hour clock. When entering time, you can enter a decimal or hours°minutes’seconds’’.

Longitude:  This is your location, going east from the Greenwich Prime Meridian.  East is positive, West is negative. Range: -180° to 180°

Latitude: This is your location, going north from the Equator.  North is positive, South is negative.  Range:  -90° to 90°

Entering HMS:

HP Prime:  Use Shift+9 and select the appropriate symbol (°, ‘, or ‘’)

Output:

r:  Distance from the Earth to the Sun in astronomical units (AU)

α:  Right ascension in decimal hours

δ:  Declination in decimal degrees

eot:  Equation of Time in minutes

alt:  Altitude/Elevation

azi:  Azimuth, from due North going clockwise

Please keep in mind that these are approximate answers.

Also, a 2-column matrix is returned to the home screen for reference.  The first column is the input column, the second is the output column.

[[ month,  distance ]

[ day,  right ascension ]

[ year, declination ]

[ local time, declination ]

[ longitude, altitude ]

[ latitude, azimuth ]]

HP Prime:  solar

EXPORT solar()

BEGIN

// aa.usno.navy.mil

// Updated 2015-03-01 EWS

// month, day, year, local standard

// time, longitude, latitude

LOCAL m,D,Y,lstd,long,lat;

INPUT({m,D,Y,lstd,long,lat},

"Data: Use Shift+9 for H°M′S″",

{"Month:","Date :","Year :",

"Local Time (24):", "Long (+E):",

"Lat (+N)"});

// Initialization

LOCAL d,g,q,L,r,ec,gmt;

LOCAL eot,alt,lha,azi,zen,loc;

LOCAL α,δ,g1,g2;

LOCAL w1,w2;

HAngle:=1;

// Greenwich Mean Time

gmt:=lstd-long/15;

// Julian Date

d:=367*Y-IP(7*(Y+IP((m+9)/12))/4)

+IP((275*m)/9)+D+1721013.5+gmt/24

-0.5*SIGN(100*Y+m-190002.5)+0.5;

d:=d-2451545;

// Intermediate Calculations

g:=(357.529+.98560028*d)  MOD 360;

q:=(280.459+.98564736*d) MOD 360;

L:=(q+1.915*SIN(g)+.02*SIN(2*g)) MOD 360;

r:=1.00014-.01671*COS(g)-.00014*COS(2*g);

ec:=23.439291-.00000036*d;

α:=ARG(COS(L)+SIN(L)*COS(ec)*i) MOD 360;

// Convert to hours

α:=α/15;

// Declination

δ:=ASIN(SIN(ec)*SIN(L));

// Equation of Time

eot:=q/15-α;

eot:=eot*60;

// Greenwich Mean Time (in hours)

g1:=-0.000319*SIN(−125.04-0.052954*d)

-2.4ᴇ−5*SIN(560.94+1.9713*d);

gmt:=(18.697374558+24.06570982441908*d

+g1*COS(ec)) MOD 24;

// Hour Angle (in degrees)

lha:=(gmt-α)*15+long;

// Altitude (approximate)

alt:=ASIN(SIN(lat)*SIN(δ)+

COS(lat)*COS(δ)*COS(lha));

// Azimuth

// Clockwise from South

azi:=ARG(SIN(lha)*i+COS(lha)*SIN(lat)

-TAN(δ)*COS(lat));

// Convert to clockwise from North

azi:=azi+180;

PRINT();

PRINT("Sun "+m+"/"+D+"/"+Y+" ; "+lstd);

PRINT("Distance: "+r);

PRINT("α (hours): "+α);

PRINT("δ (degrees): "+δ);

PRINT("eot (minutes): "+eot);

PRINT("Approximate");

PRINT("alt (elevation): "+alt);

PRINT("azi (North-clockwise): "+azi);

PRINT("DEGREES MODE SET");

RETURN [[m,r],[D,α],[Y,δ],[lstd,eot],

[long,alt],[lat,azi]];

END;

Example:

Input:

June 1, 2015; 12:00 PM , Longitude: -118°13’59”, Latitude: 34°3’

Output:

r = 1.01406353128 AU

α = 4.6292012064 hr

δ = 22.0919016903°

eot = 2.157339456 min

alt = 78.032250726°

azi = 182.442424012°

Resources:

The United States Naval Observatory (USNO)  Washington, D.C.:

“Approximate Solar Coordinates” (URL:  http://aa.usno.navy.mil/faq/docs/SunApprox.php )

“Approximate Sidereal Time” (URL: http://aa.usno.navy.mil/faq/docs/GAST.php )

“Computing Altitude and Azimuth from Greenwich Apparent Sidereal Time” (URL: http://aa.usno.navy.mil/faq/docs/Alt_Az.php )

“Converting Between Julian Dates and Gregorian Calendar Dates” (URL: http://aa.usno.navy.mil/faq/docs/JD_Formula.php )

Retrieved February 23, 2015 to March 1, 2015

This blog is property of Edward Shore - 2015

Astronomy: Distance and Midpoint Between Two Celestial Objects

Astronomy: Distance and Midpoint Between Two Celestial Objects


Stars and celestial objects have the equatorial coordinates ( α, δ, R ) where:

α = right ascension in hours, minutes, and seconds
δ = declination in degrees, minutes, and seconds
R = distance to the celestial about (in light years, astronomical units, etc)

Convert α and δ to decimal degrees:

α = (hours + minutes/60 + seconds/3600) * 15
δ = sign(δ) * ( |degrees| + |minutes/60| + |seconds/3600| )

However, calculating distance between two points in space requires that we have cartesian coordinates (x, y, z). The conversion formulas to go from equatorial to cartesian coordinates are:

x = R * cos δ * sin α
y = R * cos δ * cos α
z = R * sin δ

For completeness, here are the conversion formulas to from cartesian to equatorial coordinates:

R = √(x^2 + y^2 + z^2)
δ = asin(z/R)
α = atan(y/x) (pay attention to the quadrant!). Alternatively: α = arg(x + i*y)

The distance formula between two points in space is:

D = √( (x2 - x1)^2 + (y2 - y1)^2 + (z2 - z1)^2 )

Source: http://en.m.wikipedia.org/wiki/Equatorial_coordinate_system

Example

Find the distance between Sagittarius A* (center of the Milky Way Galaxy) and the Andromeda Galaxy (M31).

Equatorial Coordinates:

From Wolfram Alpha: ( http://m.wolframalpha.com )

Sagittarius A*:
R = 24,824 light years
α = 17h45m40s = 266.42°
δ = -29°0'28" = -29.008°

Andromeda Galaxy:
R = 2,571,000 light years
α = 42m40s = 10.68°
δ = 41°16'8" = 41.269°

Converting to the cartesian system:

Sagittarius A*:
x = -21,667.514038
y = -1,355.611275
z = -12,037.945401

Andromeda Galaxy:
x = 358,122.65578
y = 1,898,943.67736
z = 1,695,818.99789

Calculation:

D = √( (-21,667.514038 - 358,122.65578)^2 + (-1,355.611275 - 1,898,943.67736)^2
+ (-12,037.945401 - 1,695,818.99789)^2 ) ≈ 2,583,051.16059

The distance between Sagittarius A* and the Andromeda Galaxy is about 2.583 million light years.

Happy Thanksgiving, or Day of Thanks, wherever you are. Please be safe and use good judgement. We need all the positive we can get on Earth, and in the cosmos. Cheers!

Eddie

This blog is property of Edward Shore. 2014

HP 35S: Sun Altitude, Azimuth, Solar Pond Absorption

HP 35S: Sun Altitude, Azimuth, Solar Pond Absorption

Source: Sun Altitude, Azimuth, Solar Pond Absorption, HP 67/97 Energy Conservation December 1978, Author: HP

Input:

This program asks for:

D = days after March 21 (later will be sun's declination : 23.45 sin (D * .9856°) )
L = latitude given in D.MMSS (degrees minutes seconds) format (avoid ±90°)
T = time before solar noon (12:00 PM), if the time is after noon, enter hours as a negative (example: 3:00 PM → -3)
N = index of refraction of surface/fluid (see below)

---

Index of Refraction for Common Objects:

Water: 1.33
Ice: 1.309
Glass: 1.52
Diamond: 2.42

---

Formulas: (Degrees Mode)

Sun Declination
D = 23.45 * sin( days after March 21 * .9856°)

Altitude of the Sun (H):
H = asin (cos L * cos D * cos (15 * T) + sin L * sin D)

Azimuth of the Sun (A): (degree from latitude ground wise north)
A = acos ( (sin H * sin L - sin D) ÷ (cos L * cos H) )

Fraction of the surface penetrated by the sun that hour (T):
T = 2 * n * (x^2 + y^2) * sin H * cos R
Where
R = asin (cos H ÷ n)
x = (cos R + n * sin H)^-1
y = (sin H + n * cos R)^-1

Example 1:

Input:
D = 68 (May 28), L = 46°, T = 4 (8:00 AM), N = 1.33 (water)

Output:
H (altitude) = 35.98991°
A (azimuth) = 84.40835°
F (fraction of coverage) = 0.95943

Example 2:

Input:
D = 90 (June 19), L = 23°, T = -3 (3:00 PM), N = 2.42 (diamond)

Output:
H = 48.81756°
A = 99.85903°
F = 0.82156

---

Program:

U001 LBL U
U002 INPUT D \\ declination
U003 DEG
U004 0.9856
U005 *
U006 SIN
U007 23.45
U008 *
U009 STO D \\ altitude
U010 COS
U011 INPUT L
U012 HMS→ \\ or → H
U013 STO L
U014 COS
U015 *
U016 INPUT T
U017 15
U018 *
U019 COS
U020 *
U021 RCL L
U022 SIN
U023 RCL D
U024 SIN
U025 *
U026 +
U027 ASIN
U028 STO H
U029 VIEW H \\ azimuth
U030 SIN
U031 RCL L
U032 SIN
U033 *
U034 RCL D
U035 SIN
U036 -
U037 RCL L
U038 COS
U039 RCL H
U040 COS
U041 *
U042 ÷
U043 ACOS
U044 STO A
U045 VIEW A

U046 RCL H \\ fraction
U047 COS
U048 INPUT N
U049 ÷
U050 ASIN
U051 STO R
U052 COS
U053 RCL H
U054 SIN
U055 RCL* N
U056 +
U057 1/x
U058 x^2
U059 RCL H
U060 SIN
U061 RCL R
U062 COS
U063 RCL* N
U064 +
U065 1/x
U066 x^2
U067 +
U068 RCL* N
U069 2
U070 *
U071 RCL H
U072 SIN
U073 *
U074 RCL R
U075 COS
U076 *
U077 STO F
U078 VIEW F
U079 RTN

---

This blog is property of Edward Shore. 2013