Casio fx-CG 50: Parametric Regression

Casio fx-CG 50:  Parametric Regression

Introduction

The program PARFIT2 attempts to pair data (x,y) using a pair of parametric equations [ x(t), y(t) ].   Each list of data will have its own curve.   

x(t), 1 ≤ t ≤ n

y(t), 1 ≤ t ≤ n

n = number of data points

Each point is assigned at t-value, which the program does automatically:

t = 1 refers to (x1, y1) → (t1, x1), (t1, y1)

t = 2 refers to (x2, y2) → (t2, x2), (t2, y2)

t = 3 refers to (x3, y3) → (t3, x3), (t3, y3)

and so on.

The program offers four regression types:

1.  Linear:  a + b*t

2.  Logarithm:  a + b*ln t

3.  Exponential:  a * b^t

4.  Power:  a * t^b

Variables used:

A = intercept for x(t)

B = slope for x(t)

R = correlation for x(t)

C = intercept for y(t)

D = slope for y(t)

S = correlation for y(t)

This allows for greater curve fitting control, which can accounts for different growth of the x data and y data, separately.

The program ends with a graph of the calculated parametric equation.  

Casio fx-CG 50 Program: PARTFIT

ClrText

Locate 1,1,"PARAMETRIC"

Locate 1,2,"FIT - 2022"

Locate 1,3,"EWS"

For 1→I To 750: Next

ParamType

ClrText

"X DATA"?→List 1

"Y DATA"?→List 2

Seq(x,x,1,Dim List 1, 1)→List 3

Menu "X=","A+BT",1,"A+Bln T",2,"A×B^T",3,"A×T^B",4

Lbl 1

LinearReg(a+bx) List 3, List 1

a→A: b→B: r→R

"A+BT"→Xt1

Goto 5

Lbl 2

LogReg List 3, List 1

a→A: b→B: r→R

"A+B×ln T"→Xt1

Goto 5

Lbl 3

ExpReg(a∙b^x) List 3, List 1

a→A: b→B: r→R

"A+B^T"→Xt1

Goto 5

Lbl 4

PowerReg List 3, List 1

a→A: b→B: r→R

"A+T^B"→Xt1

Goto 5

Lbl 5

"A, B, CORR=" ◢

[ [ A ] [ B ] [ R ] ] ◢

Menu "Y=","C+DT",A,"C+Dln T",B,"C×D^T",C,"C×T^D",D

Lbl A

LinearReg(a+bx) List 2, List 1

a→C: b→D: r→S

"C+DT"→Yt1

Goto E

Lbl B

LogReg List 2, List 1

a→C: b→D: r→S

"C+D×ln T"→Yt1

Goto E

Lbl C

ExpReg(a∙b^x) List 3, List 1

a→C: b→D: r→S

"C+D^T"→Yt1

Goto E

Lbl D

PowerReg List 3, List 1

a→C: b→D: r→S

"C+T^D"→Yt1

Goto E

Lbl E

"C, D, CORR=" ◢

[ [ C ] [ D ] [ S ] ] ◢

DrawGraph

ZoomAuto

Download the program here:  https://drive.google.com/file/d/1UVEHNZ7WILv3rSAgXy0_5kQ1lBPGEvKc/view?usp=sharing

Examples

Example 1:

(x,y):

(100.0, 10.0)

(101.3, 20.0)

(103.0, 31.7)

(104.3, 42.9)

(105.6, 54.2)

(107.0, 65.6)

(110.0, 77.0)

Fit x to linear and y to exponential.

Results:  

x(t) = 98.17142857 + 1.571428571*t,  corr = 0.9904886791

y(t) = 9.829695698 * 1.308085656^t, corr = 0.9639002639

Example 2:

(x,y):

(5.0, 0.41)

(2.9, 0.30)

(1.7, 0.20)

(0.9, 0.18)

(0.1, 0.12)

Fit x to logarithmic, y to power.

Results:  

x(t) = 5.002357022 - 3.010299732 * ln t, corr = -0.9997066364

y(t) = 0.4487684406* t^-0.7312889362,  corr = -0.9684707132

Eddie

All original content copyright, © 2011-2022.  Edward Shore.   Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited.  This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author. 

HP 32SII and TI-66: Curve Fitting

HP 32SII and TI-66:  Curve Fitting

Introduction

