Sunday, February 17, 2019

HP Prime and TI-86: Minimum Vertical Curve Length


HP Prime and TI-86: Minimum Vertical Curve Length

Introduction

The program MVCL calculates the minimum vertical curve length for sight distances for crest curves (curve that rises then falls) and sag curves (curves that falls than rises). The equations used were determined by the AASHTO (American Association of Highway and Transportation Officials of Washington, D.C.).

HP Prime Program MVCL

EXPORT MVCL()
BEGIN
// Minimum stop speed
LOCAL g1,g2,a,c,l,s,g;

MSGBOX("Break = 2.5 s,
 Decel = 11.2 ft/s^2");

LOCAL l1:={15,20,25,30,35,40,45,
50,55,60,65,70,75,80};

LOCAL l2:={80,115,155,200,250,
305,360,425,495,570,645,730,
820,910};

INPUT({g1,g2,{c,l1}},"MVCL",
{"Grade1%:","Grade2%:",
"Speed:"});

s:=l2(c);
a:=ABS(g1-g2);

l:=2*s-2158/a;
IF s < l
l:=a*s^2/2158;
END;

g:=2*s-(400+3.5*s)/a;
IF s < g
g:=(a*s^2)/(400+3.5*s);
END;

PRINT();
PRINT("Stop speed (ft)");
PRINT("Crest curve: "+l);
PRINT("Sag curve: "+g);


END;

TI-86 Program MVCL
(744 bytes)

Input “GRADE %1:”, G1
Input “GRADE %2:”, G2
abs(G2-G1) → A
Disp “Break time = 2.5s”, “Decl. = 11.2 ft/s²”,
Car Speed?”,”(mph)”

Menu(1,”15”,A,2,”20”,B,
3,”25”,C,4,”30”,D,
5,”35”,E,6,”40”,F,
7,”45”,G,8,”50”,H,
9,”55”,I,10,”60”,J,
11,”65”,K,12,”70”,L,
13,”75”,M,14,”80”,N)

Lbl A : 80 → S : Goto Z
Lbl B : 115 → S : Goto Z
Lbl C : 155 → S : Goto Z
Lbl D : 200 → S : Goto Z
Lbl E : 250 → S : Goto Z
Lbl F : 305 → S : Goto Z
Lbl G : 360 → S : Goto Z
Lbl H : 425 → S : Goto Z
Lbl I : 495 → S : Goto Z
Lbl J : 570 → S : Goto Z
Lbl K : 645 → S : Goto Z
Lbl L : 730 → S : Goto Z
Lbl M : 820 → S : Goto Z
Lbl N : 910 → S : Goto Z

Lbl Z
Disp “Stop speed (ft)”, “crest curve:”
2 * S – 2158 / A → L
If S > L
Then
Disp L
Else
A * S² / 2158 → L
Disp L
End
Disp “sag curve:”
2 * S – (400 + 3.5 * S) / A → G
If S > G
Then
Disp G
Else
(A * S²) / (400 + 3.5 * S) → G
Disp G
End

Examples:

Example 1:
Grade 1: -1.75%
Grade 2: 2.25%
Design Speed: 40 mph

Result:
Minimum Vertical Curve Length
Crest Curve: 70.5 ft
Sag Curve: 243.125 ft

Example 2:
Grade 1: -1%
Grade 2: 1.7%
Design Speed: 50 mph

Result:
Minimum Vertical Curve Length
Crest Curve: 50.740740741 ft
Sag Curve: 150.925925926 ft

Source:

Michael R. Lindberg, PE “Civil Engineering Reference Manual for the PE Exam” 11th Ed. Professional Publications, Inc: Belmont, CA. 2008. ISBN 13-978-1-59126-192-2

Eddie

All original content copyright, © 2011-2019. Edward Shore. Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited. This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author.


No comments:

Post a Comment

HP 42S and TI-60: Dimensions of a Race Track

HP 42S and TI-60:  Dimensions of a Race Track We have a race track that consists of two rectangular tracks connected by a circular ri...