TI-84 Plus CE and TI-73 Explorer: Analog Clock

 TI-84 Plus CE and TI-73 Explorer:  Analog Clock

Introduction

The program ANALOG draws a 12-hour analog clock for any given time, given the hour and minute.  The TI-73 program covers the TI-73 Explorer and should be ported to any of the Texas Instruments calculators with monochrome screens with no or little adjustment.

The TI-84 Plus CE adds colors:  hour hand is black, minute hand is brown, the markers are orange.  Adjust colors to your liking.

Notes:

*  The program pauses when the clock is drawn.  Pressing [ENTER] restores turns the Axes back on.

*  The Pt-On command has the syntax Pt-On(x, y, mark, color*).   Mark:  Dot (1 or default), Open Square (2), Plus (3).   Color applies only to the TI-84 Plus CE or TI-84 Plus C Silver Edition.

*  The program sets the calculator to degrees mode.

Math:

Let H be the hour and M be the minute.

Set S = H + M/60,  where S is the decimal hour of the time given.

For a circle of 360°, each hour occupies 30° of the clock (360/12).  Like wise, each minute occupies 6° of the clock  (360/60).

A = 30*S,  B= 6*M

Lines are drawn from the origin (0,0) to a point (x,y).  If we set x and y to an angle θ, then:

x = r * cos θ,  y = r * sin θ, where r is the length of the line.

Angels on a cartesian plane start from the positive x-axis and measured going counter-clockwise.  However, on the analog clock requires angels to measured from the top (due north) and rotate clockwise.  This will require a vertical flip and adjusting the angle by 90°.  The adjusted coordinates are:

 

x = r * cos (θ-90°),  y = -r * sin (θ- 90°), where r is the length of the line.

TI-73 Program: ANALOG

(this includes TI-73 Explorer)

"EWS 2021"

FnOff

PlotsOff

ClrDraw

Degree

Disp "12 HR ANALOG"

Input "HOUR? ",H

Input "MINUTE? ",M

ZStandard

ZSquare

AxesOff

Circle(0,0,8)

For(X,30,360,30)

Pt-On(7*cos(X-90),-7*sin(X-90),2)

End

Line(0,0,5*cos(30H+M-90),-5*sin(30H+M-90))

Line(0,0,7*cos(6M-90),-7*sin(6M-90))

Pause

AxesOn

TI-84 Plus CE Program:  ANALOG

"EWS 2021-01-18"

FnOff 

PlotsOff 

ClrDraw

Degree

Disp "12 HOUR ANALOG CLOCK"

Input "HOUR? ",H

Input "MINUTE? ",M

ZStandard

ZSquare

AxesOff

GridOff

"FACE"

Circle(0,0,8,MEDGRAY)

For(I,30,360,30)

Pt-On(7*cos(I-90),­7*sin(I-90),2,ORANGE)

End

"HOUR"

Line(0,0,5*cos(30H+M/2-90),­5*sin(30H+M/2-90),1,BLACK)

"MINUTE"

Line(0,0,7*cos(6*M-90),­7*sin(6*M-90),1,BROWN)

Pause 

AxesOn 

Next week, more fun with the TI-73 Explorer.  

Eddie

All original content copyright, © 2011-2021.  Edward Shore.   Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited.  This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author. 

TI 84 Plus CE: Linear Equation Algebra Drill

TI 84 Plus CE: Linear Equation Algebra Drill

Note:  This program is recommended for the TI-84 Plus CE with OS 5.2 or later.

The program ALGDRILL has the user answer ten questions to solve for x in the following linear equation:

A * X + B = C

The values of A, B, and C are randomly selected from -10 to 10. Note that A ≠ 0.

TI-84 Plus CE Program ALGDRILL

"EWS 2019-04-07"
0→S

For(K,1,10)
0→A:0→B

Repeat A≠0 and B≠0
randInt(­10,10)→A
randInt(­10,10)→B
End

randInt(­10,10)→C
(C-B)/A→X
ClrHome
Disp toString(K)+". : "+toString(A)+"X + "+toString(B)+" = "+toString(C)
Input Y

If Y=X
Then
Disp "CORRECT :)",X ▶Frac
S+1→S
Else
Disp "INCORRECT.","ANSWER: ",X▶Frac
End
Pause

End
ClrHome
Disp "SCORE: "+toString(S)+"/10"
If S≥8
Disp "WELL DONE!"

Download the program here:  https://drive.google.com/file/d/13udTfPgG_qqEry1ILBD1UjvJ1JWi-mz7/view?usp=sharing

Eddie


All original content copyright, © 2011-2019.  Edward Shore.   Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited.  This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author.

HP Prime Colors (English and Spanish)

HP Prime Colors (English and Spanish)

Introduction

The program COLORES lets the user scroll through various colors (black/blanco, gray/gris, white/blanco, etc.) using the plus ( [+] ) and minus ( [ -] ) buttons.  End the program while pressing the escape button ([Esc]). 

That’s all there is to it.  Enjoy this program. 

HP Prime Program COLORES

drawnow(); // subroutine

EXPORT COLORES()

BEGIN

// 2018-05-27 EWS

// Colors in English and Spanish

// initialization

LOCAL i:=0,j:=1;

LOCAL lst:={{0,"black","negro"},

{#808080h,"gray","gris"},

{#FFFFFFh,"white","blanco"},

{#FF0000h,"red","rojo"},

{#800000h,"maroon","granate"},

{#FFC0C0h,"pink","rosado"},

{#FF00FFh,"magenta","magenta"},

{#400080h,"indigo","índigo"},

{#800080h,"purple","púrpura"},

{#000080h,"navy blue","azul marino"},

{#0000FFh,"blue","azul"},

{#00FFFFh,"cyan","cian"},

{#80D0FFh,"sky blue","cielo azul"},

{#008080h,"teal","verde azulado"},

{#003000h,"fir green","abeto verde"},

{#008000h,"green","verde"},

{#00FF00h,"lime","lima"},

{#FF8000h,"orange","naranja"},

{#D0B090h,"tan","bronceado"},

{#FFFF00h,"yellow","amarillo"}

};

LOCAL s:=SIZE(lst);

RECT();

TEXTOUT_P("Press [+] or [-] to start.",

10,45,4);

LOCAL k,j1,j2,j3;

REPEAT

k:=GETKEY;

// plus key

IF k==50 THEN

i:=i+1; j:=(i MOD s)+1;

j1:=lst(j,1); j2:=lst(j,2);

j3:=lst(j,3);

drawnow(j1,j2,j3);

END;

// minus key

IF k==45 THEN

i:=i-1; j:=(i MOD s)+1;

j1:=lst(j,1); j2:=lst(j,2);

j3:=lst(j,3);

drawnow(j1,j2,j3);

END;

UNTIL k=4; // ESC key

END;

// subroutine

drawnow(x1,x2,x3)

BEGIN

RECT();

// polygon

FILLPOLY_P({{10,10},{10,150},{150,150},

{150,10}},x1);

// text

TEXTOUT_P("English:",160,20,4);

TEXTOUT_P(x2,160,40,4);

TEXTOUT_P("Español:",160,70,4);

TEXTOUT_P(x3,160,90,4);

END;

Eddie

All original content copyright, © 2011-2018.  Edward Shore.   Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited.  This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author.  Please contact the author if you have questions.