The curve fitting program uses the linear regression module to determine the parameters b ("intercept") and m ("slope") in non-linear curves using following transformations:

Logarithmic Regression:  y = b + m * ln x
Transformations:  ( ln x, y, b, m )

Inverse Regression:  y = b + m / x
Transformations:  ( 1/x, y, b, m )

Exponential Regression:  y = b * e^(m * x)
Transformation:  ( x, ln y, e^b, m )

Power Regression:  y = b * x^m
Transformation:  ( ln x, ln y, e^b, m )

Geometric (Exponent) Regression:  y = b * m^x
Transformation:  ( x, ln y, e^b, e^m )

Simple Logistic Regression:  y = 1 / (b + m * e^(-x))
Transformation:  ( e^(-x), 1/y, b, m )

HP 32SII Program:  Curve Fitting

Note:
1.  This can be adapted into the HP 35S under one label.  Just take note of the where the label points are.
2.  The total amount of bytes used is 90.
3.  Flags 1 and 2 are used.  If flag 1 is set, e^m is calculated as slope.  If flag 2 is set, e^b is calculated as intercept.

Program:
// Initialize - LBL X
LBL X
CF 1
CF 2
CLΣ
0
RTN

// Calculation - LBL Y
LBL Y
b 
FS? 2
e^x
STO B
VIEW B
m
FS? 1
e^x
STO M
VIEW M
r 
STO R
VIEW R
RTN

// Logarithmic Regression - LBL L
LBL L
LN 
R/S
GTO L

// Inverse Regression - LBL I
LBL I
1/x
R/S
GTO I

// Exponential Regression - LBL E
LBL E
SF 2
x<>y
LN 
x<>y
R/S
GTO E

// Power Regression - LBL P
LBL P
SF 2
LN 
x<>y
LN 
x<>y
R/S
GTO P

// Geometric/Exponent Regression - LBL G
LBL G
SF 1
SF 2
x<>y
LN
x<>y
R/S 
GTO G

// Simple Logistic Regression - LBL S
LBL S
+/-
e^x
x<>y
1/x 
x<>y
STOP 
GTO S

Instructions:
1.  Clear the statistics data and flags by pressing [XEQ] X.
2.  Enter data points, run the proper label, and press [ Σ+ ] or [ Σ- ].

For example, for Logarithmic fit:
y_data [ENTER] x_data [XEQ] L [ Σ+ ]

Subsequent Data:
y_data [ENTER] x_data [R/S] [ Σ+ ]

This scheme allows for undoing data:
y_data [ENTER] x_data [XEQ] L [ Σ- ]

3.  Calculate intercept (B), slope (M), and correlation (R), press [XEQ] Y.

TI-66 Program:  Curve Fitting

Notes:
1.  This program should be able to entered on a TI-58, TI-58C, or TI-59.  At the time of the posting, I have not done it, so I don't have the key codes.
2.  94 steps are used.  [INV] [SBR] is merged into the RTN step.
3.  Flags 1 and 2 are used.  If flag 1 is set, e^m is calculated as slope.  If flag 2 is set, e^b is calculated as intercept.

Program:
// Initialize - key [ A ]
000 LBL
001 A
002 INV
003 ST.F
004 01
005 INV
006 ST.F
007 02
008 CSR
009 0
010 RTN

// Calculation - key [ A' ]
011 LBL
012 A'
013 OP
014 12
015 INV
016 IF.F
017 02
018 (   // left parenthesis
019 INV
020 LN X
021 LBL
022 (  // left parenthesis
023 STO
024 08
025 R/S
026 X<>T
027 INV
028 IF.F
029 01
030 )  // right parenthesis
031 INV
032 LN X
033 LBL
034 )  // right parenthesis
035 STO 
036 07
037 R/S
038 OP
039 13
040 STO
041 09
042 RTN

// Logarithmic Regression - key [ B ]
043 LBL
044 B
045 LN X
046 X<>T
047 R/S
048 RTN

// Inverse Regression - key [ C ]
049 LBL 
050 C
051 1/X
052 X<>T
053 R/S
054 RTN

// Exponential Regression - [ D ]
055 LBL 
056 D
057 ST.F
058 02
059 X<>T
060 R/S
061 LN X
062 R/S
063 RTN

// Power Regression - [ B' ]
064 LBL
065 B'
066 ST.F
067 02
068 LN X
069 X<>T
070 R/S
071 LN X
072 R/S
073 RTN

