The MU Key on a Four Function Calculator and Programs for the DM42/HP 42S

 The MU Key on a Four Function Calculator and Programs for the DM42/HP 42S

Not too long ago, I purchased this very colorful, four function calculator from the University I work at, the Dexin BST DX-818.

The DX-818 is powered by a solar panel with an option to be run by an AAA battery when using the calculator in less than bright light conditions. The AAA battery is optional.

A Standard Calculator

This calculator is the standard four function key calculator, complete with the square root function, percent function, the standard three memory keys (M+, M-, and MRC), and a grand total (GT) key. A grand total is started when calculations are completed by pressing the equals key [ = ]. The grand total is both recalled and cleared when the [ GT ] is pressed.

The Markup Equation

Before we head to the calculators, the mark up is a calculation of between selling price (new), cost (old), and mark up. The markup is ratio between the selling price and cost over cost and as expressed as a percentage (%):

MU = (selling price – cost) ÷ cost = (selling price ÷ cost - 1)

Solving for the other variables yield:

selling price = cost * (1 + MU)

cost = selling price ÷ (1 + MU)

In these equations, MU is expressed as a decimal.

If let the selling price be the new value and cost be the old value, then we have the equation for percent change (Δ%):

Δ% = (new – old) ÷ old = (new ÷ old - 1)

Similarly:

new = old * (1 + Δ%)

old = new ÷ (1 + Δ%)

In these equations, Δ% is expressed as a decimal.

The Markup Key (MU)

On this particular calculator, there is an [ MU ] key. This is the markup key. Apparently, there are two types of [ MU ] key, one set of syntax for Casio calculators with the [ MU ] key. An example of a Casio calculator with an [ MU ] key is the MJ-120D plus. They way Casio calculators use the [ MU ] key is a calculation:

cost [ MU ] markup percentage [ % ] returns selling price.

Immediately pressing [ = ] returns selling price – cost.

However, some calculators, like the colorful calculator featured (I really wish I knew the model number) with the [ MU ] have another syntax, and that is what I will address from here on out.

On this particular calculator, the syntax, using one of the four arithmetic functions is:

y < +, -, ×, or ÷ > x [ MU ]

No use of the equals key is needed, unless you want to add the result to the grand total.

The four calculations with the [ MU ] key, on this particular calculator (and possibly the NewYes calculators from China) are:

Key Sequence	Formula Used	Notes
Y [ + ] X [ MU ]	100 * (Y ÷ X + 1)
Y [ - ] X [ MU ]	100 * (Y ÷ X - 1)	Calculates markup or percent change (Δ%). Y = selling price, new value X = cost, old value
Y [ × ] X [ MU ]	Y * (1 + X ÷ 100)	Adds X% to Y. Calculates the new value (selling price) given old value (cost) (Y) and markup (X).
Y [ ÷ ] X [ MU ]	Y ÷ (1 – X ÷ 100)	Finds the original retail price given selling price (Y) and discount rate (X). This can also be used for gross-up calculations.

Sample Calculations

Problem	Keystrokes	Result
Determine 100 * (Y ÷ X + 1) with Y = 420, X = 25	420 [ + ] 25 [ MU ]	1780
An item that cost the company $14.75 sells for $19.99. Find the markup.	19.99 [ - ] 14.75 [ MU ]	35.5254237288 (≈35.53%)
A company manufactures a product with a unit cost of $32.84 and wants a 20% markup. What is the selling price?	32.84 [ × ] 20 [ MU ]	39.408 (about $39.41)
A product is currently on sale for $39.99. If the discount is 35%, what is the original retail price.	39.99 [ ÷ ] 35 [ MU ]	61.523076923 (about $61.52)

RPN Programming with the Swiss Micros DM42

Here are four RPN programs, which are were programmed using a Swiss Micros DM42, which can be used on the HP 42S (and probably the HP 41C).

Program MU+: Y [ + ] X [ MU ]

