HP 42S & DM 42 Linear Progression of a Slider Crank

HP 42S & DM 42 Linear Progression of a Slider Crank

Introduction

Welcome to first post of 2020!  In today's post, the program CRANK will calculate the following:

*  Maximum (xMAX) and Minimum (xMIN) slider displacement of a slider crank using linear progression

* Connecting rod angle, slider displacement, the slider's velocity, and slider's acceleration given the crank angle

Input values are:

*  Connecting rod length  (L)

*  Crank radius  (R)

*  Vertical slider offset  (E)

*  Current speed of the crankshaft, in revolutions per minute (RPM)

*  Crank angle (θ)

The program does not dictate units of measure (such as inches, millimeters, etc).   However, all angles are measured in degrees and the program sets the calculator to Degrees mode. 

HP 42S/DM42 Program:  Linear Progression of a Slider Crank

00 { 317-Byte Prgm }
01▸LBL "CRANK"
02 DEG
03 CLMENU
04▸LBL 00
05 "LNGTH"
06 KEY 1 GTO 01
07 "ANGLE"
08 KEY 2 GTO 02
09 "LIMITS"
10 KEY 3 GTO 03
11 "∡ v a"
12 KEY 4 GTO 04
13 "EXIT"
14 KEY 5 GTO 05
15 MENU
16▸LBL 10
17 STOP
18 GTO 10
19▸LBL 01
20 "ROD LGTH:"
21 PROMPT
22 STO 01
23 "RADIUS:"
24 PROMPT
25 STO 02
26 "OFFSET:"
27 PROMPT
28 STO 03
29 "RPM:"
30 PROMPT
31 STO 04
32 "DONE"
33 AVIEW
34 GTO 00
35▸LBL 02
36 "ANGLE:"
37 PROMPT
38 STO 05
39 "DONE"
40 AVIEW
41 GTO 00
42▸LBL 03
43 RCL 03
44 RCL 02
45 RCL+ 01
46 ÷
47 ASIN
48 COS
49 RCL 02
50 RCL+ 01
51 ×
52 "xMAX="
53 ARCL ST X
54 AVIEW
55 STOP
56 RCL 03
57 RCL 01
58 RCL- 02
59 ÷
60 ASIN
61 COS
62 RCL 01
63 RCL- 02
64 ×
65 "xMIN="
66 ARCL ST X
67 AVIEW
68 STOP
69 GTO 00
70▸LBL 04
71 PI
72 RCL× 04
73 30
74 ÷
75 STO 07
76 RCL 05
77 SIN
78 RCL× 02
79 RCL+ 03
80 RCL÷ 01
81 ASIN
82 STO 06
83 "CRANK ∡="
84 ARCL ST X
85 AVIEW
86 STOP
87 RCL 02
88 RCL 05
89 COS
90 ×
91 RCL 01
92 RCL 06
93 COS
94 ×
95 +
96 "POS="
97 ARCL ST X
98 AVIEW
99 STOP
100 RCL 05
101 RCL+ 06
102 SIN
103 +/-
104 RCL 06
105 COS
106 ÷
107 RCL× 07
108 RCL× 02
109 "VELOCITY="
110 ARCL ST X
111 AVIEW
112 STOP
113 RCL 05
114 RCL+ 06
115 COS
116 +/-
117 RCL 06
118 COS
119 ÷
120 RCL 05
121 COS
122 X↑2
123 RCL× 02
124 RCL 06
125 COS
126 3
127 Y↑X
128 RCL× 01
129 ÷
130 -
131 RCL 07
132 X↑2
133 ×
134 RCL× 02
135 "ACCEL="
136 ARCL ST X
137 AVIEW
138 STOP
139 GTO 00
140▸LBL 05
141 CLMENU
142 EXITALL
143 RTN
144 END

Download:  https://drive.google.com/open?id=1z0Htza_-quZ4VLIddSqTg54pM_54_uFP

Instructions

1.  Run CRANK by pressing XEQ CRANK

2.  Enter rod length (ROD LGTH), crank radius (RADIUS), offset (OFFSET), and turning speed (RPM) by pressing the LNGT submenu.  After all the input values are entered, you will see a DONE message.  Use the [R/S] key to enter values. 

3.  To enter a crank angle, choose the ANGL submenu.  Enter the crank angle.  After the angle has been entered, you will see a DONE message. 

4.  Calculate the maximum and minimum slider displacements by choosing the LIMIT submenu.

5.  Calculate the rod angle, position, velocity, and acceleration by the ∠ v a  submenu.

6.  You can renter any of the inputs at any time. 

7.  To exit the program, press EXIT.

Example
(Fix 4 Setting)

Rod length:  8 in
Crank radius:  2 in
Offset:  1.3 in
RPM:  5000 RPM

Crank Angle:  15°

Results:
xMAX=9.9151
xMIN=5.8575

CRANK ∠=13.1326
POS=9.7226
VELOCITY=-507.0277
ACCEL=-634,997.3666

Crank Angle:  20°

(xMAX and xMIN remain the same)

CRANK ∠=14.3595
POS=9.6295
VELOCITY=-610.0807
ACCEL=-600,369.9284

Source:

"Linear Progression of Slide Crank"  HP 65  Machine Pac-1. Hewlett Packard.  1975

Eddie

All original content copyright, © 2011-2020.  Edward Shore.   Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited.  This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author.

HP Prime and HP 42S/DM42/Free42: Length of V Belts Solver

HP Prime and HP 42S/DM42/Free42:  Length of V Belts Solver

Introduction

The following equation relates the length of a V belt, the center to center distance between two pulleys or sheaves:

