Fun with the TI-81 (March 2024 Edition)

Fun with the TI-81 (March 2024 Edition)

TI-81 SCATTER

Produces a scatter plot.

Size: 52 bytes

Code:

If Dim{x}=0

Disp “NO DATA”

If Dim{x}=0

Stop

ClrDraw

1→I

Lbl 0

PT-On({x}(I),{y}(I))

IS>(I,Dim{x})

Goto 0

DispGraph

Note: Dim{x} returns the number of data points in the statistics list {x}.

Keystrokes: [ VARS ], DIM, 7: Dim{x}

TI-81 ANGLES

Given three pints, the internal and external angle are calculated.

Size: 196 bytes

Code:

Deg

Disp “SIDE PT (S,T)”

Input S

Input T

Disp “CORNER (M,N)”

Input M

Input N

Disp “SIDE PT (U,V)”

Input U

Input V

(S-M)*(U-M)+(T-N)*(V-N)→D

√((S-M)^2+(T-N)^2)→A

√((U-M)^2+(V-M)^2)→B

cos^-1 (D/(A*B))→I

360-I→E

Disp “INTERNAL ANGLE”

Disp I

Disp “EXTERNAL ANGLE”

Disp E

Example:

(S,T) = (-4,-6)

(M,N) = (1,1)

(U,V) = (3,5)

INTERNAL ANGLE: 171.0273734

EXTERNAL ANGLE: 188.9726266

Source:

Cook, John D. “Ramanujan approximation for circumference of ellipse” John D. Cook Consulting. May 5, 2015. https://www.johndcook.com/blog/2013/05/05/ramanujan-circumference-ellipse/ Accessed January 24, 2024

TI-81 ELLIPSE

Given the length of the semi-axis, the program draws the ellipse, calculates the area, and approximates the circumference using Ramanujan formula.

Size: 195 bytes

Code:

Param

Rad

Disp “SEMI X-AXIS”

Input A

Disp “SEMI Y-AXIS”

Input B

(A-B)/(A+B)→L