00 {17-Byte Prgm}

01 LBL “MU+”
02 ÷

03 1

04 +

05 100

06 ×

07 RTN

08 END

Program MU-: Y [ - ] X [ MU ]

00 {17-Byte Prgm}

01 LBL “MU-”
02 ÷

03 1

04 -

05 100

06 ×

07 RTN

08 END

Program MUMLT: Y [ × ] X [ MU ]

00 {12-Byte Prgm}

01 LBL “MUMLT”
02 %

03 +

04 RTN

05 END

Program MUDIV: Y [ ÷ ] X [ MU ]

00 {21-Byte Prgm}

01 LBL “MUDIV”
02 ENTER

03 100

04 ÷

05 1

06 X<>Y

07 -

08 ÷

09 RTN

10 END

Sources

 Casio. “MJ-120D Plus” https://www.casio.com/intl/basic-calculators/product.MJ-120DPLUS/ Accessed May 23, 2026.

Eaton, Glenn. “The Calculator MU Key” Eaton Family Website. Posted on June 30, 2017. https://eatonfamily.au/calculator-mu-key/ Accessed May 23, 2026.

“How to use the MU button on a calculator? #1” YouTube Short: @newyes1162. Posted December 5, 2022. https://www.youtube.com/shorts/OiS8yFKKJSU Accessed May 23, 2026

Eddie

All original content copyright, © 2011-2026. Edward Shore. Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited. This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author.

TI-73 (Explorer): Percents and Random Fractions

TI-73 (Explorer):  Percents and Random Fractions

TI-73 Program:  PERCENT

TAX+:  Appropriately add a percent to a number.   Application:  Sales Tax

TAX-:   Appropriately subtract a percent from a number.  Application:  Discount

% CHANGE:  Percent change from the old number to new number.  Additional application:  Percent Markup (OLD = cost, NEW = selling price)

%TOT:  Finds the percentage portion of a total number

% MARGIN:  Given an item's cost and selling price, calculate the item's percent margin.  

Code:

(spaces added for clarity)

"EWS 2023-12-02"     // (comment)

Lbl 0

Menu("PERCENT","TAX+",1,"TAX-",2,

"% CHANGE",3,"%TOT",4,"% MARGIN",5,

"EXIT",E)

Lbl 1

Prompt N

Input "X% ",X

N*(1+X%)→Y

Disp "ANSWER="

Pause Y

Goto 0

Lbl 2

Prompt N

Input "X% ",X

N*(1-X%)→Y

Disp "ANSWER="

Pause Y

Goto 0

Lbl 3

Input "OLD=",O

Input "NEW=",N

(N-O)*100/O→Y

Disp "% CHANGE="

Pause Y

Goto 0

Lbl 4

Input "PART=",P

Input "WHOLE=",W

100*P/W→Y

Disp "%"

Pause Y

Goto 0

Lbl 5

Input "COST=",C

Input "SELL PRICE=",S

(S-C)/S*100→Y

Disp "% MARGIN="

Pause Y

Goto 0

Lbl E

Disp "BYE"

Pause

Note:   Results that are to be displayed need to be followed or accompanied by a Pause command, unless the results will not show.  This wrinkle is unique to the TI-73.  

Link to download PERCENT.73p

TI-73  Program:  RANDFRAC

Generate a number of fractions with randomized numerators and denominators.  

T = number of fractions to be generator

L = upper limit that the numerator and denominator can take.  The numbers range from 1 to L

The result is returned in three parts:

numerator

denominator

fraction

For example:

5

7

5/7

Simplification rules are set through the MODE key.  

Code:

(spaces added for clarity)

"EWS 2023-12-02"     // (comment)

Disp "NO. FRACTIONS"

Prompt T

Disp "UPPER LIMIT"

Prompt L

For(I,1,T)

randInt(1,L)→N

randInt(1,L)→D