L = 2 * C + 1.57 * (D + d) + (D - d)^2/(4 * C)

where:

L = length of the V belt, the belt that wraps around two pulleys (or sheaves)
C = center to center distance
D = diameter of the large pulley/sheave
d = diameter of the small pulley/sheave

HP Program VBELT

This program creates four global variables:

beltlength = L
centerdist = C
lrgpulley = D
smpulley = d

The program then takes you to the Num page of the Solve app.  This allows us to create descriptive variables to help us in the Solve app. 

Global variables are created outside the main program.

// create global variables
// outside the main program
EXPORT beltlength;
EXPORT centerdist;
EXPORT lrgpulley;
EXPORT smpulley;


EXPORT VBELT()
BEGIN
// 2019-04-28 EWS

STARTAPP("Solve");

// uncheck E0-E9
LOCAL k;
FOR k FROM 0 TO 9 DO
Solve.UNCHECK(k);
END;

// enter equation to E1
E1:="beltlength=2*centerdist+
1.57*(lrgpulley+smpulley)+
(lrgpulley-smpulley)^2/
(4*centerdist)";
Solve.CHECK(1);

// go to Num View
STARTVIEW(2);

END;

HP 42S/DM42/Free 42 Solver Program VBELT

Use the SOLVER function win calling VBELT. 

LPULLEY:  large pulley/sheave diameter
SPULLEY: small pulley/sheave diameter

LBL "VBELT"
MVAR "LENGTH"
MVAR "CENTER"
MVAR "LPULLEY"
MVAR "SPULLEY"
2
RCL * "CENTER"
RCL "LPULLEY"
RCL + "SPULLEY"
1.57
*
+
RCL "LPULLEY"
RCL - "SPULLEY"
X ↑ 2
4 
÷
RCL ÷ "CENTER"
+
RCL - "LENGTH"
END

Examples

Example 1:
Large Pulley Diameter = 1 in
Small Pulley Diameter = 3/4 in
Center to Center Distance = 1.5 in
Result:  V Belt Length ≈ 5.7579 in

Example 2:
Large Pulley Diameter = 1 in
Small Pulley Diameter = 7/16 in
V Belt Length = 6.24 in
Result: Center to Center Distance ≈ 1.975 in

Source:

Gladstone, John Air Conditioning Testing and Balancing: A Field Practice Manual Van Nostrand Reinhold Company: New York.  1974  ISBN 0-442-22703-5

Eddie

All original content copyright, © 2011-2019.  Edward Shore.   Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited.  This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author.

HP Prime & TI-84+: Bolt Pattern

HP Prime & TI-84+:  Bolt Pattern

Bolt Pattern

The program BOLTPAT will calculate a bolt pattern given:

X = center, X coordinate

Y = center, Y coordinate

N = number of bolts

D = diameter of the circle

No angle of rotation is assumed.

Coordinates of each bolt can be calculated by:

X_k = (d/2*COS(360*k/n)+xc)

Y_k = (d/2*SIN(360*k/n)+yc)

Where k = 0 to n-1

The OC-Distance between each bolt is calculated by calculating the linear distance between neighboring bolts.

Output:

Each point where the bolt should be placed.  In addition, the on-center distance between bolts is displayed.  Finally, each of the coordinates will be presented in a list.  For the TI-84+ version, the list will be stored in list L6.

HP Prime:  BOLTPAT

EXPORT BOLTPAT()

BEGIN

// EWS 2012-02-28

// No pre angle tilt

// Degrees

HAngle:=1;

// Data

LOCAL z0,z1,xc,yc;

LOCAL z,n,d,k,l,xp,yp;

INPUT({xc,yc,n,d},"Bolt Spacing",

{"xc:","yc:","n :","d :"},

{"x center","y center",

"number of bolts",

"diameter"});

l:={};

// Calculation

PRINT();

PRINT("x + y*i");

FOR k FROM 0 TO n-1 DO

xp:=(d/2*COS(360*k/n)+xc);

yp:=(d/2*SIN(360*k/n)+yc);

IF k==0 THEN

z0:=xp+i*yp;

END;

IF k==1 THEN

z1:=xp+i*yp;

END;

l:=CONCAT(l,{xp+yp*i});

PRINT("("+xp+","+yp+")");

END;

PRINT("OC-OC: "+ABS(z1-z0));

RETURN l;

END;

TI-84+: BOLTPAT

a+bi

Degree

Disp “X: X CENTER”

Disp “Y: Y CENTER”

Disp “N: NO. BOLTS”

Disp “D: DIAMETER”

Prompt X,Y,N,D

For(K,0,N-1)

D/2*cos(360*K/N)+X→S

D/2*sin(360*K/N)+Y→T

If K=0

Then

S+T*i→U

{U}→L6

End

If K>0

Then

Augment(L6,{S+T*i})→L6

End

If K=1

Then

S+T*i→V

End

Disp “POINT”,K

Disp S

Disp T

Pause

End

Disp “OC-OC:”

Pause abs(U-V)

Disp L6

Example:

Build a bolt pattern with 5 bolts of a circle of diameter of 3 units.  The center of the circle has the center (4, 1).  (X = 4, Y = 1, N = 5, D = 3)

Bolts should be placed at the following points:

(5.5, 1)

(4.4635, 2.4266)

(2.7865, 1.8817)

(2.7865, 0.1183)

(4.4635, -0.4266)

OC-Distance:  1.7634

Note:  Bolt Patterns can easily be calculated with the Machinist Calc Pro, original (Model 4087) or Pro 2 (Model 4088) (including angle of rotation). 

This blog is property of Edward Shore – 2015.