π*(A+B)*(1+(3*L^2)/(10+√(4-3*L^2))→P

π*A*B→R

Disp “APPROX. CIR=”

Disp P

Disp “AREA=”

Disp R

Pause

All-Off

“A*cos T”→X_1T

“B*sin T”→Y_1T

X1T-On

-A-1→Xmin

A+1→Xmax

-B-1→Ymin

B+1→Ymax

0→Tmin

2π→Tmax

π/24→Tstep

DispGraph

Notes:

All-Off turns all the graphing equations off from graphing.

[ 2^nd ] {Y-VARS}, OFF, 1: All-Off

XT1 and YT1 are the equation variables x1(t) and y1(t):

[ 2^nd ] {Y-VARS}, Y, 5: X_1T and 6: Y_1T, respectively

Example:

SEMI X-AXIS? 2

SEMI Y-AXIS? 3

Results:

APPROX. CIRC= 15.86543959

AREA= 18.84955592

TI-81 RELATIVE

Calculate the consequences of reality when it comes to a length and mass of an object traveling near the speed of light, c = 299,792,458 m/s.

Size: 141 bytes

Code:

299792458→C

Disp “C=”

Disp C

Disp “M/S”

Pause

Disp “°/. OF C”

Input P

P*C/100→U

√(1-(U/C)^2)→V

Disp “LENGTH”

Input L

Disp “OBS LENGTH=”

L*V→K

Disp K

Pause

Disp “MASS”

Input M

Disp “OBS. MASS=”

M/V→N

Disp N

Enter the percentage of the speed of light (70%, 80%, 90%, etc.). Three characters are used to create the percent sign (%) (°, / , . )

Example:

92.5% of the speed of light

length: 40.8 m

mass: 6,700 kg

Results:

observed length = 15.50265784 m

observed mass = 17,633.10542 kg

Source:

Jackson, Mark D. The QuickStudy for Physics BarCharts Publishing Inc. Boca Raton, Florida. 2007. ISBN 13: 9781423202677. pp. 114-115

Eddie

All original content copyright, © 2011-2024. Edward Shore. Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited. This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author.

TI-Eighties Graphing Calculators: A Timeline

 TI-Eighties Graphing Calculators:  A Timeline

(dates are from Wikipedia) - United States

TI-81:  1990

TI-85: 1992

TI-82:  1993

TI-80:  1995 - (not pictured)

TI-83:  1996 - (not pictured)

TI-86:  1996

TI-89 (Original): 1998 - (not pictured)

TI-83 Plus: 1999

TI-83 Plus Silver Edition: 2001

TI-84 Plus: 2004

TI-89 Titanium:  2004

TI-84 Plus Silver Edition: 2004 (not pictured)

TI-84 Plus Silver Edition C:  2013 (not pictured)

TI-84 Plus CE:  2015

TI-84 Plus CE Python Edition:  2021

Eddie

All original content copyright, © 2011-2021.  Edward Shore.   Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited.  This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author. 

Fun with the TI-81: Part II

Fun with the TI-81:  Part II

Please check out yesterday's blog entry for Part I.  Now let's continue.

TI-81 Decimal to Fraction:  DECTOFRAC
(148 bytes)

This program converts a number X to fraction as an approximation.  Each successful approximation is displayed until the absolute value of the error falls below 10^-12.  This program is based on a program written for the Radio Shack TRS-80 (see source). 

Variables:
X = Number
H = numerator
I = denominator
Y = error
Used: A, B, C, D, E, F, G, J

Program:
Disp "X="
Input X
IPart X → A
1 → B
X - A → C
0 → D
1 → E
1 → F
0 → G
Lbl 2
A * F + D → H
A * G + E → I
H / I - X → Y
ClrHome
Disp H
Disp "/"
Disp I 
Disp "ERR="
Disp Y
Pause
If abs Y<1e-12 font="">
Stop
C → J
B - A * C → C
J → B
F → D
H → F
G → E 
I → G
Goto 2

Example:
X = 4.7995
4 / 1,  ERR = -.7995
5 / 1,  ERR = .2005
13 / 4, ERR = -.0495
24 / 5,  ERR = 5E-4
1915 / 399, ERR = -1.253133E-6
9599 / 2000, ERR = 0

4.7995 = 9599/2000

Source:

Craig, John Clark  119 Practical Programs for the TRS-80 Pocket Computer  Tabs Books Inc.:  Blue Ridge, PA.  1982 ISBN 0-8306-0061-1 (Paperback)

TI-81 Simple Logistic Regression:  LOGISFIT 
(71 bytes)

The program LOGISFIT fits the statistical data to the equation:

y = 1 / (a + b*e^x)

This program uses the linear regression fit with the following translations:

x' = e^(-x), y' = 1/y

This fit will is good for all data except when y = 0.

Instructions: 
1.  Enter the data through the Stat Edit menu. 
2.  Run LOGISFIT.  The data will be altered. 

Program:
1 → I
Lbl 1
e^( -{x}(I) ) → {x}(I)
{y}(I)⁻¹ → {y}(I)
IS>( I, Dim{x} )
Goto 1
LinReg
Disp "Y=1/(a+be^(X))"
Disp "a"
Disp a
Disp "b"
Disp b

Example:
x1 = 0.5
y1 = 0.384
x2 = 1
y2 = 0.422
x3 = 1.5
y3 = 0.45
x4 = 2
y4 = .468
x5 = 2.5
y5 = .48

Results:
a = 2.001859259
b = .9942654005

Equation:
y = 1 / (2.001859259 + .9942654005*e^x)

Source:

Shore, Edward.  "HP Prime and TI-84 Plus CE: Simple Logistic Regression"  Eddie's Math and Calculator Blog. 2017.  http://edspi31415.blogspot.com/2017/04/hp-prime-and-ti-84-plus-ce-simple.html
Retrieved August 17, 2019

TI -81 Confidence Intervals: INTERVAL
(184 bytes)

The program INTERVAL calculates a confidence interval given the sample's mean (M), variance (V), and number of data points (N).  A Z scored is selected when the user selects one of three confidence levels: 

99%  (0.5% on each side of the curve, Z = 2.575829586)
95%  (2.5% on each side of the curve, Z = 1.959963986)
90%.  (5% on each side of the curve, Z = 1.644853627)

The interval lies between ( M - Z * V/√N,  M + Z * V/√N )

Notes:
1.  Z is used as an control variable and the Z score.
2.  The percent symbol is built of three characters, the degree symbol (°), the forward slash by pressing the [ ÷ ] key (/), the decimal point (.).

Program:
0 → Z
Disp "MEAN="
Input M
Disp "VAR="
Input V
Disp "N="
Input N
Lbl 0
ClrHome
Disp "1. 99°/."
Disp "2. 95°/."
Disp "3. 90°/."
Input P
If P=1
2.575829586 → Z
If P=2
1.959963986 → Z
If P=3
1.644853627 → Z
If Z=0
Goto 0
M + Z * V / √N → U
M - Z * V / √N → V
Disp "INTERVAL"
Disp U
Disp V

Example:
Input:  n = 100, M = 156.39, V = 10.94, 99% confidence interval
Results: 
162.2079576
156.5720424

Source:
Kelly, Kathy A., Robert E. Whitsitt II, M. Deal LaMont, Dr. Ralph A. Olivia, et all.  Scientific Calculator Sourcebook   Texas Instruments Inc.  1981.  (no ISBN number is given)

TI-81 Fresnel Polarization:  MICROPOL
(120 bytes)

Given a microwave transferring from one medium to another with the initial angle with respect to the plane surface that separates the mediums, the following are calculated:

1.  Angle of refraction, θt
2.  Fresnel Horizontal Polarization, R_H
3.  Fresnel Vertical Polarization, R_V

The Law of Refraction:
n1 sin θi = n2 sin θt

Fresnel Horizontal Polarization:
R_H = sin(θ_i - θ_t) / sin(θ_i + θ_t)

Fresnel Vertical Polarization:
R_V = tan(θ_i - θ_t) / tan(θ_i + θ_t)

Variables:
N = n_1  (index of refraction of medium 1)
M = n_2  (index of refraction of medium 2)
θ = θ_i  (angle of incidence)
Z = θ_t (angle of refraction)
H = R_H (Fresnel horizontal polarization)
V = R_V (Fresnel vertical polarization)

Note:  Angles are in degrees

Program:
Deg
Disp "N1="
Input N
Disp "θ="
Input θ
Disp "N2="
Input M
sin⁻¹ (Nsin θ / M) → Z
sin(θ-Z) / sin(θ+Z) → H 
tan (θ-Z) / tan (θ+Z) → V
Disp "REFRACT θ=" 
Disp Z
Disp "H-POLAR="
Disp H
Disp "V-POLAR="
Disp V

Example:
Inputs:  N1 = 1.001, θ = 40°, N2 = 1.333
Results:
REFRACT θ = 28.86146514°
H-POLAR = .2071186671
V-POLAR = .0761259908

Source:
Barue, Geraud  Microwave Engineering:  Land & Space Communications  John Wiley & Sons: Hoboken, NJ 2008.  ISBN 978-0-470-08996-5

TI-81 Hyperbolic Circles: Circumference and Area:  HYPCIRCL
(61 bytes)

The program HYPCIRCL calculates the circumference and area of a circle in hyperbolic space.  Note that this not the same as (normal, regular, everyday) circles in Euclidean space. 

Circumference of a hyperbolic circle: C = 2 π sinh(R)

Area of a hyperbolic circle:  A = 4 π sinh(R/2)^2

Program:
Disp "HYP CIRCLE"
Disp "R="
Input R
2π sinh R → C
4 π (sinh(R/2))² → A
Disp "C="
Disp C
Disp "A="
Disp A

Example:
Input: R = 3
Results: 
C = 62.94416455
A = 56.97380062

Source:
Series, Caroline  "Hyperbolic Geometry MA 448"  2010. Edited Jan. 4, 2013

Eddie

All original content copyright, © 2011-2019.  Edward Shore.   Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited.  This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author.

Fun with the TI-81: Part I

Fun with the TI-81:  Part I

Before there there was the TI-82, TI-83 and its family, and the TI-84 Plus and its family, there was the Texas Instrument's original calculator from the 1990, the TI-81!

Translating TI-81 to TI-84 Plus (and Back) 

Most of the commands can be copied directly.  Some caveats to keep in mind:

Disp

The TI-81's Disp (Display command) can only display either a variable's value or a string.  The command can only display one item per line.

The TI-84 Plus' Disp command can list any combination of strings and variable values, separated by a comma.  Each argument will be placed on one line.

Input

The TI-81's Input command can ask for one variable.  There is no prompt string option.  A prompt string will require an extra Disp command.  Also, there is no colon character.

Disp "VAR="
Input A

The TI-84 Plus' Input command can have an optional prompt string.

Input "VAR=", A

Lists 

The TI-81 has two lists that are used for statistical calculations, {x} and {y}.  To recall an element of either {x} or {y}, press [ 2nd ] [ 0 ] or [ 2nd ] [ 1 ], respectively.  The dimensions of the stat lists can be found by pressing [VARS], and selecting Dim{x} under the DIM menu.  Stat lists can't be resized by storing a value to it.

All of the lists for the TI-84 Plus start with a lower case bold "L".  Lists 1-6 can be pressed by [ 2nd ] [ 1 ] through [ 6 ].  There are many lists commands and functions for the TI-84 Plus.

Linear Regression Options

Running linear regression is the LinReg command on the TI-81.  The equation will always be a + bx.

Running linear regression for the TI-84 Plus will need you to designate the x-list and y-list.  There are also various options: a + bx, ax + b, or Med-Med. 

The If Command and Loops

The TI-81 only has a singular If command, no Then or Else.  The syntax is:

If condition
do if condition is true
skip to here if condition is false

Loops will require the extensive use of Lbl (label), Goto, DS<(, and IS>(.   Lbl and Goto are self-explanatory. 

DS<(var, target).   The value of var is decreased by 1.  The next command is skipped when value < target.

IS>(var, target).  The value of var is increased by 1.  The next command is skipped when value > target. 

In addition to If (which can still do the two-line structure), Lbl, Goto, DS<(, and IS>(, the TI-84 Plus has Then, Else, For, While, and Repeat.

The STO> Button

The TI-81 turns on the ALPHA keyboard when pressing [STO>].

The TI-84 Plus doesn't.

On to the programming...

TI-81 Decimal to Binary Conversion:  BINTODEC
(75 bytes)

Input the binary integer at the prompt.  Use only 1s and 0s. 

Variables:
B = binary representation
D = decimal representation
N, M:  used

Program:
Disp "BIN>DEC"
Input B
0 → D
0 → N
B → M
Lbl 0
2^N * 10 * FPart(M/10) + D → D
IPart(M/10) → M
IS>(N, IPart(log B) + 1)
Goto 0
Disp D

Example:
Input:  B:  1001010
Result:  D:  74

TI-81 Binary to Decimal Conversion:  DECTOBIN
(99 bytes)

Input the decimal integer at the prompt.  The integer needs to be in between 1 and 1024.  Only positive integers are allowed.

Variables:
B = binary representation
D = decimal representation
N, M:  used

Program:
Disp "DEC>BIN"
Disp "1≤D≤1024"
Input D
0 → B
D → M
IPart( log D / log 2 ) → N
Lbl 2
If 2^N ≤ M
B + 1 → B
If 2^N ≤ M
M - 2^N → M
If N ≠ 0 
10 * B → B
DS<(N, 0)
Goto 2
Disp B

Example:
Input:  D:  516
Result:  B:  1000000100

TI-81 Roots of a Quadratic Equation:  QUADEQN
(121 bytes)

This program solves the equation A*X^2 + B*X + C = 0, which allows for real or complex roots.

Variables:
A, B, C:  coefficients
X, Y:  roots

If the discriminant is zero or positive, the roots are real, and are stored in X and Y.

If the discriminant is negative, we have complex roots in the form of X ± Yi, X is the real part, Y is the imaginary part.

Program:
Disp "AX²+BX+C=0"
Input A
Input B
Input C
-B / (2A) → X
(B² - 4AC) / (4A²) → Y
If Y<0 font="">
Goto 0
√Y → Y
X + Y → Y
2X - Y → X
Disp "ROOTS"
Goto 2
Lbl 0
√(abs Y) → Y
Disp "X+YI, X-YI"
Lbl 2
Disp X
Disp Y

Examples:

x^2 + 4x + 5 = 0,  Roots:  2 ± i
Input:  A: 1, B: 4, C: 5
Results:  "X+YI, X-YI", X: -2, Y: 1

x^2 + 5x + 4 = 0,  Roots:  -4, -1
Input:  A: 1, B: 5, C: 1
Results: "ROOTS", X: -4, Y: -1

Tomorrow will be Part 2. Until then,

Eddie

All original content copyright, © 2011-2019.  Edward Shore.   Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited.  This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author.

Calculator Programming: Making FOR, WHILE, and REPEAT Loops with IS>, DS<, GOTO, IF, LBL

Calculator Programming:  Making FOR, WHILE, and 
REPEAT Loops with IS>, DS<, GOTO, IF, LBL

Introduction

Say your programming capabilities on your calculator, BASIC portable computer, or programming app does not have the FOR, WHILE, and REPEAT loop structures.  No worries, there are some workarounds we can use.

Today the programs will be demonstrated with the language of the TI-81 and TI-84 Plus CE, but this blog isn't limited to these two calculators.


Simulating FOR Loops with IS> and DS<

The TI-81 (and every Texas Instruments graphing calculator of that family inclusive to the TI-84 Plus CE) has the commands IS> and DS<.

IS>:  Increment and Skip

Syntax:  IS>(variable, target number)

IS> increases the value stored in a variable by 1 and performs a comparison test.  The next command is excited if the increased value is less than or equal to the target number.

IS>(var, target)
[do this command if var + 1 ≤ target]
[skip to this command if var + 1 > target]

Simulating the FOR Loop:

FOR var = begin TO end*
[commands]
NEXT
[commands after loop is over]


* Syntax varies.  For the TI-84 Plus CE:  For(var,begin, end) : [commands] : End

with:

begin → var
LBL [label]
[commands]
IS>(var, end)
GOTO [label]
[commands after loop is over]

The program PRGM1 demonstrates how to accomplish a FOR loop with IS>.  PRGM1 displays the numbers 1 to 10.  The TI-81 section can be programmed by on the TI-81 and TI-84 Plus CE, which the TI-84+ section is for calculators TI-82 and later.

"TI-81"
1→K
Lbl 1
Disp K
IS>(K,10)
Goto 1
Disp "END"
Wait 2
"TI-84+"
For(K,1,10)
Disp K
End
Disp "END"

DS<   

Decrement and Skip

Syntax:  DS<(variable, target number)

DS< decreases the value stored in a variable by 1 and performs a comparison test.  The next command is excited if the increased value is greater than or equal to the target number.  DS< is the opposite of IS>.

DS<(var, target)
[do this command if var - 1 ≥ target]
[skip to this command if var - 1 < target]

Simulating the FOR Loop:

FOR var = begin TO end STEP -1*
[commands]
NEXT
[commands after loop is over]


* Syntax varies.  For the TI-82 to the TI-84 Plus CE, including TI-80 and TI-73:
For(var,begin, end, -1) [commands] End

with:

begin → var
LBL [label]
[commands]
DS<(var, end)
GOTO [label]
[commands after loop is over]

PRGM2 demonstrates the use of DS< and the associated For loop.


"TI-81"
10→K
Lbl 1
Disp K
DS<(K,1)
Goto 1
Disp "END"
Wait 2
"TI-84+"
For(K,10,1,­1)
Disp K
End
Disp "END"

Simulating WHILE and REPEAT Loops

With the proper use of the IF, LBL, and GOTO we can simulate WHILE and REPEAT loops.

Simulated WHILE Loops

WHILE [condition is true]
[commands]
END

* While is available for TI-82 to the TI-84 Plus CE, including TI-73.

can be simulated by:

LBL [label]
[commands]
IF [while condition] 
GOTO [label]

Simulated REPEAT Loops

REPEAT
[commands]
UNTIL [condition]

* The syntax for the TI-82 to the TI-84 Plus CE, including TI-73 is:
Repeat [condition] : [commands] : End

LBL [label]
[commands]
IF [inverse of the repeat condition] 
GOTO [label]

Example:  If the repeat condition is T>5, then the inverse is T≤5.

PRGM3 is a demonstration program on how all three techniques are used to accomplish this:

Start with 1000.  Take the square root.  Keep going until the calculator gets to 1 (by the precision of the calculator).

"TI-81"
1000→K
Lbl 1
√(K)→K
Disp K
If K≠1
Goto 1
Disp "END"
Wait 2
"84+ WHILE"
1000→K
While K≠1
√(K)→K
Disp K
End
Disp "END WHILE"
Wait 2
"84+ REPEAT"
1000→K
Repeat K=1
√(K)→K
Disp K
End
Disp "END REPEAT"

I hope you find these tips useful and helpful.

Eddie

All original content copyright, © 2011-2019.  Edward Shore.   Unauthorized use and/or unauthorized distribution for commercial purposes without express and written permission from the author is strictly prohibited.  This blog entry may be distributed for noncommercial purposes, provided that full credit is given to the author.

Retro Review: Texas Instruments TI-80

TI-80

TI-80 (left), TI-84 Plus CE (right)

Look how thin the TI-80 is

Retro Review: Texas Instruments TI-80

First, thank you Nano for the TI-80 (along with giving me a pair of slide rules and an astronomy poster)!  Much appreciated!

  

Essentials

Company:  Texas Instruments

Years:  1995

Type:  Graphing, Programming

Memory:  7,034 bytes

Operating System: Algebraic

Memory Registers: 27 (A-Z, θ)

Screen:  Monochrome

Batteries:  2 CR2032 batteries

Graphing Modes:  Function (4), Parametric (3).  Table included. 

Regressions:  6: Linear (ax + b), Quadratic, Linear (a + bx), Logarithmic, Exponential, Power

Lists: Up to 99 entries per lists, 6 lists available (L1 through L6)

Matrices: none

Complex Numbers:  none

Keyboard

The keyboard is what one would expect on a Texas Instruments graphing calculator: nice and responsive. 

Screen

The screen is small.  Not kidding.  The screen is only 48 x 64 pixels big, accompanying 8 lines of 16 characters.  That means that the font is small.  What is wild is that the pi symbol (π) does not conform to the rest of the font, and is twice as long as the rest of the characters.

The screen is still bigger than the mini-graphing calculators such as the Casio fx-6300g or the Hewlett Packard HP-9g.

Is the TI-80 a simplified TI-81?

For the most part, no.  Sure, the TI-80 does not have matrices and hyperbolic functions (sinh, cosh, etc) like the TI-81.  However, the TI-80 has fractions (see the next section), integer division and remainder function, random integer, a complementary table mode, and lists.  The number of stat plots increased to 3, which they don’t have to depend on the statistics mode.

As far as programming memory, the TI-80 beats the TI-81: 7,034 bytes to 2,400 bytes.  Also, you can go beyond 37 programs for the TI-80, as the names are not restricted to one character.

Fractions

The TI-80 has a dedicated fraction menu, which allow users to convert between improper and proper form, as well as conversion between fraction and decimal approximation.  The Manual Simplification mode allows fractions to not be automatically simplified on calculation. 

To enter fractions, the format is:  A _ B / C

Note that the slash is bold.  Merely pressing the division key will not register the fraction.

To separate the whole part from the fraction, press [ 2nd ] [ + ] (UNIT_).

To separate the numerator from the denominator, press [ 2nd ] [ ÷ ] (b/c).

Example:  Enter 2 3/4

Keystrokes:  2 [ 2nd ] [ + ] 3 [ 2nd ] [ ÷ ] 4

According to Datamath (http://www.datamath.org/Graphing/TI-80.htm ), the TI-80 would get replaced with the TI-73 in 1998.  This may mean that the TI-80 became the base for the TI-73 series (TI-73, TI-73 explorer).

Lists

The TI-80 allows for 6 lists, each with a 99 element capacity.  Arithmetic can be operated on two same-sized lists, on an element-by-element functions.  Lists functions include sorting, dimension, minimum, maximum, sum of the elements, product of the elements, and sequence generation.

Programming

Programming is fairly basic for the TI-81.  Commands:

If-Then-Else-End Structure (IF, THEN, ELSE, END)

Quick if structure

For-End structure (no IS>, DS< this time) (FOR, END)

Labels:  one character and local labels (LBL, GOTO)

Subroutines (PRGM_, RETURN)

Drawing commands include points, shading (three types, general, Y<, Y>)

Since the only built-in calculus function of the TI-80 is numerical derivation (NDERIV), two programs for Newton’s Method and Simpson’s Rule are presented below.

TI-80 Program:  SOLVEY1  (Newton’s Method)

80 bytes

The equation is stored in Y1.  The program solves for X in Y1(X) = 0

INPUT “GUESS:”, X

LBL 0

X-Y1/NDERIV(Y1,X,X)→N

IF ABS (X-N)>1E-10

THEN

N→X

GOTO 0

END

N→X

DISP “X = “, X

Example: X^2-3X+1, guess X = 3

Result:  X = 2.618033989

TI-80 Program: SIMPY1 (Integral, Simpson’s Rule)

140 bytes

The equation is stored in Y1.  The program calculates ∫(Y1,X,A,B)

RADIAN

INPUT “A:”,A

INPUT “B:”,B

INPUT “N (EVEN):”,N

(B-A)/N→H

0→T

FOR(I,1,N-1)

A+IH→X

T+2*Y1→T

IF FPART(I/2)≠0

2*Y1+T→T

END

(T+Y1(A)+Y1(B))H/3→T

DISP “INTEGRAL:”,T

Example: X^2-3X+1, with A = 0 to B = 5 and N = 10

Result:  X = 9.166666667

Final Verdict

The TI-80 is a nice introductory calculator, and thanks to programming a lot can be done with it.  I wish the screen was bigger and degree/degrees-minutes-seconds conversions were available, but other than that, it was a great calculator which provides a lot of features (maybe not as intimidating as more advanced calculators). 

It is a nice calculator to add to the collection, and I thank you Nano immensely. 

Eddie

This blog is property of Edward Shore, 2017.