N ⁄ D→F     // N [ b/c ] D [ STO> ] F

Disp N,D,F

Pause

End

Note:  The fraction symbol pressed by [ b/c ], symbolized by  ⁄, shows on the screen as a thick division slash.   

Link to download RANDFRAC.73p

For those of you who are celebrating, Merry Christmas!

Eddie

All original content copyright, © 2011-2023.  Edward Shore.   Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited.  This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author. 

HP 15C: Pricing Calculations (Gamo)

HP 15C:  Pricing Calculations (Gamo)

Introduction

The following program is a solver for cost, price, markup, and margin – developed by Gamo, which was emailed to me. The program (shown for the HP 15C).  Program listed here with permission and much thanks and gratitude to Gamo. 

HP 11C and HP 15C Program:  Pricing Calculations

Note:  Key codes are for the HP 15C. 

Step	Key Code	Key	Comment
001	42, 21, 11	LBL A	Start Cost Routine
002	44, 1	STO 1
003	0	0
004	43, 30, 6	TEST 6, x≠y
005	43, 32	RTN
006	45, 2	RCL 2
007	1	1
008	45, 3	RCL 3
009	43, 14	%
010	40	+
011	10	÷
012	43, 32	RTN
013	42, 21, 12	LBL B	Start Price Routine
014	44, 2	STO 2
015	0	0
016	43, 30, 6	TEST 6 , x≠y
017	43, 32	RTN
018	45, 1	RCL 1
019	45, 3	RCL 3
020	43, 14	%
021	40	+
022	43, 32	RTN
023	42, 21, 13	LBL C	Enter Markup Routine
024	44, 3	STO 3
025	0	0
026	43, 30, 6	TEST 6, x≠ y
027	43, 32	RTN
028	45, 1	RCL 1
029	45, 2	RCL 2
030	43, 15	Δ%
031	43, 32	RTN
032	42, 21, 14	LBL D	Margin to Markup routine
033	44, 4	STO 4
034	0	0
035	43, 30, 6	TEST 6, x≠y
036	43, 32	RTN
037	45, 3	RCL 3
038	15	1/x
039	26	EEX
040	16	CHS
041	2	2
042	40	+
043	15	1/x
044	43, 32	RTN
045	42, 21, 15	LBL E	Markup to Margin routine
046	44, 3	STO 3
047	0	0
048	43, 30, 6	TEST 6, x≠y
049	43, 32	RTN
050	45, 4	RCL 4
051	15	1/x
052	26	EEX
053	16	CHS
054	2	2
055	30	-
056	15	1/x
057	43, 32	RTN

Registers: 

R1 = Cost

R2 = Price

R3 = Markup

R4 = Margin

Instructions:

The program primary runs on the cost-price-markup calculation, which belongs to labels A, B, and C, respectively.

Conversions between margin and markup are used between labels D and E.  Gamo recommends that you set the calculator in FIX 2 mode and press [ f ] (USER) prior to running this program.

This program is set up to be a solver similar to the HP 12C and Hewlett Packard other financial calculators. 

Examples

It is assumed that FIX 2 is set and USER mode is turned on.

Example 1: (from Gamo)

Cost = 66.46

Price = 105.00

Keystrokes:

66.46 [ A ]

105.00 [ B ]

[ C ], Markup =  57.99

[ C ] [ D ], Margin = 36.70

Example 2: 

Cost = 2500.00

Margin = 10.00

2500 [ A ]

10 [ D ]

[ E ] [ C ] [ B ],  Price = 2777.78

Example 3:

Price = 48.75

Markup = 10.00

48.75 [ B ]

10.00 [ C ]

[ A ], Cost = 44.32

Example 4:  Margin/Markup Calculation

Markup = 54.00

54.00 [ E ]

[ D ],  Margin = 35.06

Eddie

 All original content copyright, © 2011-2018.  Edward Shore.   Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited.  This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author.  Please contact the author if you have questions.