// Geometric/Exponent Regression - [ C' ]
074 LBL
075 C'
076 ST.F
077 01
078 ST.F
079 02
080 X<>T
081 R/S
082 LN X
083 R/S
084 RTN

// Simple Logistic Regression - [ D' ]
085 LBL
086 D'
087 +/-
088 INV
089 LN X
090 X<>T
091 R/S
092 1/X
093 R/S
094 RTN

Instructions:
1.  Clear the statistics data and flags by pressing [  ].
2.  Enter data points: enter x, run the proper label, enter y, press [R/S] and press [2nd] ( Σ+ ) or [INV] [2nd] ( Σ+ )  (for  Σ- ).

For example, for Logarithmic fit:
x_data [ B ] y_data [R/S]  [2nd] (Σ+)

This scheme allows for undoing data:
x_data [B] y_data [R/S] [INV] [2nd] (Σ+)

3.  Calculate intercept (B), slope (M), and correlation (R), press [2nd] [ A' ].

Examples

All results are rounded.

Example 1: Logarithmic Regression
Data (x,y):
(33.8, 102.4)
(34.6, 103.8)
(36.1, 105.1)
(37.8, 106.9)

Results:
B:  -33.4580
M:  38.6498
R:  0.9941

y ≈ -33.4580 + 38.6498 ln x

Example 2:  Inverse Regression
Data (x,y):
(100, 425)
(105, 429)
(110, 444)
(115, 480)

B:  823.80396
M:  -40664.72143
R:  -0.91195

y ≈ 823.80396 - 40664.72143/x

Example 3: Simple Logistic Regression
Data (x,y):
(1, 11)
(1.3, 9.615)
(1.6, 8.75)
(1.9, 8.158)
(2.6, 7.308)

B: 0.14675
M: -0.15487
R:  -0.99733

y ≈ 1 / (0.14675 - 0.15487*e^(-x))

Eddie

All original content copyright, © 2011-2019.  Edward Shore.   Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited.  This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author.

HP Prime: Best Regression Fit

HP Prime:  Best Regression Fit

The program BESTFIT compares a set of regressions to determine a best fit.  This simulates a feature presented on the Hewlett Packard HP 48S, HP 48G, HP 49G, and HP 50g.  BESTFIT compares the correlations of the following four regression models:

1.  Linear:  y = a * x + b

2.  Logarithmic:  y = a * ln x + b

3.  Exponential:  y = b * a^x   (y = b * e^(ln a * x))

4.  Power: y = b * x^a

The output is a two element list:  a string of the best fit equation and its corresponding correlation.

HP Prime Program:  BESTFIT

EXPORT BESTFIT(L1,L2)

BEGIN

// 2017-11-02 EWS

// Simulate Best Fit

// HP 48GX,49G,50g

// initialize

LOCAL clist,m,c,v,s,n;

clist:={0,0,0,0};

// test

// correlation is linear only

// requires approx()

// linear y=a*x+b

clist[1]:=approx(correlation(L1,L2));

// log y=a*LN(x)+b

c:=approx(correlation(LN(L1),L2));

IF IM(c)==0 THEN

clist[2]:=c;

END;

// exponential y=b*e^(a*x)

c:=approx(correlation(L1,LN(L2)));

IF IM(c)==0 THEN

clist[3]:=c;

END;

// power y=b*a^x

c:=approx(correlation(LN(L1),LN(L2)));

IF IM(c)==0 THEN

clist[4]:=c;

END;

// test

// POS(L0^2,MAX(L0^2))

m:=POS(clist^2,MAX(clist^2));

c:=clist[m];

IF m==1 THEN

v:=linear_regression(L1,L2);

s:=STRING(v[2])+"+"+STRING(v[1])+

"*X";

RETURN {s,c};

END;

IF m==2 THEN

v:=logarithmic_regression(L1,L2);

s:=STRING(v[2])+"+"+STRING(v[1])+

"*LN(X)";

RETURN {s,c};

END;

IF m==3 THEN

v:=exponential_regression(L1,L2);

s:=STRING(v[2])+"*"+STRING(v[1])+

"^X";

RETURN {s,c};

END;

IF m==4 THEN

v:=power_regression(L1,L2);

s:=STRING(v[2])+"*X^"+

STRING(v[1]);

RETURN {v,s};

END;

END;

Examples – BESTFIT:

Example 1:

X	y
1.05	10.45
2.28	11.33
4.20	16.38
6.34	28.87

Result: {“7.78250037344*1.21713132288^X”, 0.981261724397}

Example 2:

X	Y
-10	82
-5	41
5	-42
10	-79

Result:  {“0.5+ -8.1*X”, -0.999801918343}

Example 3:

X	Y
10	2.278
11	2.666
12	2.931
13	3.212

Result:  {“-5.79464870365+3.51429873838*LN(X)”, 0.998295735284}

BESTFIT2:  An Extended Version

Version 2 adds the following regressions: 

5.  Inverse:  y = b + a/x

6.  Simple Logistic:  y = 1/(b + a*e^(-x))

7.  Simple Quadratic:  y = b + a*x^2

8.  Square Root:  y = √(a*x + b)

HP Prime Program:  BESTFIT2

EXPORT BESTFIT2(L1,L2)

BEGIN

// 2017-11-02 EWS

// Simulate Best Fit

// HP 48GX,49G,50g

// additional models

// initialize

LOCAL clist,m,c,v,s;

clist:={0,0,0,0,0,0,0,0};

// test

// correlation is linear only

// requires approx()

// linear y=a*x+b

clist[1]:=approx(correlation(L1,L2));

// log y=a*LN(x)+b

c:=approx(correlation(LN(L1),L2));

IF IM(c)==0 THEN

clist[2]:=c;

END;

// exponential y=b*e^(a*x)

c:=approx(correlation(L1,LN(L2)));

IF IM(c)==0 THEN

clist[3]:=c;

END;

// power y=b*a^x

c:=approx(correlation(LN(L1),LN(L2)));

IF IM(c)==0 THEN

clist[4]:=c;

END;

// inverse y=b+a/x

IF POS(L1,0)==0 THEN

clist[5]:=approx(correlation(1/L1,

L2));

END;

// simple logistic

IF POS(L2,0)==0 THEN

clist[6]:=approx(correlation(e^(−L1),

1/L2));

END;

// simple quadratic

clist[7]:=approx(correlation(L1^2,

L2));

// square root

IF ΣLIST(L2≥0)==SIZE(L2) THEN

clist[8]:=approx(correlation(L1,

L2^2));

END;

// test

// POS(L0^2,MAX(L0^2))

m:=POS(clist^2,MAX(clist^2));

c:=clist[m];

IF m==1 THEN

v:=linear_regression(L1,L2);

s:=STRING(v[2])+"+"+STRING(v[1])+

"*X";

END;

IF m==2 THEN

v:=logarithmic_regression(L1,L2);

s:=STRING(v[2])+"+"+STRING(v[1])+

"*LN(X)";

END;

IF m==3 THEN

v:=exponential_regression(L1,L2);

s:=STRING(v[2])+"*"+STRING(v[1])+

"^X";

END;

IF m==4 THEN

v:=power_regression(L1,L2);

s:=STRING(v[2])+"*X^"+

STRING(v[1]);

END;

// inverse

IF m==5 THEN

v:=linear_regression(1/L1,L2);

s:=STRING(v[2])+"+"+STRING(v[1])+

"/X";

END;

// simple logistic

IF m==6 THEN

v:=linear_regression(e^(−L1),

1/L2);

s:="1/("+STRING(v[2])+"+"+

STRING(v[1])+"*e^(−X))";

END;

// simple quadratic

IF m==7 THEN

v:=linear_regression(L1^2,L2);

s:=STRING(v[2])+"+"+STRING(v[1])+

"*X^2";

END;

// square root

IF m==8 THEN

v:=linear_regression(L1,L2^2);

s:="√("+STRING(v[2])+"+"+

STRING(v[1])+"*X)";

END;

RETURN {s,c};

END;

Examples – BESTFIT2:

Example 4:

X	y
1.05	10.45
2.28	11.33
4.20	16.38
6.34	28.87

Result:  {“9.0573970192+0.48023219108*X^2”, 0.994491728382}

Example 5:

X	y
1	8.4853
2	8.9443
4	9.7980
7	10.9546

Result: {“√(63.9995089183+8.00048914762*X”, 0.999999999759}

Example 6:

X	y
1	1
2	-0.5
3	-1
4	-1.25

Result:  {“-2+3/X”, 1}

Eddie

This blog is property of Edward Shore, 2017